X-Git-Url: https://gerrit.fd.io/r/gitweb?p=csit.git;a=blobdiff_plain;f=tests%2Fvpp%2Fdevice%2Fip4_tunnels%2Flisp%2F2n1l-10ge2p1x710-ethip4lisp-ip4base-scapy.robot;fp=tests%2Fvpp%2Fdevice%2Fip4_tunnels%2Flisp%2F2n1l-10ge2p1x710-ethip4lisp-ip4base-scapy.robot;h=2760166d3cb3a2606848bd18ec6c05e41707cbba;hp=0000000000000000000000000000000000000000;hb=9f5525de03c3d1cbca8b7e2a324414308645a9f3;hpb=8079ed2ff7e2fdd41474d286b98cd9be19481f7a

diff --git a/tests/vpp/device/ip4_tunnels/lisp/2n1l-10ge2p1x710-ethip4lisp-ip4base-scapy.robot b/tests/vpp/device/ip4_tunnels/lisp/2n1l-10ge2p1x710-ethip4lisp-ip4base-scapy.robot
new file mode 100644
index 0000000000..2760166d3c
--- /dev/null
+++ b/tests/vpp/device/ip4_tunnels/lisp/2n1l-10ge2p1x710-ethip4lisp-ip4base-scapy.robot
@@ -0,0 +1,91 @@
+# Copyright (c) 2021 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+*** Settings ***
+| Resource | resources/libraries/robot/shared/default.robot
+|
+| Variables | resources/test_data/lisp/lisp.py
+|
+| Force Tags | 2_NODE_SINGLE_LINK_TOPO | DEVICETEST | HW_ENV | DCR_ENV | SCAPY
+| ... | NIC_Intel-X710 | IP4FWD | LISP | LISP_IP4o4 | DRV_VFIO_PCI
+| ... | RXQ_SIZE_0 | TXQ_SIZE_0
+| ... | ethip4lisp-ip4base
+|
+| Suite Setup | Setup suite topology interfaces | scapy
+| Test Setup | Setup test
+| Test Teardown | Tear down test | packet_trace
+|
+| Test Template | Local Template
+|
+| Documentation | *ip4-lisp-ip4 encapsulation test cases*
+|
+| ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node\
+| ... | circular topology with single links between nodes.
+| ... | *[Enc] Packet Encapsulations:* Eth-IPv4-LISP-IPv4-ICMPv4\
+| ... | on DUT1-TG, Eth-IPv4-ICMPv4 on TG-DUTn for IPv4 routing\
+| ... | over LISPoIPv4 tunnel.
+| ... | *[Cfg] DUT configuration:* DUT is configured with IPv4\
+| ... | routing and static routes. LISPoIPv4 tunnel is\
+| ... | configured between DUT1 and TG2.
+| ... | *[Ver] TG verification:* Test ICMPv4 Echo Request packets\
+| ... | are sent by TG on if1 link to DUT1; on receive TG verifies\
+| ... | packets for correctness and their IPv4 src-addr, dst-addr\
+| ... | and MAC addresses.
+| ... | *[Ref] Applicable standard specifications:* RFC6830.
+
+*** Variables ***
+| @{plugins_to_enable}= | dpdk_plugin.so | perfmon_plugin.so | lisp_plugin.so
+| ${crypto_type}= | ${None}
+| ${nic_name}= | Intel-X710
+| ${nic_driver}= | vfio-pci
+| ${nic_rxq_size}= | 0
+| ${nic_txq_size}= | 0
+| ${nic_pfs}= | 2
+| ${nic_vfs}= | 0
+| ${overhead}= | ${54}
+
+*** Keywords ***
+| Local Template
+| | [Documentation]
+| | ... | [Cfg] On DUT1 configure LISP.\
+| |
+| | ... | *Arguments:*
+| | ... | - frame_size - Framesize in Bytes in integer. Type: integer
+| | ... | - phy_cores - Number of physical cores. Type: integer
+| | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
+| |
+| | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
+| |
+| | Set Test Variable | \${frame_size}
+| |
+| | Given Set Max Rate And Jumbo
+| | And Add worker threads to all DUTs | ${phy_cores} | ${rxq}
+| | And Pre-initialize layer driver | ${nic_driver}
+| | And Apply startup configuration on all VPP DUTs | with_trace=${True}
+| | When Initialize layer driver | ${nic_driver}
+| | And Initialize layer interface
+| | And Configure topology for IPv4 LISP testing
+| | And Configure LISP in 2-node circular topology
+| | ... | ${dut1} | ${DUT1_${int}2}[0] | ${NONE}
+| | ... | ${duts_locator_set} | ${dut1_ip4_eid}
+| | ... | ${dut1_to_tg_ip4_static_adjacency}
+| | Then Send packet and verify LISP encap
+| | ... | ${tg} | ${tg_if1_ip4} | ${dst_ip4}
+| | ... | ${TG_pf1}[0] | ${TG_pf1_mac}[0] | ${DUT1_vf1_mac}[0]
+| | ... | ${TG_pf2}[0] | ${DUT1_vf2_mac}[0] | ${TG_pf2_mac}[0]
+| | ... | ${src_rloc4} | ${dst_rloc4}
+
+*** Test Cases ***
+| 64B-0c-ethip4lisp-ip4base-scapy
+| | [Tags] | 64B | 0C
+| | frame_size=${64} | phy_cores=${0}