Add Honeycomb bridge domain management tests 69/969/7
authorselias <samelias@cisco.com>
Fri, 29 Apr 2016 11:35:25 +0000 (13:35 +0200)
committerMatej Klotton <mklotton@cisco.com>
Mon, 9 May 2016 10:37:59 +0000 (10:37 +0000)
JIRA: CSIT-41, CSIT-42, CSIT-43

 - add test cases for Honecomb bridge domain management
 - add keywords used by these tests
 - prefix the names of Honeycomb test suites with numbers, so that they
   execute in a specific order
 - moved suite teardown with "Stop Honeycomb service" to bridge domain
   suite

Note: Due to time constraints, the Honeycomb service cannot be restarted
between executions of individual Honeycomb test suites. Therefore
Honeycomb will be setup in the first test suite and shut down after the
last one.

Change-Id: I36b7f8335e5ba54985da5bd83730cf856d5ab48b
Signed-off-by: selias <samelias@cisco.com>
resources/libraries/robot/honeycomb/bridge_domain.robot [new file with mode: 0644]
tests/suites/honeycomb/1 - interface_management.robot [moved from tests/suites/honeycomb/interface_management.robot with 98% similarity]
tests/suites/honeycomb/2 - bridge_domain.robot [new file with mode: 0644]

diff --git a/resources/libraries/robot/honeycomb/bridge_domain.robot b/resources/libraries/robot/honeycomb/bridge_domain.robot
new file mode 100644 (file)
index 0000000..da3ae0a
--- /dev/null
@@ -0,0 +1,202 @@
+# Copyright (c) 2016 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+*** Settings ***
+| Library | resources.libraries.python.L2Util
+| Library | resources.libraries.python.HcAPIKwBridgeDomain.BridgeDomainKeywords
+| Library | resources.libraries.python.HcAPIKwInterfaces.InterfaceKeywords
+| ... | WITH NAME | InterfaceAPI
+
+*** Keywords ***
+| Honeycomb creates first L2 bridge domain
+| | [Documentation] | Uses Honeycomb API to create a bridge domain on the \
+| | ... | VPP node. Any other bridge domains will be removed in the process.
+| | ...
+| | ... | *Arguments:*
+| | ... | - node - information about a DUT node. Type: dictionary
+| | ... | - bd_name - name of the created bridge domain. Type: string
+| | ... | - settings - settings for the created bridge domain. Type: dictionary
+| | ...
+| | ... | *Example:*
+| | ...
+| | ... | \| Honeycomb creates first L2 bridge domain \| ${nodes['DUT1']} \
+| | ... | \| bd-04 \| ${{flood:True, learn:False}} \|
+| | [Arguments] | ${node} | ${bd_name} | ${settings}
+| | Add first BD | ${node} | ${bd_name} | &{settings}
+
+| Honeycomb creates L2 bridge domain
+| | [Documentation] | Uses Honeycomb API to create a bridge domain on the \
+| | ... | VPP node.
+| | ...
+| | ... | *Arguments:*
+| | ... | - node - information about a DUT node. Type: dictionary
+| | ... | - bd_name - name of the created bridge domain. Type: string
+| | ... | - settings - settings for the created bridge domain. Type: dictionary
+| | ...
+| | ... | *Example:*
+| | ...
+| | ... | \| Honeycomb creates L2 bridge domain \| ${nodes['DUT1']} \
+| | ... | \| bd-04 \| ${{flood:True, learn:False}} \|
+| | [Arguments] | ${node} | ${bd_name} | ${settings}
+| | Add BD | ${node} | ${bd_name} | &{settings}
+
+| Bridge domain configuration from Honeycomb should be
+| | [Documentation] | Uses Honeycomb API to verify bridge domain settings\
+| | ... | against provided values.
+| | ...
+| | ... | *Arguments:*
+| | ... | - node - information about a DUT node. Type: dictionary
+| | ... | - bd_name - name of the bridge domain. Type: string
+| | ... | - settings - expected settings for the bridge domain. Type: dictionary
+| | ...
+| | ... | *Example:*
+| | ...
+| | ... | \| Bridge domain configuration from Honeycomb should be \
+| | ... | \| ${nodes['DUT1']} \| bd-04 \| ${{flood:True,learn:False}} \|
+| | [Arguments] | ${node} | ${bd_name} | ${settings}
+| | ${api_data}= | Get bd cfg data | ${node} | ${bd_name}
+| | :FOR | ${key} | IN | @{settings.keys()}
+| | | Should be equal | ${settings['${key}']} | ${api_data['${key}']}
+
+| Bridge domain configuration from VAT should be
+| | [Documentation] | Uses VAT to verify bridge domain settings\
+| | ... | against provided values.
+| | ...
+| | ... | *Arguments:*
+| | ... | - node - information about a DUT node. Type: dictionary
+| | ... | - bd_name - name of the bridge domain. Type: string
+| | ... | - settings - expected settings for the bridge domain. Type: dictionary
+| | ...
+| | ... | *Example:*
+| | ...
+| | ... | \| Bridge domain configuration from VAT should be \
+| | ... | \| ${nodes['DUT1']} \| bd-04 \| ${{flood:True,learn:False}} \|
+| | [Arguments] | ${node} | ${bd_index} | ${settings}
+| | ${vat_data}= | VPP get bridge domain data | ${node}
+| | ${vat_data}= | Set Variable | ${vat_data[${bd_index}]}
+| | :FOR | ${key} | IN | @{settings.keys()}
+| | | Run keyword if | $key in $vat_data.keys()
+| | | ... | Should be equal | ${settings['${key}']} | ${vat_data['${key}']}
+
+| Honeycomb adds interfaces to bridge domain
+| | [Documentation] | Uses Honeycomb API to assign interfaces to a bridge\
+| | ... | domain.
+| | ...
+| | ... | *Arguments:*
+| | ... | - node - information about a DUT node. Type: dictionary
+| | ... | - interface1, interface2 - names of interfaces to assign to bridge\
+| | ... | domain. Type: string
+| | ... | - bd_name - name of the bridge domain. Type: string
+| | ...
+| | ... | *Example:*
+| | ...
+| | ... | \| Honeycomb adds interfaces to bridge domain \| ${nodes['DUT1']} \
+| | ... | \| GigabitEthernet0/8/0 \| GigabitEthernet0/9/0 \| bd-04 \|
+| | [Arguments] | ${node} | ${interface1} | ${interface2} | ${bd_name}
+| | ... | ${settings}
+| | interfaceAPI.Add bridge domain to interface
+| | ... | ${node} | ${interface1} | ${bd_name} | &{settings}
+| | interfaceAPI.Add bridge domain to interface
+| | ... | ${node} | ${interface2} | ${bd_name} | &{settings}
+
+| Honeycomb should show interfaces assigned to bridge domain
+| | [Documentation] | Uses Honeycomb API to verify interface assignment to\
+| | ... | bridge domain.
+| | ...
+| | ... | *Arguments:*
+| | ... | - node - information about a DUT node. Type: dictionary
+| | ... | - interface1, interface2 - names of interfaces to assign to bridge\
+| | ... | domain. Type: string
+| | ... | - bd_name - name of the bridge domain. Type: string
+| | ...
+| | ... | *Example:*
+| | ...
+| | ... | \| Honeycomb should show interfaces assigned to bridge domain \
+| | ... | \| ${nodes['DUT1']} \| GigabitEthernet0/8/0 \| GigabitEthernet0/9/0 \
+| | ... | \| bd-04 \|
+| | [Arguments] | ${node} | ${interface1} | ${interface2} | ${bd_name}
+| | ... | ${settings}
+| | ${if1_data}= | interfaceAPI.Get interface oper data
+| | ... | ${node} | ${interface1}
+| | ${if2_data}= | interfaceAPI.Get interface oper data
+| | ... | ${node} | ${interface2}
+| | Should be equal | ${if1_data['v3po:l2']['bridge-domain']}
+| | ... | ${if1_data['v3po:l2']['bridge-domain']} | ${bd_name}
+| | :FOR | ${key} | IN | @{settings.keys()}
+| | | Should be equal | ${if1_data['v3po:l2']['${key}']}
+| | | ... | ${if2_data['v3po:l2']['${key}']} | ${settings['${key}']}
+
+| VAT should show interfaces assigned to bridge domain
+| | [Documentation] | Uses VAT to verify interface assignment to\
+| | ... | bridge domain.
+| | ...
+| | ... | *Arguments:*
+| | ... | - node - information about a DUT node. Type: dictionary
+| | ... | - interface1, interface2 - names of interfaces to assign to bridge\
+| | ... | domain. Type: string
+| | ... | - index - index of bridge domains on VPP node. Starts from 0,\
+| | ... | new BDs reuse numbers after a bridge domain is removed. Type: int
+| | ...
+| | ... | *Example:*
+| | ...
+| | ... | \| VAT should show interfaces assigned to bridge domain \
+| | ... | \| ${nodes['DUT1']} \| GigabitEthernet0/8/0 \| GigabitEthernet0/9/0 \
+| | ... | \| ${4} \|
+| | [Arguments] | ${node} | ${interface1} | ${interface2} | ${index}
+| | ${if1_index}= | Get interface sw index | ${node} | ${interface1}
+| | ${if2_index}= | Get interface sw index | ${node} | ${interface2}
+| | ${if_indices}= | Create list | ${if1_index} | ${if2_index}
+| | ${bd_data}= | VPP get bridge domain data | ${node}
+| | ${bd_data}= | Set Variable | ${bd_data[${index}]}
+| | :FOR | ${sw_if_index} | IN | ${bd_data['sw_if']}
+| | | Should contain | ${if_indices} | ${sw_if_index}
+
+| Honeycomb removes all bridge domains
+| | [Documentation] | Uses Honeycomb API to remove all bridge domains from the \
+| | ... | VPP node.
+| | ...
+| | ... | *Arguments:*
+| | ... | - node - information about a DUT node. Type: dictionary
+| | ...
+| | ... | *Example:*
+| | ...
+| | ... | \| Honeycomb removes all bridge domains \| ${nodes['DUT1']} \|
+| | [Arguments] | ${node}
+| | Remove all bds | ${node}
+
+| Honeycomb should show no bridge domains
+| | [Documentation] | Uses Honeycomb API to verify the removal of all\
+| | ... | bridge domains.
+| | ...
+| | ... | *Arguments:*
+| | ... | - node - information about a DUT node. Type: dictionary
+| | ...
+| | ... | *Example:*
+| | ...
+| | ... | \| Honeycomb should show no bridge domains \| ${nodes['DUT1']} \|
+| | [Arguments] | ${node}
+| | ${bd_data} | Get all BDs cfg data | ${node}
+| | Should be empty | ${bd_data}
+
+| VAT should show no bridge domains
+| | [Documentation] | Uses VAT to verify the removal of all bridge domains.
+| | ...
+| | ... | *Arguments:*
+| | ... | - node - information about a DUT node. Type: dictionary
+| | ...
+| | ... | *Example:*
+| | ...
+| | ... | \| VAT should show no bridge domains \| ${nodes['DUT1']} \|
+| | [Arguments] | ${node}
+| | Run Keyword And Expect Error | ValueError: No JSON object could be decoded
+| | ... | VPP get bridge domain data | ${node}
@@ -34,7 +34,6 @@
 | Resource | resources/libraries/robot/honeycomb/interfaces.robot
 | Suite Setup | Run keywords | Setup all DUTs before test | AND
 | ... | Setup Honeycomb service on DUTs | ${node}
