tests/vpp/perf/vm_vhost/40ge2p1xl710-eth-l2bdbasemaclrn-eth-4vhostvr1024-2vm-ndrpdr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | ...
  17 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  18 | ... | NIC_Intel-XL710 | ETH | L2BDMACLRN | BASE | VHOST | 2VM | VHOST_1024
  19 | ...
  20 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  21 | ... | L2 | Intel-XL710
  22 | Suite Teardown | Tear down 3-node performance topology
  23 | ...
  24 | Test Setup | Set up performance test
  25 | Test Teardown | Tear down performance test with vhost and VM with dpdk-testpmd
  26 | ... | ${min_rate}pps | ${framesize} | ${traffic_profile}
  27 | ... | dut1_node=${dut1} | dut1_vm_refs=${dut1_vm_refs}
  28 | ... | dut2_node=${dut2} | dut2_vm_refs=${dut2_vm_refs}
  29 | ...
  30 | Test Template | Local Template
  31 | ...
  32 | Documentation | *RFC2544: Pkt throughput L2BD test cases with vhost*
  33 | ...
  34 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  35 | ... | with single links between nodes.
  36 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 switching of IPv4.
  37 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2 bridge-
  38 | ... | domain and MAC learning enabled. Qemu Guests are connected to VPP via
  39 | ... | vhost-user interfaces. Guests are running DPDK testpmd interconnecting
  40 | ... | vhost-user interfaces using 5 cores pinned to cpus on NUMA1 and 2048M
  41 | ... | memory. Testpmd is using socket-mem=1024M (512x2M hugepages), 5 cores
  42 | ... | (1 main core and 4 cores dedicated for io), forwarding mode is set to
  43 | ... | io, rxd/txd=1024, burst=64. DUT1, DUT2 are tested with 2p40GE NIC XL710
  44 | ... | by Intel.
  45 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop
  46 | ... | Rate) with zero packet loss tolerance or throughput PDR (Partial Drop
  47 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage
  48 | ... | of packets transmitted. NDR and PDR are discovered for different
  49 | ... | Ethernet L2 frame sizes using MLRsearch library.
  50 | ... | Test packets are generated by TG on links to DUTs. TG traffic profile
  51 | ... | contains two L3 flow-groups (flow-group per direction, 253 flows per
  52 | ... | flow-group) with all packets containing Ethernet header, IPv4 header
  53 | ... | with IP protocol=61 and static payload. MAC addresses are matching MAC
  54 | ... | addresses of the TG node interfaces.
  55
  56 *** Variables ***
  57 # XL710-DA2 bandwidth limit ~49Gbps/2=24.5Gbps
  58 | ${s_24.5G}= | ${24500000000}
  59 # XL710-DA2 Mpps limit 37.5Mpps/2=18.75Mpps
  60 | ${s_18.75Mpps}= | ${18750000}
  61 # Traffic profile:
  62 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4src254
  63
  64 *** Keywords ***
  65 | Local Template
  66 | | [Documentation]
  67 | | ... | [Cfg] DUT runs L2BD switching config.
  68 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  69 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  70 | | ...
  71 | | ... | *Arguments:*
  72 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  73 | | ... | Type: integer, string
  74 | | ... | - phy_cores - Number of physical cores. Type: integer
  75 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  76 | | ...
  77 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  78 | | ...
  79 | | Set Test Variable | ${framesize}
  80 | | Set Test Variable | ${min_rate} | ${10000}
  81 | | ${dut1_vm_refs}= | Create Dictionary
  82 | | ${dut2_vm_refs}= | Create Dictionary
  83 | | Set Test Variable | ${dut1_vm_refs}
  84 | | Set Test Variable | ${dut2_vm_refs}
  85 | | ...
  86 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  87 | | And Add PCI devices to all DUTs
  88 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
  89 | | ... | ${s_24.5G} | ${framesize} | pps_limit=${s_18.75Mpps}
  90 | | And Apply startup configuration on all VPP DUTs
  91 | | When Initialize L2 bridge domains with Vhost-User | nf_nodes=${2}
  92 | | And Configure guest VMs with dpdk-testpmd connected via vhost-user
  93 | | ... | vm_count=${2} | jumbo=${jumbo} | perf_qemu_qsz=${1024}
  94 | | ... | use_tuned_cfs=${False}
  95 | | Then Find NDR and PDR intervals using optimized search
  96 | | ... | ${framesize} | ${traffic_profile} | ${min_rate} | ${max_rate}
  97
  98 *** Test Cases ***
  99 | tc01-64B-1c-eth-l2bdbasemaclrn-eth-4vhostvr1024-2vm-ndrpdr
 100 | | [Tags] | 64B | 1C
 101 | | framesize=${64} | phy_cores=${1}
 102
 103 | tc02-64B-2c-eth-l2bdbasemaclrn-eth-4vhostvr1024-2vm-ndrpdr
 104 | | [Tags] | 64B | 2C
 105 | | framesize=${64} | phy_cores=${2}
 106
 107 | tc03-64B-4c-eth-l2bdbasemaclrn-eth-4vhostvr1024-2vm-ndrpdr
 108 | | [Tags] | 64B | 4C
 109 | | framesize=${64} | phy_cores=${4}
 110
 111 | tc04-1518B-1c-eth-l2bdbasemaclrn-eth-4vhostvr1024-2vm-ndrpdr
 112 | | [Tags] | 1518B | 1C
 113 | | framesize=${1518} | phy_cores=${1}
 114
 115 | tc05-1518B-2c-eth-l2bdbasemaclrn-eth-4vhostvr1024-2vm-ndrpdr
 116 | | [Tags] | 1518B | 2C
 117 | | framesize=${1518} | phy_cores=${2}
 118
 119 | tc06-1518B-4c-eth-l2bdbasemaclrn-eth-4vhostvr1024-2vm-ndrpdr
 120 | | [Tags] | 1518B | 4C
 121 | | framesize=${1518} | phy_cores=${4}
 122
 123 | tc07-9000B-1c-eth-l2bdbasemaclrn-eth-4vhostvr1024-2vm-ndrpdr
 124 | | [Tags] | 9000B | 1C
 125 | | framesize=${9000} | phy_cores=${1}
 126
 127 | tc08-9000B-2c-eth-l2bdbasemaclrn-eth-4vhostvr1024-2vm-ndrpdr
 128 | | [Tags] | 9000B | 2C
 129 | | framesize=${9000} | phy_cores=${2}
 130
 131 | tc09-9000B-4c-eth-l2bdbasemaclrn-eth-4vhostvr1024-2vm-ndrpdr
 132 | | [Tags] | 9000B | 4C
 133 | | framesize=${9000} | phy_cores=${4}
 134
 135 | tc10-IMIX-1c-eth-l2bdbasemaclrn-eth-4vhostvr1024-2vm-ndrpdr
 136 | | [Tags] | IMIX | 1C
 137 | | framesize=IMIX_v4_1 | phy_cores=${1}
 138
 139 | tc11-IMIX-2c-eth-l2bdbasemaclrn-eth-4vhostvr1024-2vm-ndrpdr
 140 | | [Tags] | IMIX | 2C
 141 | | framesize=IMIX_v4_1 | phy_cores=${2}
 142
 143 | tc12-IMIX-4c-eth-l2bdbasemaclrn-eth-4vhostvr1024-2vm-ndrpdr
 144 | | [Tags] | IMIX | 4C
 145 | | framesize=IMIX_v4_1 | phy_cores=${4}