tests/vpp/perf/vm_vhost/2n1l-25ge2p1xxv710-eth-l2xcbase-eth-2vhostvr256-1vm-ndrpdr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Library | resources.libraries.python.QemuUtils
  17 | ...
  18 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  19 | ... | NIC_Intel-XXV710 | ETH | L2XCFWD | BASE | VHOST | 1VM | VHOST_256
  20 | ...
  21 | Suite Setup | Set up 2-node performance topology with DUT's NIC model
  22 | ... | L2 | Intel-XXV710
  23 | Suite Teardown | Tear down 2-node performance topology
  24 | ...
  25 | Test Setup | Set up performance test
  26 | Test Teardown | Tear down performance test with vhost and VM with dpdk-testpmd
  27 | ... | ${min_rate}pps | ${framesize} | ${traffic_profile}
  28 | ... | dut1_node=${dut1} | dut1_vm_refs=${dut1_vm_refs}
  29 | ...
  30 | Test Template | Local Template
  31 | ...
  32 | Documentation | *RFC2544: Pkt throughput L2XC test cases with vhost*
  33 | ...
  34 | ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology
  35 | ... | with single links between nodes.
  36 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 switching of IPv4. 802.1q
  37 | ... | tagging is applied on link between DUT1 and DUT2.
  38 | ... | *[Cfg] DUT configuration:* DUT1 is configured with L2 cross-
  39 | ... | connect. Qemu Guest is connected to VPP via vhost-user interfaces.
  40 | ... | Guest is running DPDK testpmd interconnecting vhost-user interfaces,
  41 | ... | forwarding mode is set to io, rxd/txd=256. DUT1 is tested with 2p25GE
  42 | ... | NIC XXV710 by Intel.
  43 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop
  44 | ... | Rate) with zero packet loss tolerance or throughput PDR (Partial Drop
  45 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage
  46 | ... | of packets transmitted. NDR and PDR are discovered for different
  47 | ... | Ethernet L2 frame sizes using MLRsearch library.
  48 | ... | Test packets are generated by TG on links to DUTs. TG traffic profile
  49 | ... | contains two L3 flow-groups (flow-group per direction, 254 flows per
  50 | ... | flow-group) with all packets containing Ethernet header, IPv4 header
  51 | ... | with IP protocol=61 and static payload. MAC addresses are matching MAC
  52 | ... | addresses of the TG node interfaces.
  53
  54 *** Variables ***
  55 # XXV710-DA2 bandwidth limit ~49Gbps/2=24.5Gbps
  56 | ${s_24.5G}= | ${24500000000}
  57 # XXV710-DA2 Mpps limit 37.5Mpps/2=18.75Mpps
  58 | ${s_18.75Mpps}= | ${18750000}
  59 # Traffic profile:
  60 | ${traffic_profile}= | trex-sl-2n-ethip4-ip4src254
  61
  62 *** Keywords ***
  63 | Local Template
  64 | | [Documentation]
  65 | | ... | [Cfg] DUT runs L2XC switching config.
  66 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  67 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  68 | | ...
  69 | | ... | *Arguments:*
  70 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  71 | | ... | Type: integer, string
  72 | | ... | - phy_cores - Number of physical cores. Type: integer
  73 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  74 | | ...
  75 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  76 | | ...
  77 | | Set Test Variable | ${framesize}
  78 | | Set Test Variable | ${min_rate} | ${10000}
  79 | | ${dut1_vm_refs}= | Create Dictionary
  80 | | Set Test Variable | ${dut1_vm_refs}
  81 | | ...
  82 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  83 | | And Add PCI devices to all DUTs
  84 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
  85 | | ... | ${s_24.5G} | ${framesize} | pps_limit=${s_18.75Mpps}
  86 | | And Apply startup configuration on all VPP DUTs
  87 | | When Initialize L2 xconnect with Vhost-User | vm_count=${1}
  88 | | And Configure guest VMs with dpdk-testpmd connected via vhost-user
  89 | | ... | vm_count=${1} | jumbo=${jumbo} | perf_qemu_qsz=${256}
  90 | | ... | use_tuned_cfs=${False}
  91 | | Then Find NDR and PDR intervals using optimized search
  92 | | ... | ${framesize} | ${traffic_profile} | ${min_rate} | ${max_rate}
  93
  94 *** Test Cases ***
  95 | tc01-64B-1c-eth-l2xcbase-eth-2vhostvr256-1vm-ndrpdr
  96 | | [Tags] | 64B | 1C
  97 | | framesize=${64} | phy_cores=${1}
  98
  99 | tc02-64B-2c-eth-l2xcbase-eth-2vhostvr256-1vm-ndrpdr
 100 | | [Tags] | 64B | 2C
 101 | | framesize=${64} | phy_cores=${2}
 102
 103 | tc03-64B-4c-eth-l2xcbase-eth-2vhostvr256-1vm-ndrpdr
 104 | | [Tags] | 64B | 4C
 105 | | framesize=${64} | phy_cores=${4}
 106
 107 | tc04-1518B-1c-eth-l2xcbase-eth-2vhostvr256-1vm-ndrpdr
 108 | | [Tags] | 1518B | 1C
 109 | | framesize=${1518} | phy_cores=${1}
 110
 111 | tc05-1518B-2c-eth-l2xcbase-eth-2vhostvr256-1vm-ndrpdr
 112 | | [Tags] | 1518B | 2C
 113 | | framesize=${1518} | phy_cores=${2}
 114
 115 | tc06-1518B-4c-eth-l2xcbase-eth-2vhostvr256-1vm-ndrpdr
 116 | | [Tags] | 1518B | 4C
 117 | | framesize=${1518} | phy_cores=${4}
 118
 119 | tc07-9000B-1c-eth-l2xcbase-eth-2vhostvr256-1vm-ndrpdr
 120 | | [Tags] | 9000B | 1C
 121 | | framesize=${9000} | phy_cores=${1}
 122
 123 | tc08-9000B-2c-eth-l2xcbase-eth-2vhostvr256-1vm-ndrpdr
 124 | | [Tags] | 9000B | 2C
 125 | | framesize=${9000} | phy_cores=${2}
 126
 127 | tc09-9000B-4c-eth-l2xcbase-eth-2vhostvr256-1vm-ndrpdr
 128 | | [Tags] | 9000B | 4C
 129 | | framesize=${9000} | phy_cores=${4}
 130
 131 | tc10-IMIX-1c-eth-l2xcbase-eth-2vhostvr256-1vm-ndrpdr
 132 | | [Tags] | IMIX | 1C
 133 | | framesize=IMIX_v4_1 | phy_cores=${1}
 134
 135 | tc11-IMIX-2c-eth-l2xcbase-eth-2vhostvr256-1vm-ndrpdr
 136 | | [Tags] | IMIX | 2C
 137 | | framesize=IMIX_v4_1 | phy_cores=${2}
 138
 139 | tc12-IMIX-4c-eth-l2xcbase-eth-2vhostvr256-1vm-ndrpdr
 140 | | [Tags] | IMIX | 4C
 141 | | framesize=IMIX_v4_1 | phy_cores=${4}