tests/vpp/perf/vm_vhost/2n1l-10ge2p1x710-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | ...
  17 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  18 | ... | NIC_Intel-X710 | DOT1Q | L2BDMACLRN | BASE | VHOST | 1VM
  19 | ... | VHOST_1024
  20 | ...
  21 | Suite Setup | Set up 2-node performance topology with DUT's NIC model
  22 | ... | L2 | Intel-X710
  23 | Suite Teardown | Tear down 2-node performance topology
  24 | ...
  25 | Test Setup | Set up performance test
  26 | Test Teardown | Tear down performance test with vhost and VM with dpdk-testpmd
  27 | ... | ${min_rate}pps | ${framesize} | ${traffic_profile}
  28 | ... | dut1_node=${dut1} | dut1_vm_refs=${dut1_vm_refs}
  29 | ...
  30 | Test Template | Local Template
  31 | ...
  32 | Documentation | *RFC2544: Pkt throughput L2BD with vhost abd IEEE 802.1Q test
  33 | ... | cases*
  34 | ...
  35 | ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology with\
  36 | ... | single links between nodes.
  37 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 switching of IPv4. IEEE\
  38 | ... | 802.1Q tagging is applied on link between DUT1-if2 and TG-if2.
  39 | ... | *[Cfg] DUT configuration:* DUT1 is configured with L2 bridge-domain and\
  40 | ... | MAC learning enabled. Qemu Guest is connected to VPP via vhost-user\
  41 | ... | interfaces. Guest is running DPDK testpmd interconnecting vhost-user\
  42 | ... | interfaces, forwarding mode is set to io, rxd/txd=1024. DUT1 is tested\
  43 | ... | with 2p10GE NIC X710 by Intel.
  44 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop\
  45 | ... | Rate) with zero packet loss tolerance or throughput PDR (Partial Drop\
  46 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage\
  47 | ... | of packets transmitted. NDR and PDR are discovered for different\
  48 | ... | Ethernet L2 frame sizes using MLRsearch library. Test packets are\
  49 | ... | generated by TG on links to DUTs. TG traffic profile contains two L3\
  50 | ... | flow-groups (flow-group per direction, 254 flows per flow-group) with\
  51 | ... | all packets containing Ethernet header, IPv4 header with IP protocol=61\
  52 | ... | and static payload. MAC addresses are matching MAC addresses of the TG\
  53 | ... | node interfaces.
  54 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  55
  56 *** Variables ***
  57 | ${subid}= | 10
  58 | ${tag_rewrite}= | pop-1
  59 | ${overhead}= | ${4}
  60 # Socket names
  61 | ${bd_id1}= | 1
  62 | ${bd_id2}= | 2
  63 | ${sock1}= | /var/run/vpp/sock-1-${bd_id1}
  64 | ${sock2}= | /var/run/vpp/sock-1-${bd_id2}
  65 # X710 bandwidth limit
  66 | ${s_limit}= | ${10000000000}
  67 # Traffic profile:
  68 | ${traffic_profile}= | trex-sl-2n-dot1qip4asym-ip4src254
  69
  70 *** Keywords ***
  71 | Local Template
  72 | | [Documentation]
  73 | | ... | [Cfg] Each DUT runs L2BD switching with VLAN and uses ${phy_cores}\
  74 | | ... | physical core(s) for worker threads.
  75 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  76 | | ...
  77 | | ... | *Arguments:*
  78 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  79 | | ... | Type: integer, string
  80 | | ... | - phy_cores - Number of physical cores. Type: integer
  81 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  82 | | ...
  83 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  84 | | ...
  85 | | Set Test Variable | ${framesize}
  86 | | Set Test Variable | ${min_rate} | ${10000}
  87 | | ${dut1_vm_refs}= | Create Dictionary
  88 | | Set Test Variable | ${dut1_vm_refs}
  89 | | ...
  90 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  91 | | And Add PCI devices to all DUTs
  92 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
  93 | | ... | ${s_limit} | ${framesize} | overhead=${overhead}
  94 | | And Apply startup configuration on all VPP DUTs
  95 | | When Initialize L2 bridge domains with Vhost-User and VLAN in circular topology
  96 | | ... | ${bd_id1} | ${bd_id2} | ${sock1} | ${sock2} | ${subid}
  97 | | ... | ${tag_rewrite}
  98 | | And Configure guest VMs with dpdk-testpmd connected via vhost-user
  99 | | ... | jumbo=${jumbo} | perf_qemu_qsz=${1024} | use_tuned_cfs=${False}
 100 | | Then Find NDR and PDR intervals using optimized search
 101 | | ... | ${framesize} | ${traffic_profile} | ${min_rate} | ${max_rate}
 102
 103 *** Test Cases ***
 104 | tc01-64B-1c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 105 | | [Tags] | 64B | 1C
 106 | | framesize=${64} | phy_cores=${1}
 107
 108 | tc02-64B-2c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 109 | | [Tags] | 64B | 2C
 110 | | framesize=${64} | phy_cores=${2}
 111
 112 | tc03-64B-4c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 113 | | [Tags] | 64B | 4C
 114 | | framesize=${64} | phy_cores=${4}
 115
 116 | tc04-1518B-1c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 117 | | [Tags] | 1518B | 1C
 118 | | framesize=${1518} | phy_cores=${1}
 119
 120 | tc05-1518B-2c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 121 | | [Tags] | 1518B | 2C
 122 | | framesize=${1518} | phy_cores=${2}
 123
 124 | tc06-1518B-4c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 125 | | [Tags] | 1518B | 4C
 126 | | framesize=${1518} | phy_cores=${4}
 127
 128 | tc07-9000B-1c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 129 | | [Tags] | 9000B | 1C
 130 | | framesize=${9000} | phy_cores=${1}
 131
 132 | tc08-9000B-2c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 133 | | [Tags] | 9000B | 2C
 134 | | framesize=${9000} | phy_cores=${2}
 135
 136 | tc09-9000B-4c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 137 | | [Tags] | 9000B | 4C
 138 | | framesize=${9000} | phy_cores=${4}
 139
 140 | tc10-IMIX-1c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 141 | | [Tags] | IMIX | 1C
 142 | | framesize=IMIX_v4_1 | phy_cores=${1}
 143
 144 | tc11-IMIX-2c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 145 | | [Tags] | IMIX | 2C
 146 | | framesize=IMIX_v4_1 | phy_cores=${2}
 147
 148 | tc12-IMIX-4c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 149 | | [Tags] | IMIX | 4C
 150 | | framesize=IMIX_v4_1 | phy_cores=${4}