-| Suite Teardown | Stop Honeycomb service on DUTs | ${node}
 | Documentation | *Honeycomb interface management test suite.*
 | ...
 | ... | Test suite uses the first interface of the first DUT node.
diff --git a/tests/suites/honeycomb/2 - bridge_domain.robot b/tests/suites/honeycomb/2 - bridge_domain.robot
new file mode 100644 (file)
index 0000000..34f5dd8
--- /dev/null
@@ -0,0 +1,83 @@
+# Copyright (c) 2016 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+*** Variables ***
+| ${node}= | ${nodes['DUT1']}
+| @{interfaces}= | ${node['interfaces'].values()[0]['name']}
+| ... | ${node['interfaces'].values()[1]['name']}
+| ${bd1_name}= | bd-01
+| ${bd2_name}= | bd-02
+| &{bd_settings}= | flood=${True} | forward=${True} | learn=${True}
+| ... | unknown-unicast-flood=${True} | arp-termination=${True}
+| &{if_settings}= | split_horizon_group=1 | bvi=${True}
+
+*** Settings ***
+| Resource | resources/libraries/robot/default.robot
+| Resource | resources/libraries/robot/honeycomb/honeycomb.robot
+| Resource | resources/libraries/robot/honeycomb/interfaces.robot
+| Resource | resources/libraries/robot/honeycomb/bridge_domain.robot
+| Suite Teardown | Stop Honeycomb service on DUTs | ${node}
+| Documentation | *Honeycomb bridge domain management test suite.*
+| ...
+| ... | Test suite uses the first two interfaces on the first DUT node.
+
+*** Test Cases ***
+| Honeycomb sets up l2 bridge domain
+| | [Documentation] | Check if Honeycomb can create bridge domains on VPP node.
+| | [Tags] | honeycomb_sanity
+| | When Honeycomb creates first l2 bridge domain
+| | ... | ${node} | ${bd1_name} | ${bd_settings}
+| | Then Bridge domain configuration from Honeycomb should be
+| | ... | ${node} | ${bd1_name} | ${bd_settings}
+| | And Bridge domain configuration from VAT should be
+| | ... | ${node} | ${0} | ${bd_settings}
+
+| Honeycomb assigns interfaces to bridge domain
+| | [Documentation] | Check if Honeycomb can assign VPP interfaces to an\
+| | ... | existing bridge domain.
+| | [Tags] | honeycomb_sanity
+| | Given Bridge domain configuration from Honeycomb should be
+| | ... | ${node} | ${bd1_name} | ${bd_settings}
+| | When Honeycomb adds interfaces to bridge domain
+| | ... | ${node} | @{interfaces} | ${bd1_name} | ${if_settings}
+| | Then Honeycomb should show interfaces assigned to bridge domain
+| | ... | ${node} | @{interfaces} | ${bd1_name} | ${if_settings}
+| | And VAT should show interfaces assigned to bridge domain
+| | ... | ${node} | ${0} | @{interfaces}
+
+| Honeycomb manages multiple bridge domains on node
+| | [Documentation] | Check if Honeycomb can manage multiple bridge domains on\
+| | ... | a single node.
+| | [Tags] | honeycomb_sanity
+| | Given Bridge domain configuration from Honeycomb should be
+| | ... | ${node} | ${bd1_name} | ${bd_settings}
+| | When Honeycomb creates l2 bridge domain
+| | ... | ${node} | ${bd2_name} | ${bd_settings}
+| | Then Bridge domain configuration from Honeycomb should be
+| | ... | ${node} | ${bd1_name} | ${bd_settings}
+| | And Bridge domain configuration from Honeycomb should be
+| | ... | ${node} | ${bd2_name} | ${bd_settings}
+| | And Bridge domain configuration from VAT should be
+| | ... | ${node} | ${0} | ${bd_settings}
+| | And Bridge domain configuration from VAT should be
+| | ... | ${node} | ${1} | ${bd_settings}
+
+| Honeycomb removes bridge domains
+| | [Documentation] | Check if Honeycomb can remove bridge domains from a VPP\
+| | ... | node.
+| | [Tags] | honeycomb_sanity
+| | Given Bridge domain configuration from Honeycomb should be
+| | ... | ${node} | ${bd1_name} | ${bd_settings}
+| | When Honeycomb removes all bridge domains | ${node}
+| | Then Honeycomb should show no bridge domains | ${node}
+| | And VAT should show no bridge domains | ${node}

©2016 FD.io a Linux Foundation Collaborative Project. All Rights Reserved.
Linux Foundation is a registered trademark of The Linux Foundation. Linux is a registered trademark of Linus Torvalds.
Please see our privacy policy and terms of use.