tests/vpp/perf/vm_vhost/10ge2p1x710-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | ...
  17 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | MRR
  18 | ... | NIC_Intel-X710 | L2BDMACLRN | ENCAP | VXLAN | L2OVRLAY | IP4UNRLAY
  19 | ... | VHOST | 1VM | VHOST_1024
  20 | ...
  21 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  22 | ... | L2 | Intel-X710
  23 | Suite Teardown | Tear down 3-node performance topology
  24 | ...
  25 | Test Setup | Set up performance test
  26 | Test Teardown | Tear down performance mrr test with vhost and VM with dpdk-testpmd
  27 | ... | dut1_node=${dut1} | dut1_vm_refs=${dut1_vm_refs}
  28 | ... | dut2_node=${dut2} | dut2_vm_refs=${dut2_vm_refs}
  29 | ...
  30 | Test Template | Local Template
  31 | ...
  32 | Documentation | *Raw results L2BD test cases with VXLANoIPv4
  33 | ... | and vhost*
  34 | ...
  35 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  36 | ... | with single links between nodes.
  37 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 switching of IPv4.
  38 | ... | Eth-IPv4-VXLAN-Eth-IPv4 is applied on link between DUT1 and DUT2.
  39 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2 bridge-
  40 | ... | domain and MAC learning enabled. Qemu Guest is connected to VPP via
  41 | ... | vhost-user interfaces. Guest is running DPDK testpmd interconnecting
  42 | ... | vhost-user interfaces using 5 cores pinned to cpus 5-9 and 2048M
  43 | ... | memory. Testpmd is using socket-mem=1024M (512x2M hugepages), 5 cores
  44 | ... | (1 main core and 4 cores dedicated for io), forwarding mode is set to
  45 | ... | io, rxd/txd=1024, burst=64. DUT1, DUT2 are tested with 2p10GE NIC X710
  46 | ... | by Intel.
  47 | ... | *[Ver] TG verification:* In MaxReceivedRate test TG sends traffic
  48 | ... | at line rate and reports total received/sent packets over trial period.
  49 | ... | Test packets are generated by TG on links to DUTs. TG traffic profile
  50 | ... | contains two L3 flow-groups (flow-group per direction, 254 flows per
  51 | ... | flow-group) with all packets containing Ethernet header, IPv4 header
  52 | ... | with IP protocol=61 and static payload. MAC addresses are matching MAC
  53 | ... | addresses of the TG node interfaces.
  54 | ... | *[Ref] Applicable standard specifications:* RFC7348.
  55
  56 *** Variables ***
  57 # Socket names
  58 | ${bd_id1}= | 1
  59 | ${bd_id2}= | 2
  60 # X710 bandwidth limit
  61 | ${s_limit}= | ${10000000000}
  62 | ${overhead}= | ${50}
  63 # Traffic profile:
  64 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4src254
  65
  66 *** Keywords ***
  67 | Local Template
  68 | | [Documentation]
  69 | | ... | [Cfg] DUT runs L2BD switching config.
  70 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  71 | | ... | [Ver] Measure MaxReceivedRate for ${framesize}B frames using single\
  72 | | ... | trial throughput test.
  73 | | ...
  74 | | ... | *Arguments:*
  75 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  76 | | ... | Type: integer, string
  77 | | ... | - phy_cores - Number of physical cores. Type: integer
  78 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  79 | | ...
  80 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  81 | | ...
  82 | | ${dut1_vm_refs}= | Create Dictionary
  83 | | ${dut2_vm_refs}= | Create Dictionary
  84 | | Set Test Variable | ${dut1_vm_refs}
  85 | | Set Test Variable | ${dut2_vm_refs}
  86 | | ...
  87 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  88 | | And Add PCI devices to all DUTs
  89 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
  90 | | ... | ${s_limit} | ${framesize} | overhead=${overhead}
  91 | | And Apply startup configuration on all VPP DUTs
  92 | | When Initialize L2 bridge domains with Vhost-User and VXLANoIPv4 in 3-node circular topology
  93 | | ... | ${bd_id1} | ${bd_id2}
  94 | | And Configure guest VMs with dpdk-testpmd connected via vhost-user
  95 | | ... | vm_count=${1} | jumbo=${jumbo} | perf_qemu_qsz=${1024}
  96 | | ... | use_tuned_cfs=${False}
  97 | | Then Traffic should pass with maximum rate
  98 | | ... | ${max_rate}pps | ${framesize} | ${traffic_profile}
  99
 100 *** Test Cases ***
 101 | tc01-64B-1c-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 102 | | [Tags] | 64B | 1C
 103 | | framesize=${64} | phy_cores=${1}
 104
 105 | tc02-64B-2c-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 106 | | [Tags] | 64B | 2C
 107 | | framesize=${64} | phy_cores=${2}
 108
 109 | tc03-64B-4c-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 110 | | [Tags] | 64B | 4C
 111 | | framesize=${64} | phy_cores=${4}
 112
 113 | tc04-1518B-1c-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 114 | | [Tags] | 1518B | 1C
 115 | | framesize=${1518} | phy_cores=${1}
 116
 117 | tc05-1518B-2c-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 118 | | [Tags] | 1518B | 2C
 119 | | framesize=${1518} | phy_cores=${2}
 120
 121 | tc06-1518B-4c-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 122 | | [Tags] | 1518B | 4C
 123 | | framesize=${1518} | phy_cores=${4}
 124
 125 | tc07-9000B-1c-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 126 | | [Tags] | 9000B | 1C
 127 | | framesize=${9000} | phy_cores=${1}
 128
 129 | tc08-9000B-2c-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 130 | | [Tags] | 9000B | 2C
 131 | | framesize=${9000} | phy_cores=${2}
 132
 133 | tc09-9000B-4c-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 134 | | [Tags] | 9000B | 4C
 135 | | framesize=${9000} | phy_cores=${4}
 136
 137 | tc10-IMIX-1c-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 138 | | [Tags] | IMIX | 1C
 139 | | framesize=IMIX_v4_1 | phy_cores=${1}
 140
 141 | tc11-IMIX-2c-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 142 | | [Tags] | IMIX | 2C
 143 | | framesize=IMIX_v4_1 | phy_cores=${2}
 144
 145 | tc12-IMIX-4c-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 146 | | [Tags] | IMIX | 4C
 147 | | framesize=IMIX_v4_1 | phy_cores=${4}