tests/vpp/perf/vm_vhost/2n1l-25ge2p1xxv710-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Library | resources.libraries.python.QemuUtils
  17 | ...
  18 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  19 | ... | NIC_Intel-XXV710 | DOT1Q | L2BDMACLRN | BASE | VHOST | 1VM
  20 | ... | VHOST_1024
  21 | ...
  22 | Suite Setup | Set up 2-node performance topology with DUT's NIC model
  23 | ... | L2 | Intel-XXV710
  24 | Suite Teardown | Tear down 2-node performance topology
  25 | ...
  26 | Test Setup | Set up performance test
  27 | Test Teardown | Tear down performance test with vhost and VM with dpdk-testpmd
  28 | ... | ${min_rate}pps | ${framesize} | ${traffic_profile}
  29 | ... | dut1_node=${dut1} | dut1_vm_refs=${dut1_vm_refs}
  30 | ...
  31 | Test Template | Local Template
  32 | ...
  33 | Documentation | *RFC2544: Pkt throughput L2BD with vhost abd IEEE 802.1Q test
  34 | ... | cases*
  35 | ...
  36 | ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology with\
  37 | ... | single links between nodes.
  38 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 switching of IPv4. IEEE\
  39 | ... | 802.1Q tagging is applied on link between DUT1-if2 and TG-if2.
  40 | ... | *[Cfg] DUT configuration:* DUT1 is configured with L2 bridge-domain and\
  41 | ... | MAC learning enabled. Qemu Guest is connected to VPP via vhost-user\
  42 | ... | interfaces. Guest is running DPDK testpmd interconnecting vhost-user\
  43 | ... | interfaces, forwarding mode is set to io, rxd/txd=1024. DUT1 is tested\
  44 | ... | with 2p25GE NIC XXV710 by Intel.
  45 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop\
  46 | ... | Rate) with zero packet loss tolerance or throughput PDR (Partial Drop\
  47 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage\
  48 | ... | of packets transmitted. NDR and PDR are discovered for different\
  49 | ... | Ethernet L2 frame sizes using MLRsearch library. Test packets are\
  50 | ... | generated by TG on links to DUTs. TG traffic profile contains two L3\
  51 | ... | flow-groups (flow-group per direction, 254 flows per flow-group) with\
  52 | ... | all packets containing Ethernet header, IPv4 header with IP protocol=61\
  53 | ... | and static payload. MAC addresses are matching MAC addresses of the TG\
  54 | ... | node interfaces.
  55 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  56
  57 *** Variables ***
  58 | ${subid}= | 10
  59 | ${tag_rewrite}= | pop-1
  60 | ${overhead}= | ${4}
  61 # Socket names
  62 | ${bd_id1}= | 1
  63 | ${bd_id2}= | 2
  64 | ${sock1}= | /tmp/sock-1-${bd_id1}
  65 | ${sock2}= | /tmp/sock-1-${bd_id2}
  66 # XXV710-DA2 bandwidth limit ~49Gbps/2=24.5Gbps
  67 | ${s_24.5G}= | ${24500000000}
  68 # XXV710-DA2 Mpps limit 37.5Mpps/2=18.75Mpps
  69 | ${s_18.75Mpps}= | ${18750000}
  70 # Traffic profile:
  71 | ${traffic_profile}= | trex-sl-2n-dot1qip4asym-ip4src254
  72
  73 *** Keywords ***
  74 | Local Template
  75 | | [Documentation]
  76 | | ... | [Cfg] Each DUT runs L2BD switching with VLAN and uses ${phy_cores}\
  77 | | ... | physical core(s) for worker threads.
  78 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  79 | | ...
  80 | | ... | *Arguments:*
  81 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  82 | | ... | Type: integer, string
  83 | | ... | - phy_cores - Number of physical cores. Type: integer
  84 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  85 | | ...
  86 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  87 | | ...
  88 | | Set Test Variable | ${framesize}
  89 | | Set Test Variable | ${min_rate} | ${10000}
  90 | | ${dut1_vm_refs}= | Create Dictionary
  91 | | Set Test Variable | ${dut1_vm_refs}
  92 | | ...
  93 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  94 | | And Add PCI devices to all DUTs
  95 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
  96 | | ... | ${s_24.5G} | ${framesize} | pps_limit=${s_18.75Mpps}
  97 | | ... | overhead=${overhead}
  98 | | And Apply startup configuration on all VPP DUTs
  99 | | When Initialize L2 bridge domains with Vhost-User and VLAN in circular topology
 100 | | ... | ${bd_id1} | ${bd_id2} | ${sock1} | ${sock2} | ${subid}
 101 | | ... | ${tag_rewrite}
 102 | | ${vm1}= | And Configure guest VM with dpdk-testpmd connected via vhost-user
 103 | | ... | DUT1 | ${sock1} | ${sock2} | DUT1_VM1 | jumbo=${jumbo}
 104 | | ... | perf_qemu_qsz=${1024} | use_tuned_cfs=${False}
 105 | | Set To Dictionary | ${dut1_vm_refs} | DUT1_VM1 | ${vm1}
 106 | | Then Find NDR and PDR intervals using optimized search
 107 | | ... | ${framesize} | ${traffic_profile} | ${min_rate} | ${max_rate}
 108
 109 *** Test Cases ***
 110 | tc01-64B-1c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 111 | | [Tags] | 64B | 1C
 112 | | framesize=${64} | phy_cores=${1}
 113
 114 | tc02-64B-2c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 115 | | [Tags] | 64B | 2C
 116 | | framesize=${64} | phy_cores=${2}
 117
 118 | tc03-64B-4c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 119 | | [Tags] | 64B | 4C
 120 | | framesize=${64} | phy_cores=${4}
 121
 122 | tc04-1518B-1c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 123 | | [Tags] | 1518B | 1C
 124 | | framesize=${1518} | phy_cores=${1}
 125
 126 | tc05-1518B-2c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 127 | | [Tags] | 1518B | 2C
 128 | | framesize=${1518} | phy_cores=${2}
 129
 130 | tc06-1518B-4c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 131 | | [Tags] | 1518B | 4C
 132 | | framesize=${1518} | phy_cores=${4}
 133
 134 | tc07-9000B-1c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 135 | | [Tags] | 9000B | 1C
 136 | | framesize=${9000} | phy_cores=${1}
 137
 138 | tc08-9000B-2c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 139 | | [Tags] | 9000B | 2C
 140 | | framesize=${9000} | phy_cores=${2}
 141
 142 | tc09-9000B-4c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 143 | | [Tags] | 9000B | 4C
 144 | | framesize=${9000} | phy_cores=${4}
 145
 146 | tc10-IMIX-1c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 147 | | [Tags] | IMIX | 1C
 148 | | framesize=IMIX_v4_1 | phy_cores=${1}
 149
 150 | tc11-IMIX-2c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 151 | | [Tags] | IMIX | 2C
 152 | | framesize=IMIX_v4_1 | phy_cores=${2}
 153
 154 | tc12-IMIX-4c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 155 | | [Tags] | IMIX | 4C
 156 | | framesize=IMIX_v4_1 | phy_cores=${4}