resources/libraries/robot/honeycomb/bridge_domain.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Library | resources.libraries.python.L2Util
  16 | Library | resources.libraries.python.honeycomb.HcAPIKwBridgeDomain.BridgeDomainKeywords
  17 | Library | resources.libraries.python.honeycomb.HcAPIKwInterfaces.InterfaceKeywords
  18 | ...     | WITH NAME | InterfaceAPI
  19 | Library | resources.libraries.python.InterfaceUtil
  20 | ...     | WITH NAME | interfaceCLI
  21
  22 *** Keywords ***
  23 | Honeycomb creates first L2 bridge domain
  24 | | [Documentation] | Uses Honeycomb API to create a bridge domain on the \
  25 | | ... | VPP node. Any other bridge domains will be removed in the process.
  26 | | ...
  27 | | ... | *Arguments:*
  28 | | ... | - node - Information about a DUT node. Type: dictionary
  29 | | ... | - bd_name - Name of the created bridge domain. Type: string
  30 | | ... | - settings - Settings for the created bridge domain. Type: dictionary
  31 | | ...
  32 | | ... | *Example:*
  33 | | ...
  34 | | ... | \| Honeycomb creates first L2 bridge domain \| ${nodes['DUT1']} \
  35 | | ... | \| bd-04 \| ${{flood:True, learn:False}} \|
  36 | | [Arguments] | ${node} | ${bd_name} | ${settings}
  37 | | Add first BD | ${node} | ${bd_name} | &{settings}
  38
  39 | Honeycomb creates L2 bridge domain
  40 | | [Documentation] | Uses Honeycomb API to create a bridge domain on the \
  41 | | ... | VPP node.
  42 | | ...
  43 | | ... | *Arguments:*
  44 | | ... | - node - Information about a DUT node. Type: dictionary
  45 | | ... | - bd_name - Name of the created bridge domain. Type: string
  46 | | ... | - settings - Settings for the created bridge domain. Type: dictionary
  47 | | ...
  48 | | ... | *Example:*
  49 | | ...
  50 | | ... | \| Honeycomb creates L2 bridge domain \| ${nodes['DUT1']} \
  51 | | ... | \| bd-04 \| ${{flood:True, learn:False}} \|
  52 | | [Arguments] | ${node} | ${bd_name} | ${settings}
  53 | | Add BD | ${node} | ${bd_name} | &{settings}
  54
  55 | Bridge domain configuration from Honeycomb should be
  56 | | [Documentation] | Uses Honeycomb API to verify bridge domain settings\
  57 | | ... | against provided values.
  58 | | ...
  59 | | ... | *Arguments:*
  60 | | ... | - node - Information about a DUT node. Type: dictionary
  61 | | ... | - bd_name - Name of the bridge domain. Type: string
  62 | | ... | - settings - Expected settings for the bridge domain. Type: dictionary
  63 | | ...
  64 | | ... | *Example:*
  65 | | ...
  66 | | ... | \| Bridge domain configuration from Honeycomb should be \
  67 | | ... | \| ${nodes['DUT1']} \| bd-04 \| ${{flood:True,learn:False}} \|
  68 | | [Arguments] | ${node} | ${bd_name} | ${settings}
  69 | | ${api_data}= | Get bd oper data | ${node} | ${bd_name}
  70 | | :FOR | ${key} | IN | @{settings.keys()}
  71 | | | Should be equal | ${settings['${key}']} | ${api_data['${key}']}
  72
  73 | Bridge domain configuration from VAT should be
  74 | | [Documentation] | Uses VAT to verify bridge domain settings\
  75 | | ... | against provided values.
  76 | | ...
  77 | | ... | *Arguments:*
  78 | | ... | - node - Information about a DUT node. Type: dictionary
  79 | | ... | - bd_name - Name of the bridge domain. Type: string
  80 | | ... | - settings - Expected settings for the bridge domain. Type: dictionary
  81 | | ...
  82 | | ... | *Example:*
  83 | | ...
  84 | | ... | \| Bridge domain configuration from VAT should be \
  85 | | ... | \| ${nodes['DUT1']} \| bd-04 \| ${{flood:True,learn:False}} \|
  86 | | [Arguments] | ${node} | ${bd_index} | ${settings}
  87 | | ${vat_data}= | VPP get bridge domain data | ${node}
  88 | | ${vat_data}= | Set Variable | ${vat_data[${bd_index}]}
  89 | | :FOR | ${key} | IN | @{settings.keys()}
  90 | | | Run keyword if | $key in $vat_data.keys()
  91 | | | ... | Should be equal | ${settings['${key}']} | ${vat_data['${key}']}
  92
  93 | Honeycomb adds interfaces to bridge domain
  94 | | [Documentation] | Uses Honeycomb API to assign interfaces to a bridge\
  95 | | ... | domain.
  96 | | ...
  97 | | ... | *Arguments:*
  98 | | ... | - node - Information about a DUT node. Type: dictionary
  99 | | ... | - interface1, interface2 - Names of interfaces to assign to bridge\
 100 | | ... | domain. Type: string
 101 | | ... | - bd_name - Name of the bridge domain. Type: string
 102 | | ... | - settings - Bridge domain specific interface settings.\
 103 | | ... | Type: dictionary
 104 | | ...
 105 | | ... | *Example:*
 106 | | ...
 107 | | ... | \| Honeycomb adds interfaces to bridge domain \| ${nodes['DUT1']} \
 108 | | ... | \| GigabitEthernet0/8/0 \| GigabitEthernet0/9/0 \| bd-04 \
 109 | | ... | \| ${{split_horizon_group:2, bvi:False}} \|
 110 | | [Arguments] | ${node} | ${interface1} | ${interface2} | ${bd_name}
 111 | | ... | ${settings}
 112 | | interfaceAPI.Add bridge domain to interface
 113 | | ... | ${node} | ${interface1} | ${bd_name} | &{settings}
 114 | | interfaceAPI.Add bridge domain to interface
 115 | | ... | ${node} | ${interface2} | ${bd_name} | &{settings}
 116
 117 | Honeycomb should show interfaces assigned to bridge domain
 118 | | [Documentation] | Uses Honeycomb API to verify interface assignment to\
 119 | | ... | bridge domain.
 120 | | ...
 121 | | ... | *Arguments:*
 122 | | ... | - node - Information about a DUT node. Type: dictionary
 123 | | ... | - interface1, interface2 - Names of interfaces to assign to bridge\
 124 | | ... | domain. Type: string
 125 | | ... | - bd_name - Name of the bridge domain. Type: string
 126 | | ... | - settings - Bridge domain specific interface settings.\
 127 | | ... | Type: dictionary
 128 | | ...
 129 | | ... | *Example:*
 130 | | ...
 131 | | ... | \| Honeycomb should show interfaces assigned to bridge domain \
 132 | | ... | \| ${nodes['DUT1']} \| GigabitEthernet0/8/0 \| GigabitEthernet0/9/0 \
 133 | | ... | \| bd-04 \| ${{split_horizon_group:2, bvi:False}} \|
 134 | | [Arguments] | ${node} | ${interface1} | ${interface2} | ${bd_name}
 135 | | ... | ${settings}
 136 | | ${if1_data}= | interfaceAPI.Get interface oper data
 137 | | ... | ${node} | ${interface1}
 138 | | ${if2_data}= | interfaceAPI.Get interface oper data
 139 | | ... | ${node} | ${interface2}
 140 | | Should be equal | ${if1_data['v3po:l2']['bridge-domain']}
 141 | | ... | ${if2_data['v3po:l2']['bridge-domain']} | ${bd_name}
 142 | | Should be equal | ${if1_data['v3po:l2']['split-horizon-group']}
 143 | | ... | ${if2_data['v3po:l2']['split-horizon-group']}
 144 | | ... | ${settings['split_horizon_group']}
 145 | | Should be equal | ${if1_data['v3po:l2']['bridged-virtual-interface']}
 146 | | ... | ${if2_data['v3po:l2']['bridged-virtual-interface']}
 147 | | ... | ${settings['bvi']}
 148
 149 | VAT should show interfaces assigned to bridge domain
 150 | | [Documentation] | Uses VAT to verify interface assignment to\
 151 | | ... | bridge domain.
 152 | | ...
 153 | | ... | *Arguments:*
 154 | | ... | - node - Information about a DUT node. Type: dictionary
 155 | | ... | - index - Index of bridge domains on VPP node. Starts from 0,\
 156 | | ... | new BDs reuse numbers after a bridge domain is removed. Type: int
 157 | | ... | - interface1, interface2 - Names of interfaces to assign to bridge\
 158 | | ... | domain. Type: string
 159 | | ... | - settings - Bridge domain specific interface settings.\
 160 | | ... | Type: dictionary
 161 | | ...
 162 | | ... | *Example:*
 163 | | ...
 164 | | ... | \| VAT should show interfaces assigned to bridge domain \
 165 | | ... | \| ${nodes['DUT1']} \| ${4} \| GigabitEthernet0/8/0 \
 166 | | ... | \| GigabitEthernet0/9/0 \| ${{split_horizon_group:2, bvi:False}} \|
 167 | | [Arguments] | ${node} | ${index} | ${interface1} | ${interface2}
 168 | | ... | ${settings}
 169 | | ${if1_index}= | Get interface sw index | ${node} | ${interface1}
 170 | | ${if2_index}= | Get interface sw index | ${node} | ${interface2}
 171 | | ${if_indices}= | Create list | ${if1_index} | ${if2_index}
 172 | | ${bd_data}= | VPP get bridge domain data | ${node}
 173 | | ${bd_interfaces}= | Set Variable | ${bd_data[${index}]['sw_if']}
 174 | | @{bd_interfaces}= | Create List | ${bd_interfaces[0]} | ${bd_interfaces[1]}
 175 | | :FOR | ${interface} | IN | @{bd_interfaces}
 176 | | | Should contain | ${if_indices} | ${interface['sw_if_index']}
 177 | | | Should be equal | ${interface['shg']} | ${settings['split_horizon_group']}
 178
 179 | Honeycomb removes all bridge domains
 180 | | [Documentation] | Uses Honeycomb API to remove all bridge domains from the \
 181 | | ... | VPP node.
 182 | | ...
 183 | | ... | *Arguments:*
 184 | | ... | - node - Information about a DUT node. Type: dictionary
 185 | | ...
 186 | | ... | *Example:*
 187 | | ...
 188 | | ... | \| Honeycomb removes all bridge domains \| ${nodes['DUT1']} \|
 189 | | [Arguments] | ${node}
 190 | | Remove all bds | ${node}
 191
 192 | Honeycomb should show no bridge domains
 193 | | [Documentation] | Uses Honeycomb API to verify the removal of all\
 194 | | ... | bridge domains.
 195 | | ...
 196 | | ... | *Arguments:*
 197 | | ... | - node - Information about a DUT node. Type: dictionary
 198 | | ...
 199 | | ... | *Example:*
 200 | | ...
 201 | | ... | \| Honeycomb should show no bridge domains \| ${nodes['DUT1']} \|
 202 | | [Arguments] | ${node}
 203 | | ${bd_data}= | Get all BDs oper data | ${node}
 204 | | Should be empty | ${bd_data}
 205
 206 | VAT should show no bridge domains
 207 | | [Documentation] | Uses VAT to verify the removal of all bridge domains.
 208 | | ...
 209 | | ... | *Arguments:*
 210 | | ... | - node - Information about a DUT node. Type: dictionary
 211 | | ...
 212 | | ... | *Example:*
 213 | | ...
 214 | | ... | \| VAT should show no bridge domains \| ${nodes['DUT1']} \|
 215 | | [Arguments] | ${node}
 216 | | Run Keyword And Expect Error | ValueError: No JSON object could be decoded
 217 | | ... | VPP get bridge domain data | ${node}
 218
 219 | Honeycomb adds interface to bridge domain
 220 | | [Documentation] | Uses Honeycomb API to assign interface to a bridge\
 221 | | ... | domain.
 222 | | ...
 223 | | ... | *Arguments:*
 224 | | ... | - node - Information about a DUT node. Type: dictionary
 225 | | ... | - interface - Name of interface to assign to bridge domain.\
 226 | | ... | Type: string
 227 | | ... | - bd_name - Name of the bridge domain. Type: string
 228 | | ... | - settings - Bridge domain specific interface settings.\
 229 | | ... | Type: dictionary
 230 | | ...
 231 | | ... | *Example:*
 232 | | ...
 233 | | ... | \| Honeycomb adds interfaces to bridge domain \| ${nodes['DUT1']} \
 234 | | ... | \| GigabitEthernet0/8/0 \| bd-04 \
 235 | | ... | \| ${{split_horizon_group:2, bvi:False}} \|
 236 | | ...
 237 | | [Arguments] | ${node} | ${interface} | ${bd_name} | ${settings}
 238 | | ...
 239 | | interfaceAPI.Add bridge domain to interface
 240 | | ... | ${node} | ${interface} | ${settings['bridge-domain']}
 241 | | ... | ${settings['split-horizon-group']}
 242 | | ... | ${settings['bridged-virtual-interface']}
 243
 244 | Bridge domain configuration in interface operational data should be empty
 245 | | [Documentation] | Get interface operational data and retrieve bridge
 246 | | ... | domain configuration from it. It should be empty.
 247 | | ...
 248 | | ... | *Arguments:*
 249 | | ... | - node - Information about a DUT node. Type: dictionary
 250 | | ... | - interface - Name of interface where the bridge domain parameters \
 251 | | ... | will be checked.Type: string
 252 | | ...
 253 | | ... | *Example:*
 254 | | ... | \| Bridge domain configuration in interface operational data should \
 255 | | ... | be empty \| ${nodes['DUT1']} \| GigabitEthernet0/8/0 \|
 256 | | ...
 257 | | [Arguments] | ${node} | ${interface}
 258 | | ...
 259 | | ${if_data}= | interfaceAPI.Get BD Oper Data From Interface
 260 | | ... | ${node} | ${interface}
 261 | | Should be empty | ${if_data}
 262
 263 | Bridge domain configuration in interface operational data should be
 264 | | [Documentation] | Get interface operational data and retrieve bridge
 265 | | ... | domain configuration from it. Compare the data to the expected one.
 266 | | ...
 267 | | ... | *Arguments:*
 268 | | ... | - node - Information about a DUT node. Type: dictionary
 269 | | ... | - interface - Name of interface where the bridge domain parameters \
 270 | | ... | will be checked. Type: string
 271 | | ... | - bd_settings - The referential bridge domain data. Type: dictionary
 272 | | ...
 273 | | ... | *Example:*
 274 | | ... | \| Bridge domain configuration in interface operational data should \
 275 | | ... | be \| ${nodes['DUT1']} \| GigabitEthernet0/8/0 \| ${if_bd_settings} \|
 276 | | ...
 277 | | [Arguments] | ${node} | ${interface} | ${bd_settings}
 278 | | ...
 279 | | ${if_data}= | interfaceAPI.Get BD Oper Data From Interface
 280 | | ... | ${node} | ${interface}
 281 | | interfaceAPI.Compare Data Structures | ${if_data} | ${bd_settings}
 282
 283 | VAT removes bridge domain
 284 | | [Documentation] Remove the specified bridge domain using VAT.
 285 | | ...
 286 | | ... | *Arguments:*
 287 | | ... | - node - Information about a DUT node. Type: dictionary
 288 | | ... | - bd_id - Bridge domain ID. Type: integer
 289 | | ...
 290 | | ... | *Example:*
 291 | | ... | \| VAT removes bridge domain \
 292 | | ... | \| ${nodes['DUT1']} \| 1 \|
 293 | | ...
 294 | | [Arguments] | ${node} | ${bd_id}
 295 | | ...
 296 | | Delete Bridge Domain VAT | ${node} | ${bd_id}