Code Review / csit.git / commitdiff
? search:
summary | shortlog | log | commit | commitdiff | review | tree
raw | patch | inline | side by side (parent: 06f37e7)
Add Honeycomb VxLAN test suite 96/1096/5
authorselias <samelias@cisco.com>
Fri, 13 May 2016 09:51:32 +0000 (11:51 +0200)
committerMatej Klotton <mklotton@cisco.com>
Mon, 16 May 2016 10:55:26 +0000 (10:55 +0000)
JIRA: CSIT-47

 - add test suite for VxLAN management through Honeycomb
 - add keywords required for VxLAN management tests
 - add resource file with additional variables for testing
 - increment bridge domain test suite index

Change-Id: Ica0d7ae15f5b7058832a944d5ca0c72026ba299c
Signed-off-by: selias <samelias@cisco.com>
resources/libraries/robot/honeycomb/interfaces.robot patch | blob | history
resources/libraries/robot/honeycomb/vxlan.robot [new file with mode: 0644] patch | blob
tests/suites/honeycomb/1 - interface_management.robot patch | blob | history
tests/suites/honeycomb/2 - vxlan.robot [new file with mode: 0644] patch | blob
tests/suites/honeycomb/3 - bridge_domain.robot [moved from tests/suites/honeycomb/2 - bridge_domain.robot with 97% similarity] patch | blob | history
tests/suites/honeycomb/resources/vxlan.py [new file with mode: 0644] patch | blob

diff --git a/resources/libraries/robot/honeycomb/interfaces.robot b/resources/libraries/robot/honeycomb/interfaces.robot
index 7e2e654..f1f7cea 100644 (file)
--- a/resources/libraries/robot/honeycomb/interfaces.robot
+++ b/resources/libraries/robot/honeycomb/interfaces.robot
@@ -12,7 +12,6 @@
 # limitations under the License.
 
 *** Settings ***
-| Library | resources/libraries/python/honeycomb/HoneycombUtil.py
 | Library | resources.libraries.python.InterfaceUtil
 | ...     | WITH NAME | interfaceCLI
 | Library | resources.libraries.python.honeycomb.HcAPIKwInterfaces.InterfaceKeywords
@@ -336,68 +335,3 @@
 | | ${vat_data}= | InterfaceCLI.VPP get interface data | ${node} | ${interface}
 | | Should be equal | ${vat_data['mtu']} | ${mtu}
 | | Should be equal | ${vat_data['sub_inner_vlan_id']} | ${vrf-id}
