tests/vpp/perf/vm_vhost/10ge2p1x710-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Library | resources.libraries.python.QemuUtils
  17 | ...
  18 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | MRR
  19 | ... | NIC_Intel-X710 | L2BDMACLRN | ENCAP | VXLAN | L2OVRLAY | IP4UNRLAY
  20 | ... | VHOST | 1VM | VHOST_1024
  21 | ...
  22 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  23 | ... | L2 | Intel-X710
  24 | Suite Teardown | Tear down 3-node performance topology
  25 | ...
  26 | Test Setup | Set up performance test
  27 | Test Teardown | Tear down performance mrr test with vhost and VM with dpdk-testpmd
  28 | ... | dut1_node=${dut1} | dut1_vm_refs=${dut1_vm_refs}
  29 | ... | dut2_node=${dut2} | dut2_vm_refs=${dut2_vm_refs}
  30 | ...
  31 | Test Template | Local Template
  32 | ...
  33 | Documentation | *Raw results L2BD test cases with VXLANoIPv4
  34 | ... | and vhost*
  35 | ...
  36 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  37 | ... | with single links between nodes.
  38 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 switching of IPv4.
  39 | ... | Eth-IPv4-VXLAN-Eth-IPv4 is applied on link between DUT1 and DUT2.
  40 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2 bridge-
  41 | ... | domain and MAC learning enabled. Qemu Guest is connected to VPP via
  42 | ... | vhost-user interfaces. Guest is running DPDK testpmd interconnecting
  43 | ... | vhost-user interfaces using 5 cores pinned to cpus 5-9 and 2048M
  44 | ... | memory. Testpmd is using socket-mem=1024M (512x2M hugepages), 5 cores
  45 | ... | (1 main core and 4 cores dedicated for io), forwarding mode is set to
  46 | ... | io, rxd/txd=1024, burst=64. DUT1, DUT2 are tested with 2p10GE NIC X710
  47 | ... | by Intel.
  48 | ... | *[Ver] TG verification:* In MaxReceivedRate test TG sends traffic
  49 | ... | at line rate and reports total received/sent packets over trial period.
  50 | ... | Test packets are generated by TG on links to DUTs. TG traffic profile
  51 | ... | contains two L3 flow-groups (flow-group per direction, 254 flows per
  52 | ... | flow-group) with all packets containing Ethernet header, IPv4 header
  53 | ... | with IP protocol=61 and static payload. MAC addresses are matching MAC
  54 | ... | addresses of the TG node interfaces.
  55 | ... | *[Ref] Applicable standard specifications:* RFC7348.
  56
  57 *** Variables ***
  58 # Socket names
  59 | ${bd_id1}= | 1
  60 | ${bd_id2}= | 2
  61 | ${sock1}= | /tmp/sock-1-${bd_id1}
  62 | ${sock2}= | /tmp/sock-1-${bd_id2}
  63 # X710 bandwidth limit
  64 | ${s_limit}= | ${10000000000}
  65 | ${overhead} | ${50}
  66 # Traffic profile:
  67 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4src254
  68
  69 *** Keywords ***
  70 | Local Template
  71 | | [Documentation]
  72 | | ... | [Cfg] DUT runs L2BD switching config.
  73 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  74 | | ... | [Ver] Measure MaxReceivedRate for ${framesize}B frames using single\
  75 | | ... | trial throughput test.
  76 | | ...
  77 | | ... | *Arguments:*
  78 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  79 | | ... | Type: integer, string
  80 | | ... | - phy_cores - Number of physical cores. Type: integer
  81 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  82 | | ...
  83 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  84 | | ...
  85 | | ${dut1_vm_refs}= | Create Dictionary
  86 | | ${dut2_vm_refs}= | Create Dictionary
  87 | | Set Test Variable | ${dut1_vm_refs}
  88 | | Set Test Variable | ${dut2_vm_refs}
  89 | | ...
  90 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  91 | | And Add PCI devices to all DUTs
  92 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
  93 | | ... | ${s_limit} | ${framesize} | overhead=${overhead}
  94 | | And Apply startup configuration on all VPP DUTs
  95 | | When Initialize L2 bridge domains with Vhost-User and VXLANoIPv4 in 3-node circular topology
  96 | | ... | ${bd_id1} | ${bd_id2} | ${sock1} | ${sock2}
  97 | | ${vm1}= | And Configure guest VM with dpdk-testpmd connected via vhost-user
  98 | | ... | DUT1 | ${sock1} | ${sock2} | DUT1_VM1 | jumbo=${jumbo}
  99 | | ... | perf_qemu_qsz=${1024} | use_tuned_cfs=${False}
 100 | | Set To Dictionary | ${dut1_vm_refs} | DUT1_VM1 | ${vm1}
 101 | | ${vm2}= | And Configure guest VM with dpdk-testpmd connected via vhost-user
 102 | | ... | DUT2 | ${sock1} | ${sock2} | DUT2_VM1 | jumbo=${jumbo}
 103 | | ... | perf_qemu_qsz=${1024} | use_tuned_cfs=${False}
 104 | | Set To Dictionary | ${dut2_vm_refs} | DUT2_VM1 | ${vm2}
 105 | | Then Traffic should pass with maximum rate
 106 | | ... | ${max_rate}pps | ${framesize} | ${traffic_profile}
 107
 108 *** Test Cases ***
 109 | tc01-64B-1c-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 110 | | [Tags] | 64B | 1C
 111 | | framesize=${64} | phy_cores=${1}
 112
 113 | tc02-64B-2c-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 114 | | [Tags] | 64B | 2C
 115 | | framesize=${64} | phy_cores=${2}
 116
 117 | tc03-64B-4c-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 118 | | [Tags] | 64B | 4C
 119 | | framesize=${64} | phy_cores=${4}
 120
 121 | tc04-1518B-1c-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 122 | | [Tags] | 1518B | 1C
 123 | | framesize=${1518} | phy_cores=${1}
 124
 125 | tc05-1518B-2c-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 126 | | [Tags] | 1518B | 2C
 127 | | framesize=${1518} | phy_cores=${2}
 128
 129 | tc06-1518B-4c-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 130 | | [Tags] | 1518B | 4C
 131 | | framesize=${1518} | phy_cores=${4}
 132
 133 | tc07-9000B-1c-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 134 | | [Tags] | 9000B | 1C
 135 | | framesize=${9000} | phy_cores=${1}
 136
 137 | tc08-9000B-2c-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 138 | | [Tags] | 9000B | 2C
 139 | | framesize=${9000} | phy_cores=${2}
 140
 141 | tc09-9000B-4c-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 142 | | [Tags] | 9000B | 4C
 143 | | framesize=${9000} | phy_cores=${4}
 144
 145 | tc10-IMIX-1c-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 146 | | [Tags] | IMIX | 1C
 147 | | framesize=IMIX_v4_1 | phy_cores=${1}
 148
 149 | tc11-IMIX-2c-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 150 | | [Tags] | IMIX | 2C
 151 | | framesize=IMIX_v4_1 | phy_cores=${2}
 152
 153 | tc12-IMIX-4c-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 154 | | [Tags] | IMIX | 4C
 155 | | framesize=IMIX_v4_1 | phy_cores=${4}