tests/vpp/perf/vm_vhost/40ge2p1xl710-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Library | resources.libraries.python.QemuUtils
  17 | ...
  18 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | MRR
  19 | ... | NIC_Intel-XL710 | ETH | L2BDMACLRN | BASE | VHOST | 1VM | VHOST_1024
  20 | ...
  21 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  22 | ... | L2 | Intel-XL710
  23 | Suite Teardown | Tear down 3-node performance topology
  24 | ...
  25 | Test Setup | Set up performance test
  26 | Test Teardown | Tear down performance mrr test with vhost and VM with dpdk-testpmd
  27 | ... | dut1_node=${dut1} | dut1_vm_refs=${dut1_vm_refs}
  28 | ... | dut2_node=${dut2} | dut2_vm_refs=${dut2_vm_refs}
  29 | ...
  30 | Documentation | *Raw results L2BD test cases with vhost*
  31 | ...
  32 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  33 | ... | with single links between nodes.
  34 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 switching of IPv4.
  35 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2 bridge-
  36 | ... | domain and MAC learning enabled. Qemu Guests are connected to VPP via
  37 | ... | vhost-user interfaces. Guests are running DPDK testpmd interconnecting
  38 | ... | vhost-user interfaces using 5 cores pinned to cpus on NUMA1 and 2048M
  39 | ... | memory. Testpmd is using socket-mem=1024M (512x2M hugepages), 5 cores
  40 | ... | (1 main core and 4 cores dedicated for io), forwarding mode is set to
  41 | ... | io, rxd/txd=1024, burst=64. DUT1, DUT2 are tested with 2p40GE NIC XL710
  42 | ... | by Intel.
  43 | ... | *[Ver] TG verification:* In MaxReceivedRate test TG sends traffic
  44 | ... | at line rate and reports total received/sent packets over trial period.
  45 | ... | Test packets are generated by TG on links to DUTs. TG traffic profile
  46 | ... | contains two L3 flow-groups (flow-group per direction, 253 flows per
  47 | ... | flow-group) with all packets containing Ethernet header, IPv4 header
  48 | ... | with IP protocol=61 and static payload. MAC addresses are matching MAC
  49 | ... | addresses of the TG node interfaces.
  50
  51 *** Variables ***
  52 | ${perf_qemu_qsz}= | 1024
  53 # Socket names
  54 | ${bd_id1}= | 1
  55 | ${bd_id2}= | 2
  56 | ${sock1}= | /tmp/sock-1-${bd_id1}
  57 | ${sock2}= | /tmp/sock-1-${bd_id2}
  58 # XL710-DA2 bandwidth limit ~49Gbps/2=24.5Gbps
  59 | ${s_24.5G}= | ${24500000000}
  60 # XL710-DA2 Mpps limit 37.5Mpps/2=18.75Mpps
  61 | ${s_18.75Mpps}= | ${18750000}
  62 # Traffic profile:
  63 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4src254
  64
  65 *** Keywords ***
  66 | Check RR for eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm
  67 | | [Documentation]
  68 | | ... | [Cfg] DUT runs L2BD switching config with ${wt} thread, ${wt} phy\
  69 | | ... | core, ${rxq} receive queue per NIC port.
  70 | | ... | [Ver] Measure MaxReceivedRate for ${framesize} frames using single\
  71 | | ... | trial throughput test.
  72 | | ...
  73 | | [Arguments] | ${framesize} | ${wt} | ${rxq}
  74 | | ...
  75 | | # Test Variables required for test and test teardown
  76 | | Set Test Variable | ${framesize}
  77 | | ${get_framesize}= | Get Frame Size | ${framesize}
  78 | | ${max_rate}= | Calculate pps | ${s_24.5G} | ${get_framesize}
  79 | | ${max_rate}= | Set Variable If
  80 | | ... | ${max_rate} > ${s_18.75Mpps} | ${s_18.75Mpps} | ${max_rate}
  81 | | ${dut1_vm_refs}= | Create Dictionary
  82 | | ${dut2_vm_refs}= | Create Dictionary
  83 | | Set Test Variable | ${dut1_vm_refs}
  84 | | Set Test Variable | ${dut2_vm_refs}
  85 | | ${jumbo_frames}= | Set Variable If | ${get_framesize} < ${1522}
  86 | | ... | ${False} | ${True}
  87 | | ...
  88 | | Given Add '${wt}' worker threads and '${rxq}' rxqueues in 3-node single-link circular topology
  89 | | And Add PCI devices to all DUTs
  90 | | And Run Keyword If | ${get_framesize} < ${1522}
  91 | | ... | Add no multi seg to all DUTs
  92 | | And Apply startup configuration on all VPP DUTs
  93 | | When Initialize L2 bridge domains with Vhost-User in 3-node circular topology
  94 | | ... | ${bd_id1} | ${bd_id2} | ${sock1} | ${sock2}
  95 | | ${vm1}= | And Configure guest VM with dpdk-testpmd connected via vhost-user
  96 | | ... | ${dut1} | ${sock1} | ${sock2} | DUT1_VM1
  97 | | ... | jumbo_frames=${jumbo_frames}
  98 | | Set To Dictionary | ${dut1_vm_refs} | DUT1_VM1 | ${vm1}
  99 | | ${vm2}= | And Configure guest VM with dpdk-testpmd connected via vhost-user
 100 | | ... | ${dut2} | ${sock1} | ${sock2} | DUT2_VM1
 101 | | ... | jumbo_frames=${jumbo_frames}
 102 | | Set To Dictionary | ${dut2_vm_refs} | DUT2_VM1 | ${vm2}
 103 | | Then Traffic should pass with maximum rate
 104 | | ... | ${max_rate}pps | ${framesize} | ${traffic_profile}
 105
 106 *** Test Cases ***
 107 | tc01-64B-1t1c-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 108 | | [Documentation]
 109 | | ... | [Cfg] DUT runs L2BD switching config with 1 phy\
 110 | | ... | core, 1 receive queue per NIC port.
 111 | | ... | [Ver] Measure MaxReceivedRate for 64B frames using single\
 112 | | ... | trial throughput test.
 113 | | ...
 114 | | [Tags] | 64B | 1C
 115 | | ...
 116 | | [Template] | Check RR for eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm
 117 | | framesize=${64} | wt=1 | rxq=1
 118
 119 | tc02-1518B-1t1c-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 120 | | [Documentation]
 121 | | ... | [Cfg] DUT runs L2BD switching config with 1 phy\
 122 | | ... | core, 1 receive queue per NIC port.
 123 | | ... | [Ver] Measure MaxReceivedRate for 1518B frames using single\
 124 | | ... | trial throughput test.
 125 | | ...
 126 | | [Tags] | 1518B | 1C
 127 | | ...
 128 | | [Template] | Check RR for eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm
 129 | | framesize=${1518} | wt=1 | rxq=1
 130
 131 | tc03-9000B-1t1c-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 132 | | [Documentation]
 133 | | ... | [Cfg] DUT runs L2BD switching config with 1 phy\
 134 | | ... | core, 1 receive queue per NIC port.
 135 | | ... | [Ver] Measure MaxReceivedRate for 9000B frames using single\
 136 | | ... | trial throughput test.
 137 | | ...
 138 | | [Tags] | 9000B | 1C
 139 | | ...
 140 | | [Template] | Check RR for eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm
 141 | | framesize=${9000} | wt=1 | rxq=1
 142
 143 | tc04-IMIX-1t1c-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 144 | | [Documentation]
 145 | | ... | [Cfg] DUT runs L2BD switching config with 1 phy\
 146 | | ... | core, 1 receive queue per NIC port.
 147 | | ... | [Ver] Measure MaxReceivedRate for IMIX_v4_1 frames using single\
 148 | | ... | trial throughput test.
 149 | | ... | IMIX_v4_1 = (28x64B; 16x570B; 4x1518B)
 150 | | ...
 151 | | [Tags] | IMIX | 1C
 152 | | ...
 153 | | [Template] | Check RR for eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm
 154 | | framesize=IMIX_v4_1 | wt=1 | rxq=1
 155
 156 | tc05-64B-2t2c-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 157 | | [Documentation]
 158 | | ... | [Cfg] DUT runs L2BD switching config with 2 phy\
 159 | | ... | cores, 1 receive queue per NIC port.
 160 | | ... | [Ver] Measure MaxReceivedRate for 64B frames using single\
 161 | | ... | trial throughput test.
 162 | | ...
 163 | | [Tags] | 64B | 2C
 164 | | ...
 165 | | [Template] | Check RR for eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm
 166 | | framesize=${64} | wt=2 | rxq=1
 167
 168 | tc06-1518B-2t2c-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 169 | | [Documentation]
 170 | | ... | [Cfg] DUT runs L2BD switching config with 2 phy\
 171 | | ... | cores, 1 receive queue per NIC port.
 172 | | ... | [Ver] Measure MaxReceivedRate for 1518B frames using single\
 173 | | ... | trial throughput test.
 174 | | ...
 175 | | [Tags] | 1518B | 2C
 176 | | ...
 177 | | [Template] | Check RR for eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm
 178 | | framesize=${1518} | wt=2 | rxq=1
 179
 180 | tc07-9000B-2t2c-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 181 | | [Documentation]
 182 | | ... | [Cfg] DUT runs L2BD switching config with 2 phy\
 183 | | ... | cores, 1 receive queue per NIC port.
 184 | | ... | [Ver] Measure MaxReceivedRate for 9000B frames using single\
 185 | | ... | trial throughput test.
 186 | | ...
 187 | | [Tags] | 9000B | 2C
 188 | | ...
 189 | | [Template] | Check RR for eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm
 190 | | framesize=${9000} | wt=2 | rxq=1
 191
 192 | tc08-IMIX-2t2c-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 193 | | [Documentation]
 194 | | ... | [Cfg] DUT runs L2BD switching config with 2 phy\
 195 | | ... | cores, 1 receive queue per NIC port.
 196 | | ... | [Ver] Measure MaxReceivedRate for IMIX_v4_1 frames using single\
 197 | | ... | trial throughput test.
 198 | | ... | IMIX_v4_1 = (28x64B; 16x570B; 4x1518B)
 199 | | ...
 200 | | [Tags] | IMIX | 2C
 201 | | ...
 202 | | [Template] | Check RR for eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm
 203 | | framesize=IMIX_v4_1 | wt=2 | rxq=1
 204
 205 | tc09-64B-4t4c-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 206 | | [Documentation]
 207 | | ... | [Cfg] DUT runs L2BD switching config with 4 phy\
 208 | | ... | cores, 2 receive queues per NIC port.
 209 | | ... | [Ver] Measure MaxReceivedRate for 64B frames using single\
 210 | | ... | trial throughput test.
 211 | | ...
 212 | | [Tags] | 64B | 4C
 213 | | ...
 214 | | [Template] | Check RR for eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm
 215 | | framesize=${64} | wt=4 | rxq=2
 216
 217 | tc10-1518B-4t4c-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 218 | | [Documentation]
 219 | | ... | [Cfg] DUT runs L2BD switching config with 4 phy\
 220 | | ... | cores, 2 receive queues per NIC port.
 221 | | ... | [Ver] Measure MaxReceivedRate for 1518B frames using single\
 222 | | ... | trial throughput test.
 223 | | ...
 224 | | [Tags] | 1518B | 4C
 225 | | ...
 226 | | [Template] | Check RR for eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm
 227 | | framesize=${1518} | wt=4 | rxq=2
 228
 229 | tc11-9000B-4t4c-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 230 | | [Documentation]
 231 | | ... | [Cfg] DUT runs L2BD switching config with 4 phy\
 232 | | ... | cores, 2 receive queues per NIC port.
 233 | | ... | [Ver] Measure MaxReceivedRate for 9000B frames using single\
 234 | | ... | trial throughput test.
 235 | | ...
 236 | | [Tags] | 9000B | 4C
 237 | | ...
 238 | | [Template] | Check RR for eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm
 239 | | framesize=${9000} | wt=4 | rxq=2
 240
 241 | tc12-IMIX-4t4c-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 242 | | [Documentation]
 243 | | ... | [Cfg] DUT runs L2BD switching config with 4 phy\
 244 | | ... | cores, 2 receive queues per NIC port.
 245 | | ... | [Ver] Measure MaxReceivedRate for IMIX_v4_1 frames using single\
 246 | | ... | trial throughput test.
 247 | | ... | IMIX_v4_1 = (28x64B; 16x570B; 4x1518B)
 248 | | ...
 249 | | [Tags] | IMIX | 4C
 250 | | ...
 251 | | [Template] | Check RR for eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm
 252 | | framesize=IMIX_v4_1 | wt=4 | rxq=2