-
-| Honeycomb sets interface VxLAN configuration
-| | [Documentation] | Uses Honeycomb API to change VxLAN configuration \
-| | ... | of the specified interface.
-| | ...
-| | ... | *Arguments:*
-| | ... | - node - information about a DUT node. Type: dictionary
-| | ... | - interface - name of an interface on the specified node. Type: string
-| | ... | - vxlan_settings - Configuration data for VxLAN. Type: dictionary
-| | ...
-| | ... | *Example:*
-| | ... | \| Honeycomb sets interface VxLAN configuration \
-| | ... | \|${node} \| ${interface} \| &{vxlan_settings} \|
-| | ...
-| | [Arguments] | ${node} | ${interface} | &{vxlan_settings}
-| | :FOR | ${items} | IN | @{vxlan_settings.items()}
-| | | interfaceAPI.Configure interface vxlan | ${node} | ${interface} | @{items}
-
-| VxLAN configuration from Honeycomb should be
-| | [Documentation] | Retrieves interface VxLAN configuration through Honeycomb\
-| | ... | and compares with state supplied in argument.
-| | ...
-| | ... | *Arguments:*
-| | ... | - node - information about a DUT node. Type: dictionary
-| | ... | - interface - name of an interface on the specified node. Type: string
-| | ... | - vxlan_settings - Configuration data for VxLAN. Type: dictionary
-| | ...
-| | ... | *Example:*
-| | ...
-| | ... | \| VxLAN configuration from Honeycomb should be \
-| | ... | \| ${node} \| ${interface} \| &{vxlan_settings} \|
-| | ...
-| | [Arguments] | ${node} | ${interface} | &{vxlan_settings}
-| | ${api_data}= | interfaceAPI.Get interface cfg data | ${node} | ${interface}
-| | :FOR | ${items} | IN | @{vxlan_settings.items()}
-| | | Should be equal as strings
-| | ... | ${api_data['v3po:vxlan']['@{items}[0]']} | ${items[1]}
-| | ${api_data}= | interfaceAPI.Get interface oper data | ${node} | ${interface}
-| | :FOR | ${items} | IN | @{vxlan_settings.items()}
-| | | Should be equal as strings
-| | ... | ${api_data['v3po:vxlan']['@{items}[0]']} | ${items[1]}
-
-| VxLAN configuration from VAT should be
-| | [Documentation] | Retrieves interface VxLAN configuration through VAT and\
-| | ... | compares with state supplied in argument.
-| | ...
-| | ... | *Arguments:*
-| | ... | - node - information about a DUT node. Type: dictionary
-| | ... | - interface - name of an interface on the specified node. Type: string
-| | ... | - vxlan_settings - Configuration data for VxLAN. Type: dictionary
-| | ...
-| | ... | *Example:*
-| | ...
-| | ... | \| VxLAN configuration from Honeycomb should be \
-| | ... | \| ${node} \| ${interface} \| &{vxlan_settings} \|
-| | ...
-| | [Arguments] | ${node} | ${interface} | &{vxlan_settings}
-| | ${vat_data}= | VxLAN Dump | ${node} | ${interface}
-| | Should be equal as strings
-| | ... | ${vat_data['dst_address']} | ${vxlan_settings['dst']}
-| | Should be equal as strings
-| | ... | ${vat_data['src_address']} | ${vxlan_settings['src']}
-| | Should be equal as strings | ${vat_data['vni']} | ${vxlan_settings['vni']}
-| | Should be equal as strings
-| | ... | ${vat_data['encap-vrf-id']} | ${vxlan_settings['encap_vrf_id']}
diff --git a/resources/libraries/robot/honeycomb/vxlan.robot b/resources/libraries/robot/honeycomb/vxlan.robot
new file mode 100644 (file)
index 0000000..83a6e12
--- /dev/null
+++ b/resources/libraries/robot/honeycomb/vxlan.robot
@@ -0,0 +1,172 @@
+# Copyright (c) 2016 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+*** Settings ***
+| Library | resources.libraries.python.InterfaceUtil
+| ...     | WITH NAME | interfaceCLI
+| Library | resources.libraries.python.honeycomb.HcAPIKwInterfaces.InterfaceKeywords
+| ...     | WITH NAME | InterfaceAPI
+
+*** Keywords ***
+| Honeycomb sets interface VxLAN configuration
+| | [Documentation] | Uses Honeycomb API to configure a VxLAN tunnel.
+| | ...
+| | ... | *Arguments:*
+| | ... | - node - information about a DUT node. Type: dictionary
+| | ... | - interface - name of an interface on the specified node. Type: string
+| | ... | - settings - Configuration data for VxLAN. Type: dictionary
+| | ...
+| | ... | *Example:*
+| | ... | \| Honeycomb sets interface VxLAN configuration \
+| | ... | \|${nodes['DUT1']} \| vxlan_01 \| ${{'src':'192.168.0.2',\
+| | ... |  'dst':'192.168.0.3', 'vni':5, 'encap-vrf-id':0}} \|
+| | ...
+| | [Arguments] | ${node} | ${interface} | ${settings}
+| | interfaceAPI.Create VxLAN interface | ${node} | ${interface}
+| | ... | &{settings}
+
+| Honeycomb removes VxLAN tunnel settings
+| | [Documentation] | Uses Honeycomb API to disable a VxLAN tunnel and remove\
+| | ... | it from configuration data.
+| | ...
+| | ... | *Arguments:*
+| | ... | - node - information about a DUT node. Type: dictionary
+| | ... | - interface - name of an interface on the specified node. Type: string
+| | ...
+| | ... | *Example:*
+| | ...
+| | ... | \| Honeycomb removes VxLAN tunnel \| ${nodes['DUT1']} \| vxlan_01 \|
+| | [Arguments] | ${node} | ${interface}
+| | interfaceAPI.Delete interface | ${node} | ${interface}
+
+| VxLAN configuration from Honeycomb should be
+| | [Documentation] | Retrieves interface VxLAN configuration through Honeycomb\
+| | ... | and compares with settings supplied in argument.
+| | ...
+| | ... | *Arguments:*
+| | ... | - node - information about a DUT node. Type: dictionary
+| | ... | - interface - name of an interface on the specified node. Type: string
+| | ... | - settings - Configuration data for VxLAN. Type: dictionary
+| | ...
+| | ... | *Example:*
+| | ...
+| | ... | \| VxLAN configuration from Honeycomb should be \
+| | ... | \|${nodes['DUT1']} \| vxlan_01 \| ${{'src':'192.168.0.2',\
+| | ... |  'dst':'192.168.0.3', 'vni':5, 'encap-vrf-id':0}} \|
+| | ...
+| | [Arguments] | ${node} | ${interface} | ${settings}
+| | ${api_data}= | interfaceAPI.Get interface oper data | ${node} | ${interface}
+| | ${api_vxlan}= | Set Variable | ${api_data['v3po:vxlan']}
+| | :FOR | ${key} | IN | @{settings.keys()}
+| | | Should be equal | ${api_vxlan['${key}']} | ${settings['${key}']}
+
+| VxLAN configuration from VAT should be
+| | [Documentation] | Retrieves interface VxLAN configuration through VAT and\
+| | ... | compares with settings supplied in argument.
+| | ...
+| | ... | *Arguments:*
+| | ... | - node - information about a DUT node. Type: dictionary
+| | ... | - settings - Configuration data for VxLAN. Type: dictionary
+| | ...
+| | ... | *Example:*
+| | ...
+| | ... | \| VxLAN configuration from Honeycomb should be \
+| | ... | \|${nodes['DUT1']} \| ${{'src':'192.168.0.2',\
+| | ... |  'dst':'192.168.0.3', 'vni':5, 'encap-vrf-id':0}} \|
+| | ...
+| | ... | *Note:*
+| | ... | Due to the difficulty of identifying newly created interfaces by name\
+| | ... | or by sw_index, this keyword assumes there is only one VxLAN tunnel\
+| | ... | present on the specified node.
+| | [Arguments] | ${node} | ${settings}
+| | ${vat_data}= | VxLAN Dump | ${node}
+| | ${vat_data}= | Set Variable | ${vat_data[0]}
+| | Should be equal | ${vat_data['dst_address']} | ${settings['dst']}
+| | Should be equal | ${vat_data['src_address']} | ${settings['src']}
+| | Should be equal | ${vat_data['vni']} | ${settings['vni']}
+| | Should be equal
+| | ... | ${vat_data['encap_vrf_id']} | ${settings['encap-vrf-id']}
+
+| VxLAN configuration from Honeycomb should be empty
+| | [Documentation] | Attempts to retrieve interface VxLAN configuration\
+| | ... | through Honeycomb and expects to recieve an empty dictionary.
+| | ...
+| | ... | *Arguments:*
+| | ... | - node - information about a DUT node. Type: dictionary
+| | ... | - interface - name of an interface on the specified node. Type: string
+| | ...
+| | ... | *Example:*
+| | ...
+| | ... | \| VxLAN configuration from Honeycomb should be empty\
+| | ... | \|${nodes['DUT1']} \| vxlan_01 \|
+| | ...
+| | [Arguments] | ${node} | ${interface}
+| | ${api_data}= | interfaceAPI.Get interface oper data | ${node} | ${interface}
+| | Should be empty | ${api_data}
+
+| VxLAN configuration from VAT should be empty
+| | [Documentation] | Attempts to retrieve interface VxLAN configuration\
+| | ... | through VAT and expects a "no data" error.
+| | ...
+| | ... | *Arguments:*
+| | ... | - node - information about a DUT node. Type: dictionary
+| | ... | - interface - name of an interface on the specified node. Type: string
+| | ...
+| | ... | *Example:*
+| | ...
+| | ... | \| VxLAN configuration from VAT should be empty\
+| | ... | \| ${nodes['DUT1']} \|
+| | ...
+| | [Arguments] | ${node}
+| | Run Keyword And Expect Error | ValueError: No JSON object could be decoded
+| | ... | VxLAN Dump | ${node}
+
+| Honeycomb fails setting VxLan on different interface type
+| | [Documentation] | Attempts to set VxLAN settings on an ethernet\
+| | ... | type interface and expects to fail.
+| | ...
+| | ... | *Arguments:*
+| | ... | - node - information about a DUT node. Type: dictionary
+| | ... | - interface - name of an interface on the specified node. Type: string
+| | ... | - settings - Configuration data for VxLAN. Type: dictionary
+| | ...
+| | ... | *Example:*
+| | ...
+| | ... | \| Honeycomb fails setting VxLan on different interface type\
+| | ... | \|${nodes['DUT1']} \| GigabitEthernet0/9/0 \| ${{'src':'192.168.0.2',\
+| | ... |  'dst':'192.168.0.3', 'vni':5, 'encap-vrf-id':0}} \|
+| | ...
+| | [Arguments] | ${node} | ${interface} | ${settings}
+| | Run Keyword And Expect Error | HoneycombError: * Status code: 500.
+| | ... | interfaceAPI.Configure interface vxlan
+| | ... | ${node} | ${interface} | &{settings}
+
+| Honeycomb fails setting invalid VxLAN configuration
+| | [Documentation] | Attempts to create a VxLAN interface with invalid\
+| | ... | configuration and expects to fail.
+| | ...
+| | ... | *Arguments:*
+| | ... | - node - information about a DUT node. Type: dictionary
+| | ... | - interface - name of an interface on the specified node. Type: string
+| | ... | - settings_list - Bad configuration data for VxLAN. Type: list
+| | ...
+| | ... | *Example:*
+| | ...
+| | ... | \| Honeycomb fails setting invalid VxLAN configuration\
+| | ... | \|${nodes['DUT1']} \| vxlan_01 \| ${{'src':'abcd', 'vni':-3}} \|
+| | ...
+| | [Arguments] | ${node} | ${interface} | ${settings_list}
+| | :FOR | ${settings} | IN | @{settings_list}
+| | | Run Keyword And Expect Error | HoneycombError: * Status code: 500.
+| | | ... | interfaceAPI.Create VxLAN interface
+| | | ... | ${node} | ${interface} | &{settings}
diff --git a/tests/suites/honeycomb/1 - interface_management.robot b/tests/suites/honeycomb/1 - interface_management.robot
index ae4fec9..e320c46 100644 (file)
--- a/tests/suites/honeycomb/1 - interface_management.robot
+++ b/tests/suites/honeycomb/1 - interface_management.robot
@@ -95,14 +95,3 @@
 | | ... | ${node} | ${interface} | ${ethernet} | ${routing}
 | | And Interface ethernet and routing configuration from VAT should be
 | | ... | ${node} | ${interface} | ${ethernet['mtu']} | ${routing['vrf-id']}
