tests/vpp/perf/vm_vhost/2n1l-10ge2p1x710-eth-l2xcbase-eth-4vhostvr1024-2vm-ndrpdr.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | ...
  17 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  18 | ... | NIC_Intel-X710 | ETH | L2XCFWD | BASE | VHOST | 2VM | VHOST_1024
  19 | ...
  20 | Suite Setup | Set up 2-node performance topology with DUT's NIC model
  21 | ... | L2 | ${nic_name}
  22 | Suite Teardown | Tear down 2-node performance topology
  23 | ...
  24 | Test Setup | Set up performance test
  25 | Test Teardown | Tear down performance test with vhost and VM with dpdk-testpmd
  26 | ... | dut1_node=${dut1} | dut1_vm_refs=${dut1_vm_refs}
  27 | ...
  28 | Test Template | Local Template
  29 | ...
  30 | Documentation | *RFC2544: Pkt throughput L2XC test cases with vhost*
  31 | ...
  32 | ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology
  33 | ... | with single links between nodes.
  34 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 switching of IPv4.
  35 | ... | *[Cfg] DUT configuration:* DUT1 is configured with L2 cross-
  36 | ... | connect. Qemu Guest is connected to VPP via vhost-user interfaces.
  37 | ... | Guest is running DPDK testpmd interconnecting vhost-user interfaces,
  38 | ... | forwarding mode is set to io, rxd/txd=256. DUT1 is tested
  39 | ... | with ${nic_name}.\
  40 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop\
  41 | ... | Rate) with zero packet loss tolerance and throughput PDR (Partial Drop\
  42 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage\
  43 | ... | of packets transmitted. NDR and PDR are discovered for different\
  44 | ... | Ethernet L2 frame sizes using MLRsearch library.\
  45 | ... | Test packets are generated by TG on links to DUTs. TG traffic profile
  46 | ... | contains two L3 flow-groups (flow-group per direction, 254 flows per
  47 | ... | flow-group) with all packets containing Ethernet header, IPv4 header
  48 | ... | with IP protocol=61 and static payload. MAC addresses are matching MAC
  49 | ... | addresses of the TG node interfaces.
  50
  51 *** Variables ***
  52 | ${nic_name}= | Intel-X710
  53 | ${overhead}= | ${0}
  54 # Traffic profile:
  55 | ${traffic_profile}= | trex-sl-2n-ethip4-ip4src254
  56
  57 *** Keywords ***
  58 | Local Template
  59 | | [Documentation]
  60 | | ... | [Cfg] DUT runs L2XC switching config.
  61 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  62 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  63 | | ...
  64 | | ... | *Arguments:*
  65 | | ... | - frame_size - Framesize in Bytes in integer or string (IMIX_v4_1).
  66 | | ... | Type: integer, string
  67 | | ... | - phy_cores - Number of physical cores. Type: integer
  68 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  69 | | ...
  70 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  71 | | ...
  72 | | Set Test Variable | \${frame_size}
  73 | | ...
  74 | | ${dut1_vm_refs}= | Create Dictionary
  75 | | Set Test Variable | ${dut1_vm_refs}
  76 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  77 | | And Add PCI devices to all DUTs
  78 | | Set Max Rate And Jumbo And Handle Multi Seg
  79 | | And Apply startup configuration on all VPP DUTs
  80 | | When Initialize L2 xconnect with Vhost-User | vm_count=${2}
  81 | | And Configure guest VMs with dpdk-testpmd connected via vhost-user
  82 | | ... | vm_count=${2} | jumbo=${jumbo} | perf_qemu_qsz=${1024}
  83 | | ... | use_tuned_cfs=${False}
  84 | | Then Find NDR and PDR intervals using optimized search
  85
  86 *** Test Cases ***
  87 | tc01-64B-1c-eth-l2xcbase-eth-4vhostvr1024-2vm-ndrpdr
  88 | | [Tags] | 64B | 1C
  89 | | frame_size=${64} | phy_cores=${1}
  90
  91 | tc02-64B-2c-eth-l2xcbase-eth-4vhostvr1024-2vm-ndrpdr
  92 | | [Tags] | 64B | 2C
  93 | | frame_size=${64} | phy_cores=${2}
  94
  95 | tc03-64B-4c-eth-l2xcbase-eth-4vhostvr1024-2vm-ndrpdr
  96 | | [Tags] | 64B | 4C
  97 | | frame_size=${64} | phy_cores=${4}
  98
  99 | tc04-1518B-1c-eth-l2xcbase-eth-4vhostvr1024-2vm-ndrpdr
 100 | | [Tags] | 1518B | 1C
 101 | | frame_size=${1518} | phy_cores=${1}
 102
 103 | tc05-1518B-2c-eth-l2xcbase-eth-4vhostvr1024-2vm-ndrpdr
 104 | | [Tags] | 1518B | 2C
 105 | | frame_size=${1518} | phy_cores=${2}
 106
 107 | tc06-1518B-4c-eth-l2xcbase-eth-4vhostvr1024-2vm-ndrpdr
 108 | | [Tags] | 1518B | 4C
 109 | | frame_size=${1518} | phy_cores=${4}
 110
 111 | tc07-9000B-1c-eth-l2xcbase-eth-4vhostvr1024-2vm-ndrpdr
 112 | | [Tags] | 9000B | 1C
 113 | | frame_size=${9000} | phy_cores=${1}
 114
 115 | tc08-9000B-2c-eth-l2xcbase-eth-4vhostvr1024-2vm-ndrpdr
 116 | | [Tags] | 9000B | 2C
 117 | | frame_size=${9000} | phy_cores=${2}
 118
 119 | tc09-9000B-4c-eth-l2xcbase-eth-4vhostvr1024-2vm-ndrpdr
 120 | | [Tags] | 9000B | 4C
 121 | | frame_size=${9000} | phy_cores=${4}
 122
 123 | tc10-IMIX-1c-eth-l2xcbase-eth-4vhostvr1024-2vm-ndrpdr
 124 | | [Tags] | IMIX | 1C
 125 | | frame_size=IMIX_v4_1 | phy_cores=${1}
 126
 127 | tc11-IMIX-2c-eth-l2xcbase-eth-4vhostvr1024-2vm-ndrpdr
 128 | | [Tags] | IMIX | 2C
 129 | | frame_size=IMIX_v4_1 | phy_cores=${2}
 130
 131 | tc12-IMIX-4c-eth-l2xcbase-eth-4vhostvr1024-2vm-ndrpdr
 132 | | [Tags] | IMIX | 4C
 133 | | frame_size=IMIX_v4_1 | phy_cores=${4}