tests/vpp/perf/vm_vhost/10ge2p1x710-ethip4-ip4base-eth-2vhostvr1024-1vm-ndrpdr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Library | resources.libraries.python.QemuUtils
  17 | ...
  18 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  19 | ... | NIC_Intel-X710 | ETH | IP4FWD | BASE | VHOST | 1VM | VHOST_1024
  20 | ...
  21 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  22 | ... | L3 | Intel-X710
  23 | Suite Teardown | Tear down 3-node performance topology
  24 | ...
  25 | Test Setup | Set up performance test
  26 | Test Teardown | Tear down performance test with vhost and VM with dpdk-testpmd
  27 | ... | ${min_rate}pps | ${framesize} | ${traffic_profile}
  28 | ... | dut1_node=${dut1} | dut1_vm_refs=${dut1_vm_refs}
  29 | ... | dut2_node=${dut2} | dut2_vm_refs=${dut2_vm_refs}
  30 | ...
  31 | Test Template | Local Template
  32 | ...
  33 | Documentation | *RFC2544: Pkt throughput IPv4 test cases with vhost*
  34 | ...
  35 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  36 | ... | with single links between nodes.
  37 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for IPv4 routing.
  38 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with IPv4
  39 | ... | routing and two static IPv4 /24 route entries. Qemu Guest is connected
  40 | ... | to VPP via vhost-user interfaces. Guest is running DPDK testpmd
  41 | ... | interconnecting vhost-user interfaces using 5 cores pinned to cpus 5-9
  42 | ... | and 2048M memory. Testpmd is using socket-mem=1024M (512x2M hugepages),
  43 | ... | 5 cores (1 main core and 4 cores dedicated for io), forwarding mode is
  44 | ... | set to mac, rxd/txd=1024, burst=64. DUT1, DUT2 are tested with 2p10GE
  45 | ... | NIC X710 by Intel.
  46 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop
  47 | ... | Rate) with zero packet loss tolerance or throughput PDR (Partial Drop
  48 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage
  49 | ... | of packets transmitted. NDR and PDR are discovered for different
  50 | ... | Ethernet L2 frame sizes using MLRsearch library.
  51 | ... | Test packets are generated by TG on links to DUTs. TG traffic profile
  52 | ... | contains two L3 flow-groups (flow-group per direction, 253 flows per
  53 | ... | flow-group) with all packets containing Ethernet header, IPv4 header
  54 | ... | with IP protocol=61 and static payload. MAC addresses are matching MAC
  55 | ... | addresses of the TG node interfaces.
  56
  57 *** Variables ***
  58 | ${perf_qemu_qsz}= | 1024
  59 # Socket names
  60 | ${sock1}= | /tmp/sock-1
  61 | ${sock2}= | /tmp/sock-2
  62 # FIB tables
  63 | ${fib_table_1}= | 100
  64 | ${fib_table_2}= | 101
  65 # X710 bandwidth limit
  66 | ${s_limit}= | ${10000000000}
  67 # Traffic profile:
  68 | ${traffic_profile} | trex-sl-3n-ethip4-ip4src253
  69
  70 *** Keywords ***
  71 | Local Template
  72 | | [Documentation]
  73 | | ... | [Cfg] DUT runs IPv4 routing config.
  74 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  75 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  76 | | ...
  77 | | ... | *Arguments:*
  78 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  79 | | ... | Type: integer, string
  80 | | ... | - phy_cores - Number of physical cores. Type: integer
  81 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  82 | | ...
  83 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  84 | | ...
  85 | | Set Test Variable | ${framesize}
  86 | | Set Test Variable | ${min_rate} | ${10000}
  87 | | ${dut1_vm_refs}= | Create Dictionary
  88 | | ${dut2_vm_refs}= | Create Dictionary
  89 | | Set Test Variable | ${dut1_vm_refs}
  90 | | Set Test Variable | ${dut2_vm_refs}
  91 | | ...
  92 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  93 | | And Add PCI devices to all DUTs
  94 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
  95 | | ... | ${s_limit} | ${framesize}
  96 | | And Apply startup configuration on all VPP DUTs
  97 | | When Initialize IPv4 forwarding with vhost in 3-node circular topology
  98 | | ... | ${sock1} | ${sock2}
  99 | | ${vm1}= | And Configure guest VM with dpdk-testpmd-mac connected via vhost-user
 100 | | ... | ${dut1} | ${sock1} | ${sock2} | DUT1_VM1 | ${dut1_vif1_mac}
 101 | | ... | ${dut1_vif2_mac} | jumbo_frames=${jumbo}
 102 | | Set To Dictionary | ${dut1_vm_refs} | DUT1_VM1 | ${vm1}
 103 | | ${vm2}= | And Configure guest VM with dpdk-testpmd-mac connected via vhost-user
 104 | | ... | ${dut2} | ${sock1} | ${sock2} | DUT2_VM1 | ${dut2_vif1_mac}
 105 | | ... | ${dut2_vif2_mac} | jumbo_frames=${jumbo}
 106 | | Set To Dictionary | ${dut2_vm_refs} | DUT2_VM1 | ${vm2}
 107 | | Then Find NDR and PDR intervals using optimized search
 108 | | ... | ${framesize} | ${traffic_profile} | ${min_rate} | ${max_rate}
 109
 110 *** Test Cases ***
 111 | tc01-64B-1c-ethip4-ip4base-eth-2vhostvr1024-1vm-ndrpdr
 112 | | [Tags] | 64B | 1C
 113 | | framesize=${64} | phy_cores=${1}
 114
 115 | tc02-64B-2c-ethip4-ip4base-eth-2vhostvr1024-1vm-ndrpdr
 116 | | [Tags] | 64B | 2C
 117 | | framesize=${64} | phy_cores=${2}
 118
 119 | tc03-64B-4c-ethip4-ip4base-eth-2vhostvr1024-1vm-ndrpdr
 120 | | [Tags] | 64B | 4C
 121 | | framesize=${64} | phy_cores=${4}
 122
 123 | tc04-1518B-1c-ethip4-ip4base-eth-2vhostvr1024-1vm-ndrpdr
 124 | | [Tags] | 1518B | 1C
 125 | | framesize=${1518} | phy_cores=${1}
 126
 127 | tc05-1518B-2c-ethip4-ip4base-eth-2vhostvr1024-1vm-ndrpdr
 128 | | [Tags] | 1518B | 2C
 129 | | framesize=${1518} | phy_cores=${2}
 130
 131 | tc06-1518B-4c-ethip4-ip4base-eth-2vhostvr1024-1vm-ndrpdr
 132 | | [Tags] | 1518B | 4C
 133 | | framesize=${1518} | phy_cores=${4}
 134
 135 | tc07-9000B-1c-ethip4-ip4base-eth-2vhostvr1024-1vm-ndrpdr
 136 | | [Tags] | 9000B | 1C
 137 | | framesize=${9000} | phy_cores=${1}
 138
 139 | tc08-9000B-2c-ethip4-ip4base-eth-2vhostvr1024-1vm-ndrpdr
 140 | | [Tags] | 9000B | 2C
 141 | | framesize=${9000} | phy_cores=${2}
 142
 143 | tc09-9000B-4c-ethip4-ip4base-eth-2vhostvr1024-1vm-ndrpdr
 144 | | [Tags] | 9000B | 4C
 145 | | framesize=${9000} | phy_cores=${4}
 146
 147 | tc10-IMIX-1c-ethip4-ip4base-eth-2vhostvr1024-1vm-ndrpdr
 148 | | [Tags] | IMIX | 1C
 149 | | framesize=IMIX_v4_1 | phy_cores=${1}
 150
 151 | tc11-IMIX-2c-ethip4-ip4base-eth-2vhostvr1024-1vm-ndrpdr
 152 | | [Tags] | IMIX | 2C
 153 | | framesize=IMIX_v4_1 | phy_cores=${2}
 154
 155 | tc12-IMIX-4c-ethip4-ip4base-eth-2vhostvr1024-1vm-ndrpdr
 156 | | [Tags] | IMIX | 4C
 157 | | framesize=IMIX_v4_1 | phy_cores=${4}