-
-| Honeycomb modifies interface configuration - VxLAN
-| | [Documentation] | Check if Honeycomb API can configure interface VxLAN \
-| | ... | settings.
-| | [Tags] | honeycomb_sanity
-| | When Honeycomb sets interface VxLAN configuration
-| | ... | ${node} | ${interface} | &{vxlan_settings}
-| | Then VxLAN configuration from Honeycomb should be
-| | ... | ${node} | ${interface} | &{vxlan_settings}
-| | And VxLAN configuration from VAT should be
-| | ... | ${node} | ${interface} | &{vxlan_settings}
diff --git a/tests/suites/honeycomb/2 - vxlan.robot b/tests/suites/honeycomb/2 - vxlan.robot
new file mode 100644 (file)
index 0000000..c1dee35
--- /dev/null
+++ b/tests/suites/honeycomb/2 - vxlan.robot
@@ -0,0 +1,100 @@
+# Copyright (c) 2016 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+*** Variables ***
+# Node and interfaces to run tests on.
+| ${node}= | ${nodes['DUT1']}
+| ${interface}= | ${node['interfaces'].values()[0]['name']}
+| ${vx_interface}= | vx_tunnel_test
+# Configuration which will be set and verified during tests.
+| &{vxlan_settings}= | src=192.168.0.2 | dst=192.168.0.3 | vni=${88}
+| ... | encap-vrf-id=${0}
+| &{vxlan_settings2}= | src=192.168.0.4 | dst=192.168.0.5 | vni=${47}
+| ... | encap-vrf-id=${0}
+| &{vxlan_settings_ipv6}= | src=10::10 | dst=10::11 | vni=${88}
+| ... | encap-vrf-id=${0}
+
+*** Settings ***
+| Resource | resources/libraries/robot/default.robot
+| Resource | resources/libraries/robot/honeycomb/honeycomb.robot
+| Resource | resources/libraries/robot/honeycomb/interfaces.robot
+| Resource | resources/libraries/robot/honeycomb/vxlan.robot
+# import additional VxLAN settings from resource file
+| Variables | tests/suites/honeycomb/resources/vxlan.py
+| Documentation | *Honeycomb VxLAN management test suite.*
+| ...
+| ... | Test suite uses the first interface of the first DUT node.
+
+*** Test Cases ***
+| Honeycomb configures VxLAN tunnel
+| | [Documentation] | Check if Honeycomb API can configure VxLAN settings.
+| | [Tags] | honeycomb_sanity
+| | Given VxLAN configuration from Honeycomb should be empty
+| | ... | ${node} | ${vx_interface}
+| | When Honeycomb sets interface VxLAN configuration
+| | ... | ${node} | ${vx_interface} | ${vxlan_settings}
+| | Then VxLAN configuration from Honeycomb should be
+| | ... | ${node} | ${vx_interface} | ${vxlan_settings}
+| | And VxLAN configuration from VAT should be
+| | ... | ${node} | ${vxlan_settings}
+
+| Honeycomb disables VxLAN tunnel
+| | [Documentation] | Check if Honeycomb API can reset VxLAN configuration.
+| | [Tags] | honeycomb_sanity
+| | Given VxLAN configuration from Honeycomb should be
+| | ... | ${node} | ${vx_interface} | ${vxlan_settings}
+| | When Honeycomb removes VxLAN tunnel settings | ${node} | ${vx_interface}
+| | Then VxLAN configuration from Honeycomb should be empty
+| | ... | ${node} | ${vx_interface}
+| | And VxLAN configuration from VAT should be empty | ${node}
+
+| Honeycomb does not set VxLAN configuration on another interface type
+| | [Documentation] | Check if Honeycomb API prevents setting VxLAN\
+| | ... | on incorrect interface.
+| | [Tags] | honeycomb_sanity
+| | Given VxLAN configuration from Honeycomb should be empty
+| | ... | ${node} | ${interface}
+| | And VxLAN configuration from VAT should be empty | ${node}
+| | When Honeycomb fails setting VxLan on different interface type
+| | ... | ${node} | ${interface} | ${vxlan_settings2}
+| | Then VxLAN configuration from Honeycomb should be empty
+| | ... | ${node} | ${interface}
+| | And VxLAN configuration from VAT should be empty
+| | ... | ${node}
+
+| Honeycomb does not set invalid VxLAN configuration
+| | [Documentation] | Check if Honeycomb API prevents setting incorrect VxLAN\
+| | ... | settings.
+| | [Tags] | honeycomb_sanity
+| | Given VxLAN configuration from Honeycomb should be empty
+| | ... | ${node} | ${vx_interface}
+| | And VxLAN configuration from VAT should be empty | ${node}
+| | When Honeycomb fails setting invalid VxLAN configuration
+| | ... | ${node} | ${vx_interface} | ${vxlan_invalid}
+| | Then VxLAN configuration from Honeycomb should be empty
+| | ... | ${node} | ${vx_interface}
+
+| Honeycomb configures VxLAN tunnel with ipv6
+| | [Documentation] | Check if Honeycomb API can configure VxLAN with\
+| | ... | ipv6 settings.
+| | [Tags] | honeycomb_sanity
+| | Given VxLAN configuration from Honeycomb should be empty
+| | ... | ${node} | ${vx_interface}
+| | And VxLAN configuration from VAT should be empty | ${node}
+| | When Honeycomb sets interface VxLAN configuration
+| | ... | ${node} | ${vx_interface} | ${vxlan_settings_ipv6}
+| | Then VxLAN configuration from Honeycomb should be
+| | ... | ${node} | ${vx_interface} | ${vxlan_settings_ipv6}
+| | And VxLAN configuration from VAT should be
+| | ... | ${node} | ${vxlan_settings_ipv6}
+
diff --git a/tests/suites/honeycomb/2 - bridge_domain.robot b/tests/suites/honeycomb/3 - bridge_domain.robot
similarity index 97%
rename from tests/suites/honeycomb/2 - bridge_domain.robot
rename to tests/suites/honeycomb/3 - bridge_domain.robot
index 8b75888..71774fe 100644 (file)
--- a/tests/suites/honeycomb/2 - bridge_domain.robot
+++ b/tests/suites/honeycomb/3 - bridge_domain.robot
@@ -12,9 +12,11 @@
 # limitations under the License.
 
 *** Variables ***
+# Node and interfaces to run tests on.
 | ${node}= | ${nodes['DUT1']}
 | @{interfaces}= | ${node['interfaces'].values()[0]['name']}
 | ... | ${node['interfaces'].values()[1]['name']}
+# Configuration which will be set and verified during tests.
 | ${bd1_name}= | bd-01
 | ${bd2_name}= | bd-02
 | &{bd_settings}= | flood=${True} | forward=${True} | learn=${True}
diff --git a/tests/suites/honeycomb/resources/vxlan.py b/tests/suites/honeycomb/resources/vxlan.py
new file mode 100644 (file)
index 0000000..43307aa
--- /dev/null
+++ b/tests/suites/honeycomb/resources/vxlan.py
@@ -0,0 +1,28 @@
+# Copyright (c) 2016 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+"""Test variables for Honeycomb VxLAN management test suite."""
+
+# invalid VxLAN settings
+vxlan_invalid = [
+    # same source and destination IPs
+    {'src': '192.168.0.2', 'dst': '192.168.0.2', 'vni': 88, 'encap-vrf-id': 0},
+    # missing source
+    {'dst': '192.168.0.2', 'vni': 88, 'encap-vrf-id': 0},
+    # missing destination
+    {'src': '192.168.0.2', 'vni': 88, 'encap-vrf-id': 0},
+    # missing vni
+    {'src': '192.168.0.2', 'dst': '192.168.0.3', 'encap-vrf-id': 0},
+    # missing encap id
+    {'src': '192.168.0.2', 'dst': '192.168.0.3', 'vni': 88}
+]
Integration tests