resources/libraries/robot/l2/l2_bridge_domain.robot

   1 # Copyright (c) 2020 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Library | resources.libraries.python.L2Util
  16 | Library | resources.libraries.python.InterfaceUtil
  17 | Library | resources.libraries.python.NodePath
  18 | Library | resources.libraries.python.VhostUser
  19 | Library | resources.libraries.python.Memif
  20
  21 *** Keywords ***
  22 | Show Bridge Domain Data On All DUTs
  23 | | [Documentation] | Show Bridge Domain data on all DUTs.
  24 | |
  25 | | FOR | ${dut} | IN | @{duts}
  26 | | | VPP Get Bridge Domain Data | ${nodes['${dut}']}
  27 | | END
  28
  29 | Add interface to bridge domain
  30 | | [Documentation]
  31 | | ... | Set given interface admin state to up and add this
  32 | | ... | interface to required L2 bridge domain on defined VPP node.
  33 | |
  34 | | ... | *Arguments:*
  35 | | ... | - ${dut} - DUT node. Type: dictionary
  36 | | ... | - ${dut_if} - DUT node interface name. Type: string
  37 | | ... | - ${bd_id} - Bridge domain ID. Type: integer
  38 | | ... | - ${shg} - Split-horizon group ID. Type: integer, default value: 0
  39 | |
  40 | | ... | *Example:*
  41 | |
  42 | | ... | \| Add interface to bridge domain \| ${nodes['DUT2']} \
  43 | | ... | \| GigabitEthernet0/8/0 \| 3 \|
  44 | |
  45 | | [Arguments] | ${dut} | ${dut_if} | ${bd_id} | ${shg}=0
  46 | |
  47 | | Set Interface State | ${dut} | ${dut_if} | up
  48 | | Add Interface To L2 BD | ${dut} | ${dut_if} | ${bd_id} | ${shg}
  49
  50 | Initialize L2 bridge domain on node
  51 | | [Documentation]
  52 | | ... | Setup L2 bridge domain topology by adding two interfaces on DUT into
  53 | | ... | separate bridge domains that are created automatically starting with
  54 | | ... | index 1. Learning is enabled. Interfaces are brought up.
  55 | |
  56 | | ... | *Arguments:*
  57 | | ... | - dut - DUT node. Type: string
  58 | | ... | - count - Number of bridge domains interfaces. Type: integer
  59 | |
  60 | | ... | *Example:*
  61 | |
  62 | | ... | \| Initialize L2 bridge domain on node \| DUT1 \| 1 \|
  63 | |
  64 | | [Arguments] | ${dut} | ${count}=${1}
  65 | |
  66 | | FOR | ${id} | IN RANGE | 1 | ${count} + 1
  67 | | | Add Interface To L2 BD
  68 | | | ... | ${nodes['${dut}']} | ${${dut}_${int}1_${id}}[0] | ${id}
  69 | | | Add Interface To L2 BD
  70 | | | ... | ${nodes['${dut}']} | ${${dut}_${int}2_${id}}[0] | ${id}
  71 | | END
  72
  73 | Initialize L2 bridge domain
  74 | | [Documentation]
  75 | | ... | Setup L2 bridge domain topology by adding two interfaces on each DUT
  76 | | ... | into separate bridge domains that are created automatically starting
  77 | | ... | with index 1. Learning is enabled. Interfaces are brought up.
  78 | |
  79 | | ... | *Arguments:*
  80 | | ... | - count - Number of bridge domains. Type: integer
  81 | |
  82 | | ... | *Example:*
  83 | |
  84 | | ... | \| Initialize L2 bridge domain \| 1 \|
  85 | |
  86 | | [Arguments] | ${count}=${1}
  87 | |
  88 | | FOR | ${dut} | IN | @{duts}
  89 | | | Initialize L2 bridge domain on node | ${dut} | count=${count}
  90 | | END
  91
  92 | Initialize L2 bridge domains with Vhost-User on node
  93 | | [Documentation]
  94 | | ... | Create pairs of Vhost-User interfaces for defined number of VMs on
  95 | | ... | defined VPP node. Add each Vhost-User interface into L2 bridge
  96 | | ... | domains with learning enabled with physical inteface or Vhost-User
  97 | | ... | interface of another VM.
  98 | |
  99 | | ... | *Arguments:*
 100 | | ... | - dut - DUT node. Type: string
 101 | | ... | - nf_chain - NF chain. Type: integer
 102 | | ... | - nf_nodes - Number of NFs nodes per chain. Type: integer
 103 | |
 104 | | ... | *Note:*
 105 | | ... | Socket paths for VM are defined in following format:
 106 | | ... | - /var/run/vpp/sock-\${VM_ID}-1
 107 | | ... | - /var/run/vpp/sock-\${VM_ID}-2
 108 | |
 109 | | ... | *Example:*
 110 | |
 111 | | ... | \| Initialize L2 bridge domains with Vhost-User on node \| DUT1 \
 112 | | ... | \| 1 \| 1 \|
 113 | |
 114 | | [Arguments] | ${dut} | ${nf_chain}=${1} | ${nf_nodes}=${1}
 115 | |
 116 | | ${bd_id1}= | Evaluate | ${nf_nodes} * (${nf_chain} - 1) + ${nf_chain}
 117 | | ${bd_id2}= | Evaluate | ${nf_nodes} * ${nf_chain} + ${nf_chain}
 118 | | Add interface to bridge domain
 119 | | ... | ${nodes['${dut}']} | ${${dut}_${int}1_${nf_chain}}[0]
 120 | | ... | ${bd_id1}
 121 | | Add interface to bridge domain
 122 | | ... | ${nodes['${dut}']} | ${${dut}_${int}2_${nf_chain}}[0]
 123 | | ... | ${bd_id2}
 124 | | FOR | ${nf_node} | IN RANGE | 1 | ${nf_nodes} + 1
 125 | | | ${qemu_id}= | Evaluate | (${nf_chain} - ${1}) * ${nf_nodes} + ${nf_node}
 126 | | | Configure vhost interfaces
 127 | | | ... | ${nodes['${dut}']}
 128 | | | ... | /var/run/vpp/sock-${qemu_id}-1 | /var/run/vpp/sock-${qemu_id}-2
 129 | | | ... | ${dut}-vhost-${qemu_id}-if1 | ${dut}-vhost-${qemu_id}-if2
 130 | | | ${bd_id1}= | Evaluate | ${qemu_id} + (${nf_chain} - 1)
 131 | | | ${bd_id2}= | Evaluate | ${bd_id1} + 1
 132 | | | Add interface to bridge domain
 133 | | | ... | ${nodes['${dut}']} | ${${dut}-vhost-${qemu_id}-if1} | ${bd_id1}
 134 | | | Add interface to bridge domain
 135 | | | ... | ${nodes['${dut}']} | ${${dut}-vhost-${qemu_id}-if2} | ${bd_id2}
 136 | | END
 137
 138 | Initialize L2 bridge domains with Vhost-User
 139 | | [Documentation]
 140 | | ... | Create pairs of Vhost-User interfaces for defined number of VNF nodes
 141 | | ... | on all defined VPP nodes. Add each Vhost-User interface into L2 bridge
 142 | | ... | domains with learning enabled with physical inteface or Vhost-User
 143 | | ... | interface of another VM.
 144 | |
 145 | | ... | *Arguments:*
 146 | | ... | - nf_chain - NF chain. Type: integer
 147 | | ... | - nf_nodes - Number of NFs nodes per chain. Type: integer
 148 | |
 149 | | ... | *Example:*
 150 | |
 151 | | ... | \| Initialize L2 bridge domains with Vhost-User \| 1 \| 1 \|
 152 | |
 153 | | [Arguments] | ${nf_chain}=${1} | ${nf_nodes}=${1}
 154 | |
 155 | | FOR | ${dut} | IN | @{duts}
 156 | | | Initialize L2 bridge domains with Vhost-User on node
 157 | | | ... | ${dut} | nf_chain=${nf_chain} | nf_nodes=${nf_nodes}
 158 | | END
 159
 160 | Initialize L2 bridge domains for multiple chains with Vhost-User
 161 | | [Documentation]
 162 | | ... | Create pairs of Vhost-User interfaces for defined number of NF chains
 163 | | ... | with defined number of VNF nodes on all defined VPP nodes. Add each
 164 | | ... | Vhost-User interface into L2 bridge domains with learning enabled
 165 | | ... | with physical inteface or Vhost-User interface of another VM.
 166 | | ... | Put all interfaces in path up.
 167 | |
 168 | | ... | *Arguments:*
 169 | | ... | - nf_chains - Number of chains of NFs. Type: integer
 170 | | ... | - nf_nodes - Number of NFs nodes per chain. Type: integer
 171 | | ... | - start - Id of first chain, allows to add chains during test.
 172 | | ... |     Type: integer
 173 | |
 174 | | ... | *Example:*
 175 | |
 176 | | ... | \| Initialize L2 bridge domains for multiple chains with Vhost-User \
 177 | | ... | \| 3 \| 1 \| 2 \|
 178 | |
 179 | | [Arguments] | ${nf_chains}=${1} | ${nf_nodes}=${1} | ${start}=${1}
 180 | |
 181 | | Set interfaces in path up
 182 | | FOR | ${nf_chain} | IN RANGE | ${start} | ${nf_chains} + 1
 183 | | | Initialize L2 bridge domains with Vhost-User
 184 | | | ... | nf_chain=${nf_chain} | nf_nodes=${nf_nodes}
 185 | | END
 186
 187 | Initialize L2 bridge domain with VXLANoIPv4 in 3-node circular topology
 188 | | [Documentation]
 189 | | ... | Setup L2 bridge domain topology with VXLANoIPv4 by connecting
 190 | | ... | physical and vxlan interfaces on each DUT. All interfaces are brought
 191 | | ... | up. IPv4 addresses with prefix /24 are configured on interfaces
 192 | | ... | between DUTs. VXLAN sub-interfaces has same IPv4 address as
 193 | | ... | interfaces.
 194 | |
 195 | | Set interfaces in path up
 196 | | VPP Interface Set IP Address
 197 | | ... | ${dut1} | ${DUT1_${int}2}[0] | 172.16.0.1 | 24
 198 | | VPP Interface Set IP Address
 199 | | ... | ${dut2} | ${DUT2_${int}1}[0] | 172.16.0.2 | 24
 200 | | VPP Add IP Neighbor
 201 | | ... | ${dut1} | ${DUT1_${int}2}[0] | 172.16.0.2
 202 | | ... | ${DUT2_${int}1_mac}[0]
 203 | | VPP Add IP Neighbor
 204 | | ... | ${dut2} | ${DUT2_${int}1}[0] | 172.16.0.1
 205 | | ... | ${DUT1_${int}2_mac}[0]
 206 | | ${dut1s_vxlan}= | Create VXLAN interface
 207 | | ... | ${dut1} | 24 | 172.16.0.1 | 172.16.0.2
 208 | | ${dut2s_vxlan}= | Create VXLAN interface
 209 | | ... | ${dut2} | 24 | 172.16.0.2 | 172.16.0.1
 210 | | VPP Add L2 Bridge Domain
 211 | | ... | ${dut1} | ${1} | ${DUT1_${int}1}[0] | ${dut1s_vxlan}
 212 | | Set Interface State
 213 | | ... | ${dut1} | ${dut1s_vxlan} | up
 214 | | VPP Add L2 Bridge Domain
 215 | | ... | ${dut2} | ${1} | ${DUT2_${int}2}[0] | ${dut2s_vxlan}
 216 | | Set Interface State
 217 | | ... | ${dut2} | ${dut2s_vxlan} | up
 218
 219 | Initialize L2 bridge domain with VLAN and VXLANoIPv4 in 3-node circular topology
 220 | | [Documentation]
 221 | | ... | Setup L2 bridge domain topology with VLAN and VXLANoIPv4 by connecting
 222 | | ... | pairs of VLAN sub-interface and VXLAN interface to separate L2 bridge
 223 | | ... | domain on each DUT. All interfaces are brought up. IPv4 addresses
 224 | | ... | with prefix /32 are configured on interfaces between DUTs. VXLAN
 225 | | ... | sub-interfaces has same IPv4 address as interfaces.
 226 | |
 227 | | ... | *Arguments:*
 228 | | ... | - vxlan_count - VXLAN count. Type: integer
 229 | |
 230 | | ... | *Example:*
 231 | |
 232 | | ... | \| Initialize L2 bridge domain with VLAN and VXLANoIPv4 in 3-node \
 233 | | ... | \| circular topology \| ${1} \|
 234 | |
 235 | | [Arguments] | ${vxlan_count}=${1}
 236 | |
 237 | | Set interfaces in path up
 238 | |
 239 | | ${bd_id_start}= | Set Variable | ${1}
 240 | | ${vni_start} = | Set Variable | ${20}
 241 | |
 242 | | ${ip_step} = | Set Variable | ${2}
 243 | | ${dut1_ip_start}= | Set Variable | 172.16.0.1
 244 | | ${dut2_ip_start}= | Set Variable | 172.16.0.2
 245 | |
 246 | | Vpp create multiple VXLAN IPv4 tunnels
 247 | | ... | node=${dut1}
 248 | | ... | node_vxlan_if=${DUT1_${int}2}[0]
 249 | | ... | node_vlan_if=${DUT1_${int}1}[0]
 250 | | ... | op_node=${dut2}
 251 | | ... | op_node_if=${DUT2_${int}1}[0]
 252 | | ... | n_tunnels=${vxlan_count}
 253 | | ... | vni_start=${vni_start}
 254 | | ... | src_ip_start=${dut1_ip_start}
 255 | | ... | dst_ip_start=${dut2_ip_start}
 256 | | ... | ip_step=${ip_step}
 257 | | ... | bd_id_start=${bd_id_start}
 258 | | Vpp create multiple VXLAN IPv4 tunnels
 259 | | ... | node=${dut2}
 260 | | ... | node_vxlan_if=${DUT2_${int}1}[0]
 261 | | ... | node_vlan_if=${DUT2_${int}2}[0]
 262 | | ... | op_node=${dut1}
 263 | | ... | op_node_if=${DUT1_${int}2}[0]
 264 | | ... | n_tunnels=${vxlan_count}
 265 | | ... | vni_start=${vni_start}
 266 | | ... | src_ip_start=${dut2_ip_start}
 267 | | ... | dst_ip_start=${dut1_ip_start}
 268 | | ... | ip_step=${ip_step}
 269 | | ... | bd_id_start=${bd_id_start}
 270
 271 | Initialize L2 bridge domains with Vhost-User and VXLANoIPv4 in 3-node circular topology
 272 | | [Documentation]
 273 | | ... | Create two Vhost-User interfaces on all defined VPP nodes. Add each
 274 | | ... | Vhost-User interface into L2 bridge domains with learning enabled
 275 | | ... | with physical inteface.
 276 | | ... | Setup VXLANoIPv4 between DUTs by connecting physical and vxlan
 277 | | ... | interfaces on each DUT. All interfaces are brought up.
 278 | | ... | IPv4 addresses with prefix /24 are configured on interfaces between
 279 | | ... | DUTs. VXLAN sub-interfaces has same IPv4 address as interfaces.
 280 | |
 281 | | ... | *Arguments:*
 282 | | ... | - bd_id1 - Bridge domain ID. Type: integer
 283 | | ... | - bd_id2 - Bridge domain ID. Type: integer
 284 | |
 285 | | ... | *Example:*
 286 | |
 287 | | ... | \| L2 bridge domains with Vhost-User and VXLANoIPv4 initialized in a\
 288 | | ... | 3-node circular topology \| 1 \| 2 \|
 289 | |
 290 | | [Arguments] | ${bd_id1} | ${bd_id2}
 291 | |
 292 | | VPP Interface Set IP Address
 293 | | ... | ${dut1} | ${DUT1_${int}2}[0] | 172.16.0.1 | 24
 294 | | VPP Interface Set IP Address
 295 | | ... | ${dut2} | ${DUT2_${int}1}[0] | 172.16.0.2 | 24
 296 | | Set interfaces in path up
 297 | | ${dut1s_vxlan}= | Create VXLAN interface
 298 | | ... | ${dut1} | 24 | 172.16.0.1 | 172.16.0.2
 299 | | ${dut2s_vxlan}= | Create VXLAN interface
 300 | | ... | ${dut2} | 24 | 172.16.0.2 | 172.16.0.1
 301 | | Configure vhost interfaces | ${dut1}
 302 | | ... | /var/run/vpp/sock-1-${bd_id1} | /var/run/vpp/sock-1-${bd_id2}
 303 | | Add interface to bridge domain
 304 | | ... | ${dut1} | ${DUT1_${int}1}[0] | ${bd_id1}
 305 | | Add interface to bridge domain
 306 | | ... | ${dut1} | ${vhost_if1} | ${bd_id1}
 307 | | Add interface to bridge domain
 308 | | ... | ${dut1} | ${vhost_if2} | ${bd_id2}
 309 | | Add interface to bridge domain
 310 | | ... | ${dut1} | ${dut1s_vxlan} | ${bd_id2}
 311 | | Configure vhost interfaces | ${dut2}
 312 | | ... | /var/run/vpp/sock-1-${bd_id1} | /var/run/vpp/sock-1-${bd_id2}
 313 | | Add interface to bridge domain
 314 | | ... | ${dut2} | ${dut2s_vxlan} | ${bd_id1}
 315 | | Add interface to bridge domain
 316 | | ... | ${dut2} | ${vhost_if1} | ${bd_id1}
 317 | | Add interface to bridge domain
 318 | | ... | ${dut2} | ${vhost_if2} | ${bd_id2}
 319 | | Add interface to bridge domain
 320 | | ... | ${dut2} | ${DUT2_${int}2}[0] | ${bd_id2}
 321
 322 | Initialize L2 bridge domains with VLAN dot1q sub-interfaces in circular topology
 323 | | [Documentation]
 324 | | ... | Setup L2 bridge domain topology with learning enabled with VLAN by
 325 | | ... | connecting physical and vlan interfaces on each DUT. In case of 3-node
 326 | | ... | topology create VLAN sub-interfaces between DUTs. In case of 2-node
 327 | | ... | topology create VLAN sub-interface on dut1-if2 interface. All
 328 | | ... | interfaces are brought up.
 329 | |
 330 | | ... | *Arguments:*
 331 | | ... | - bd_id1 - Bridge domain ID. Type: integer
 332 | | ... | - bd_id2 - Bridge domain ID. Type: integer
 333 | | ... | - subid - ID of the sub-interface to be created. Type: string
 334 | | ... | - tag_rewrite - Method of tag rewrite. Type: string
 335 | |
 336 | | ... | _NOTE:_ This KW uses following test case variables:
 337 | | ... | - dut1 - DUT1 node.
 338 | | ... | - dut2 - DUT2 node.
 339 | | ... | - dut1_if2 - DUT1 interface towards DUT2.
 340 | | ... | - dut2_if1 - DUT2 interface towards DUT1.
 341 | |
 342 | | ... | *Example:*
 343 | |
 344 | | ... | \| Initialize L2 bridge domains with VLAN dot1q sub-interfaces
 345 | | ... | in a 3-node circular topology \| 1 \| 2 \| 10 \| pop-1 \|
 346 | |
 347 | | [Arguments] | ${bd_id1} | ${bd_id2} | ${subid} | ${tag_rewrite}
 348 | |
 349 | | ${dut2_status} | ${value}= | Run Keyword And Ignore Error
 350 | | ... | Variable Should Exist | ${dut2}
 351 | |
 352 | | Set interfaces in path up
 353 | |
 354 | | Run Keyword If | '${dut2_status}' == 'PASS'
 355 | | ... | Initialize VLAN dot1q sub-interfaces in circular topology
 356 | | ... | ${dut1} | ${DUT1_${int}2}[0]
 357 | | ... | ${dut2} | ${DUT2_${int}1}[0] | SUB_ID=${subid}
 358 | | ... | ELSE | Initialize VLAN dot1q sub-interfaces in circular topology
 359 | | ... | ${dut1} | ${DUT1_${int}2}[0] | SUB_ID=${subid}
 360 | | Run Keyword If | '${dut2_status}' == 'PASS'
 361 | | ... | Configure L2 tag rewrite method on interfaces
 362 | | ... | ${dut1} | ${subif_index_1}
 363 | | ... | ${dut2} | ${subif_index_2} | TAG_REWRITE_METHOD=${tag_rewrite}
 364 | | ... | ELSE | Configure L2 tag rewrite method on interfaces
 365 | | ... | ${dut1} | ${subif_index_1} | TAG_REWRITE_METHOD=${tag_rewrite}
 366 | | Add interface to bridge domain
 367 | | ... | ${dut1} | ${DUT1_${int}1}[0] | ${bd_id1}
 368 | | Add interface to bridge domain
 369 | | ... | ${dut1} | ${subif_index_1} | ${bd_id1}
 370 | | Run Keyword If | '${dut2_status}' == 'PASS'
 371 | | ... | Add interface to bridge domain
 372 | | ... | ${dut2} | ${subif_index_2} | ${bd_id2}
 373 | | Run Keyword If | '${dut2_status}' == 'PASS'
 374 | | ... | Add interface to bridge domain
 375 | | ... | ${dut2} | ${DUT2_${int}2}[0] | ${bd_id2}
 376
 377 | Initialize L2 bridge domains with Vhost-User and VLAN in circular topology
 378 | | [Documentation]
 379 | | ... | Create two Vhost-User interfaces on all defined VPP nodes. Add each
 380 | | ... | Vhost-User interface into L2 bridge domains with learning enabled
 381 | | ... | with physical inteface. In case of 3-node topology create VLAN
 382 | | ... | sub-interfaces between DUTs. In case of 2-node topology create VLAN
 383 | | ... | sub-interface on dut1-if2 interface. All interfaces are brought up.
 384 | |
 385 | | ... | *Arguments:*
 386 | | ... | - bd_id1 - Bridge domain ID. Type: integer
 387 | | ... | - bd_id2 - Bridge domain ID. Type: integer
 388 | | ... | - subid - ID of the sub-interface to be created. Type: string
 389 | | ... | - tag_rewrite - Method of tag rewrite. Type: string
 390 | |
 391 | | ... | *Example:*
 392 | |
 393 | | ... | \| L2 bridge domains with Vhost-User and VLAN initialized in circular\
 394 | | ... | topology \| 1 \| 2 \| 10 \| pop-1 \|
 395 | |
 396 | | [Arguments] | ${bd_id1} | ${bd_id2} | ${subid} | ${tag_rewrite}
 397 | |
 398 | | ${dut2_status} | ${value}= | Run Keyword And Ignore Error
 399 | | ... | Variable Should Exist | ${dut2}
 400 | |
 401 | | Set interfaces in path up
 402 | |
 403 | | Run Keyword If | '${dut2_status}' == 'PASS'
 404 | | ... | Initialize VLAN dot1q sub-interfaces in circular topology
 405 | | ... | ${dut1} | ${DUT1_${int}2}[0]
 406 | | ... | ${dut2} | ${DUT2_${int}1}[0] | SUB_ID=${subid}
 407 | | ... | ELSE | Initialize VLAN dot1q sub-interfaces in circular topology
 408 | | ... | ${dut1} | ${DUT1_${int}2}[0] | SUB_ID=${subid}
 409 | | Run Keyword If | '${dut2_status}' == 'PASS'
 410 | | ... | Configure L2 tag rewrite method on interfaces
 411 | | ... | ${dut1} | ${subif_index_1}
 412 | | ... | ${dut2} | ${subif_index_2} | TAG_REWRITE_METHOD=${tag_rewrite}
 413 | | ... | ELSE | Configure L2 tag rewrite method on interfaces
 414 | | ... | ${dut1} | ${subif_index_1} | TAG_REWRITE_METHOD=${tag_rewrite}
 415 | | Configure vhost interfaces | ${dut1}
 416 | | ... | /var/run/vpp/sock-1-${bd_id1} | /var/run/vpp/sock-1-${bd_id2}
 417 | | Add interface to bridge domain
 418 | | ... | ${dut1} | ${DUT1_${int}1}[0] | ${bd_id1}
 419 | | Add interface to bridge domain
 420 | | ... | ${dut1} | ${vhost_if1} | ${bd_id1}
 421 | | Add interface to bridge domain
 422 | | ... | ${dut1} | ${vhost_if2} | ${bd_id2}
 423 | | Add interface to bridge domain
 424 | | ... | ${dut1} | ${subif_index_1} | ${bd_id2}
 425 | | Run Keyword If | '${dut2_status}' == 'PASS'
 426 | | ... | Configure vhost interfaces | ${dut2}
 427 | | ... | /var/run/vpp/sock-1-${bd_id1} | /var/run/vpp/sock-1-${bd_id2}
 428 | | Run Keyword If | '${dut2_status}' == 'PASS'
 429 | | ... | Add interface to bridge domain | ${dut2} | ${subif_index_2}
 430 | | ... | ${bd_id1}
 431 | | Run Keyword If | '${dut2_status}' == 'PASS'
 432 | | ... | Add interface to bridge domain | ${dut2} | ${vhost_if1} | ${bd_id1}
 433 | | Run Keyword If | '${dut2_status}' == 'PASS'
 434 | | ... | Add interface to bridge domain | ${dut2} | ${vhost_if2} | ${bd_id2}
 435 | | Run Keyword If | '${dut2_status}' == 'PASS'
 436 | | ... | Add interface to bridge domain | ${dut2} | ${DUT2_${int}2}[0]
 437 | | ... | ${bd_id2}
 438
 439 | Initialize L2 bridge domains with Vhost-User and VLAN with VPP link bonding in a 3-node circular topology
 440 | | [Documentation]
 441 | | ... | Create two Vhost-User interfaces on all defined VPP nodes. Create one
 442 | | ... | link bonding (BondEthernet) interface on both VPP nodes. Enslave one
 443 | | ... | physical interface towards next DUT by BondEthernet interface. Setup
 444 | | ... | VLAN on BondEthernet interfaces between DUTs. Add one Vhost-User
 445 | | ... | interface into L2 bridge domains with learning enabled with physical
 446 | | ... | interface towards TG and other Vhost-User interface into L2 bridge
 447 | | ... | domains with learning enabled with VLAN sub-interface. All interfaces
 448 | | ... | are brought up.
 449 | |
 450 | | ... | *Arguments:*
 451 | | ... | - bd_id1 - Bridge domain ID. Type: integer
 452 | | ... | - bd_id2 - Bridge domain ID. Type: integer
 453 | | ... | - subid - ID of the sub-interface to be created. Type: string
 454 | | ... | - tag_rewrite - Method of tag rewrite. Type: string
 455 | | ... | - bond_mode - Link bonding mode. Type: string
 456 | | ... | - lb_mode - Load balance mode. Type: string
 457 | |
 458 | | ... | *Example:*
 459 | |
 460 | | ... | \| Initialize L2 bridge domains with Vhost-User and VLAN with VPP\
 461 | | ... | link bonding in a 3-node circular topology \| 1 \| 2 \
 462 | | ... | \| 10 \| pop-1 \| xor \| l34 \|
 463 | |
 464 | | [Arguments] | ${bd_id1} | ${bd_id2} | ${subid} | ${tag_rewrite}
 465 | | ... | ${bond_mode} | ${lb_mode}
 466 | |
 467 | | Set interfaces in path up
 468 | | ${dut1_eth_bond_if1}= | VPP Create Bond Interface
 469 | | ... | ${dut1} | ${bond_mode} | ${lb_mode}
 470 | | Set Interface State | ${dut1} | ${dut1_eth_bond_if1} | up
 471 | | VPP Set interface MTU | ${dut1} | ${dut1_eth_bond_if1}
 472 | | FOR | ${pf} | IN RANGE | 1 | ${nic_pfs} + 1
 473 | | | ${_even}= | Evaluate | ${pf} % 2
 474 | | | Run Keyword Unless | ${even}
 475 | | | ... | VPP Enslave Physical Interface
 476 | | | ... | ${dut1} | ${DUT1_${int}${pf}}[0] | ${dut1_eth_bond_if1}
 477 | | END
 478 | | ${dut2_eth_bond_if1}= | VPP Create Bond Interface
 479 | | ... | ${dut2} | ${bond_mode} | ${lb_mode}
 480 | | Set Interface State | ${dut2} | ${dut2_eth_bond_if1} | up
 481 | | VPP Set interface MTU | ${dut2} | ${dut2_eth_bond_if1}
 482 | | FOR | ${pf} | IN RANGE | 1 | ${nic_pfs} + 1
 483 | | | ${_even}= | Evaluate | ${pf} % 2
 484 | | | Run Keyword If | ${even}
 485 | | | ... | VPP Enslave Physical Interface
 486 | | | ... | ${dut2} | ${DUT2_${int}${pf}}[0] | ${dut2_eth_bond_if1}
 487 | | END
 488 | | VPP Show Bond Data On All Nodes | ${nodes} | verbose=${TRUE}
 489 | | Initialize VLAN dot1q sub-interfaces in circular topology
 490 | | ... | ${dut1} | ${dut1_eth_bond_if1}
 491 | | ... | ${dut2} | ${dut2_eth_bond_if1} | ${subid}
 492 | | Configure L2 tag rewrite method on interfaces
 493 | | ... | ${dut1} | ${subif_index_1}
 494 | | ... | ${dut2} | ${subif_index_2} | ${tag_rewrite}
 495 | | Configure vhost interfaces | ${dut1}
 496 | | ... | /var/run/vpp/sock-1-${bd_id1} | /var/run/vpp/sock-1-${bd_id2}
 497 | | Add interface to bridge domain
 498 | | ... | ${dut1} | ${DUT1_${int}1}[0] | ${bd_id1}
 499 | | Add interface to bridge domain
 500 | | ... | ${dut1} | ${vhost_if1} | ${bd_id1}
 501 | | Add interface to bridge domain
 502 | | ... | ${dut1} | ${vhost_if2} | ${bd_id2}
 503 | | Add interface to bridge domain
 504 | | ... | ${dut1} | ${subif_index_1} | ${bd_id2}
 505 | | Configure vhost interfaces | ${dut2}
 506 | | ... | /var/run/vpp/sock-1-${bd_id1} | /var/run/vpp/sock-1-${bd_id2}
 507 | | Add interface to bridge domain
 508 | | ... | ${dut2} | ${subif_index_2} | ${bd_id1}
 509 | | Add interface to bridge domain
 510 | | ... | ${dut2} | ${vhost_if1} | ${bd_id1}
 511 | | Add interface to bridge domain
 512 | | ... | ${dut2} | ${vhost_if2} | ${bd_id2}
 513 | | Add interface to bridge domain
 514 | | ... | ${dut2} | ${DUT2_${int}2}[0] | ${bd_id2}
 515
 516 | Initialize L2 Bridge Domain with memif pairs on DUT node
 517 | | [Documentation]
 518 | | ... | Create pairs of Memif interfaces on DUT node. Put each Memif interface
 519 | | ... | to separate L2 bridge domain with one physical or memif interface
 520 | | ... | to create a chain accross DUT node.
 521 | |
 522 | | ... | *Arguments:*
 523 | | ... | - dut - DUT node. Type: dictionary
 524 | | ... | - nf_chain - NF chain. Type: integer
 525 | | ... | - nf_nodes - Number of NFs nodes per chain. Type: integer
 526 | | ... | - auto_scale - Whether to use same amount of RXQs for memif interface
 527 | | ... | in containers as vswitch, otherwise use single RXQ. Type: boolean
 528 | |
 529 | | ... | *Note:*
 530 | | ... | Socket paths for Memif are defined in following format:
 531 | | ... | - /tmp/memif-\${dut}_CNF\${nf_id}-\${sid}
 532 | |
 533 | | ... | *Example:*
 534 | |
 535 | | ... | \| Initialize L2 Bridge Domain with memif pairs on DUT node \
 536 | | ... | \| ${dut} \| 1 \| 1 \|
 537 | |
 538 | | [Arguments] | ${dut} | ${nf_chain}=${1} | ${nf_nodes}=${1}
 539 | | ... | ${auto_scale}=${True}
 540 | |
 541 | | ${rxq}= | Run Keyword If | ${auto_scale} == ${True}
 542 | | ... | Set Variable | ${rxq_count_int}
 543 | | ... | ELSE | Set Variable | ${1}
 544 | | ${bd_id1}= | Evaluate | ${nf_nodes} * (${nf_chain} - 1) + ${nf_chain}
 545 | | ${bd_id2}= | Evaluate | ${nf_nodes} * ${nf_chain} + ${nf_chain}
 546 | | Add interface to bridge domain
 547 | | ... | ${nodes['${dut}']} | ${${dut}_${int}1_${nf_chain}}[0]
 548 | | ... | ${bd_id1}
 549 | | Add interface to bridge domain
 550 | | ... | ${nodes['${dut}']} | ${${dut}_${int}2_${nf_chain}}[0]
 551 | | ... | ${bd_id2}
 552 | | FOR | ${nf_node} | IN RANGE | 1 | ${nf_nodes}+1
 553 | | | ${nf_id}= | Evaluate | (${nf_chain} - ${1}) * ${nf_nodes} + ${nf_node}
 554 | | | ${sock1}= | Set Variable | memif-${dut}_CNF
 555 | | | ${sock2}= | Set Variable | memif-${dut}_CNF
 556 | | | ${bd_id1}= | Evaluate | ${nf_id} + (${nf_chain} - 1)
 557 | | | ${bd_id2}= | Evaluate | ${bd_id1} + 1
 558 | | | Set up memif interfaces on DUT node | ${nodes['${dut}']}
 559 | | | ... | ${sock1} | ${sock2} | ${nf_id} | ${dut}-memif-${nf_id}-if1
 560 | | | ... | ${dut}-memif-${nf_id}-if2 | ${rxq} | ${rxq}
 561 | | | Add interface to bridge domain
 562 | | | ... | ${nodes['${dut}']} | ${${dut}-memif-${nf_id}-if1} | ${bd_id1}
 563 | | | Add interface to bridge domain
 564 | | | ... | ${nodes['${dut}']} | ${${dut}-memif-${nf_id}-if2} | ${bd_id2}
 565 | | END
 566
 567 | Initialize L2 Bridge Domain with memif pairs
 568 | | [Documentation]
 569 | | ... | Create pairs of Memif interfaces on all defined VPP nodes. Put each
 570 | | ... | Memif interface to separate L2 bridge domain with one physical or
 571 | | ... | virtual interface to create a chain accross DUT node.
 572 | |
 573 | | ... | *Arguments:*
 574 | | ... | - nf_chain - NF chain. Type: integer
 575 | | ... | - nf_nodes - Number of NFs nodes per chain. Type: integer
 576 | | ... | - auto_scale - Whether to use same amount of RXQs for memif interface
 577 | | ... | in containers as vswitch, otherwise use single RXQ. Type: boolean
 578 | |
 579 | | ... | *Example:*
 580 | |
 581 | | ... | \| Initialize L2 Bridge Domain with memif pairs \| 1 \| 1 \|
 582 | |
 583 | | [Arguments] | ${nf_chain}=${1} | ${nf_nodes}=${1} | ${auto_scale}=${True}
 584 | |
 585 | | FOR | ${dut} | IN | @{duts}
 586 | | | Initialize L2 Bridge Domain with memif pairs on DUT node | ${dut}
 587 | | | ... | nf_chain=${nf_chain} | nf_nodes=${nf_nodes}
 588 | | | ... | auto_scale=${auto_scale}
 589 | | END
 590
 591 | Initialize L2 Bridge Domain for multiple chains with memif pairs
 592 | | [Documentation]
 593 | | ... | Create pairs of Memif interfaces for defined number of NF chains
 594 | | ... | with defined number of NF nodes on all defined VPP nodes. Add each
 595 | | ... | Memif interface into L2 bridge domains with learning enabled
 596 | | ... | with physical inteface or Memif interface of another NF.
 597 | |
 598 | | ... | *Arguments:*
 599 | | ... | - nf_chains - Number of chains of NFs. Type: integer
 600 | | ... | - nf_nodes - Number of NFs nodes per chain. Type: integer
 601 | | ... | - auto_scale - Whether to use same amount of RXQs for memif interface
 602 | | ... | in containers as vswitch, otherwise use single RXQ. Type: boolean
 603 | |
 604 | | ... | *Example:*
 605 | |
 606 | | ... | \| Initialize L2 Bridge Domain for multiple chains with memif pairs \
 607 | | ... | \| 1 \| 1 \|
 608 | |
 609 | | [Arguments] | ${nf_chains}=${1} | ${nf_nodes}=${1} | ${auto_scale}=${True}
 610 | |
 611 | | FOR | ${nf_chain} | IN RANGE | 1 | ${nf_chains}+1
 612 | | | Initialize L2 Bridge Domain with memif pairs | nf_chain=${nf_chain}
 613 | | | ... | nf_nodes=${nf_nodes} | auto_scale=${auto_scale}
 614 | | END
 615 | | Set interfaces in path up
 616 | | Show Memif on all DUTs | ${nodes}
 617 | | VPP round robin RX placement on all DUTs | ${nodes} | prefix=memif
 618
 619 | Initialize L2 Bridge Domain for pipeline with memif pairs
 620 | | [Documentation]
 621 | | ... | Create pairs of Memif interfaces on all defined VPP nodes. Put each
 622 | | ... | Memif interface to separate L2 bridge domain with one physical or
 623 | | ... | virtual interface to create a service pipeline on DUT node.
 624 | |
 625 | | ... | *Arguments:*
 626 | | ... | - nf_chain - NF pipe. Type: integer
 627 | | ... | - nf_nodes - Number of NFs nodes per pipeline. Type: integer
 628 | | ... | - auto_scale - Whether to use same amount of RXQs for memif interface
 629 | | ... | in containers as vswitch, otherwise use single RXQ. Type: boolean
 630 | |
 631 | | ... | *Example:*
 632 | |
 633 | | ... | \| Initialize L2 Bridge Domain for pipeline with memif pairs \
 634 | | ... | \| 1 \| 1 \|
 635 | |
 636 | | [Arguments] | ${nf_chain}=${1} | ${nf_nodes}=${1} | ${auto_scale}=${True}
 637 | |
 638 | | ${rxq}= | Run Keyword If | ${auto_scale} == ${True}
 639 | | ... | Set Variable | ${rxq_count_int}
 640 | | ... | ELSE | Set Variable | ${1}
 641 | | ${bd_id1}= | Evaluate | ${nf_nodes} * (${nf_chain} - 1) + ${nf_chain}
 642 | | ${bd_id2}= | Evaluate | ${nf_nodes} * ${nf_chain} + ${nf_chain}
 643 | | FOR | ${dut} | IN | @{duts}
 644 | | | Add interface to bridge domain
 645 | | | ... | ${nodes['${dut}']} | ${${dut}_${int}1_${nf_chain}}[0]
 646 | | | ... | ${bd_id1}
 647 | | | Add interface to bridge domain
 648 | | | ... | ${nodes['${dut}']} | ${${dut}_${int}2_${nf_chain}}[0]
 649 | | | ... | ${bd_id2}
 650 | | | ${nf_id_frst}= | Evaluate | (${nf_chain}-${1}) * ${nf_nodes} + ${1}
 651 | | | ${nf_id_last}= | Evaluate | (${nf_chain}-${1}) * ${nf_nodes} + ${nf_nodes}
 652 | | | ${sid_frst}= | Evaluate | ${nf_id_frst} * ${2} - ${1}
 653 | | | ${sid_last}= | Evaluate | ${nf_id_last} * ${2}
 654 | | | Set up single memif interface on DUT node | ${nodes['${dut}']}
 655 | | | ... | memif-${dut}_CNF | mid=${nf_id_frst} | sid=${sid_frst}
 656 | | | ... | memif_if=${dut}-memif-${nf_id_frst}-if1
 657 | | | ... | rxq=${rxq} | txq=${rxq}
 658 | | | Set up single memif interface on DUT node | ${nodes['${dut}']}
 659 | | | ... | memif-${dut}_CNF | mid=${nf_id_last} | sid=${sid_last}
 660 | | | ... | memif_if=${dut}-memif-${nf_id_last}-if2
 661 | | | ... | rxq=${rxq} | txq=${rxq}
 662 | | | Add interface to bridge domain
 663 | | | ... | ${nodes['${dut}']} | ${${dut}-memif-${nf_id_frst}-if1} | ${bd_id1}
 664 | | | Add interface to bridge domain
 665 | | | ... | ${nodes['${dut}']} | ${${dut}-memif-${nf_id_last}-if2} | ${bd_id2}
 666 | | END
 667
 668 | Initialize L2 Bridge Domain for multiple pipelines with memif pairs
 669 | | [Documentation]
 670 | | ... | Create pairs of Memif interfaces for defined number of NF pipelines
 671 | | ... | with defined number of NF nodes on all defined VPP nodes. Add each
 672 | | ... | Memif interface into L2 bridge domains with learning enabled
 673 | | ... | with physical inteface or Memif interface of another NF.
 674 | |
 675 | | ... | *Arguments:*
 676 | | ... | - nf_chains - Number of pipelines of NFs. Type: integer
 677 | | ... | - nf_nodes - Number of NFs nodes per pipeline. Type: integer
 678 | | ... | - auto_scale - Whether to use same amount of RXQs for memif interface
 679 | | ... | in containers as vswitch, otherwise use single RXQ. Type: boolean
 680 | |
 681 | | ... | *Example:*
 682 | |
 683 | | ... | \| Initialize L2 Bridge Domain for multiple pipelines with memif \
 684 | | ... | pairs \| 1 \| 1 \|
 685 | |
 686 | | [Arguments] | ${nf_chains}=${1} | ${nf_nodes}=${1} | ${auto_scale}=${True}
 687 | |
 688 | | FOR | ${nf_chain} | IN RANGE | 1 | ${nf_chains}+1
 689 | | | Initialize L2 Bridge Domain for pipeline with memif pairs
 690 | | | ... | nf_chain=${nf_chain} | nf_nodes=${nf_nodes}
 691 | | | ... | auto_scale=${auto_scale}
 692 | | END
 693 | | Set interfaces in path up
 694 | | Show Memif on all DUTs | ${nodes}
 695 | | VPP round robin RX placement on all DUTs | ${nodes} | prefix=memif
 696
 697 | Initialize L2 Bridge Domain with memif pairs and VLAN in circular topology
 698 | | [Documentation]
 699 | | ... | Create pairs of Memif interfaces on all defined VPP nodes. Put each
 700 | | ... | Memif interface to separate L2 bridge domain with one physical or
 701 | | ... | virtual interface to create a chain accross DUT node. In case of
 702 | | ... | 3-node topology create VLAN sub-interfaces between DUTs. In case of
 703 | | ... | 2-node topology create VLAN sub-interface on dut1-if2 interface. All
 704 | | ... | interfaces are brought up.
 705 | |
 706 | | ... | *Arguments:*
 707 | | ... | - bd_id1 - Bridge domain ID. Type: integer
 708 | | ... | - bd_id2 - Bridge domain ID. Type: integer
 709 | | ... | - subid - ID of the sub-interface to be created. Type: string
 710 | | ... | - tag_rewrite - Method of tag rewrite. Type: string
 711 | |
 712 | | ... | *Example:*
 713 | |
 714 | | ... | \| Initialize L2 Bridge Domain with memif pairs and VLAN in circular\
 715 | | ... | topology \| 1 \| 2 \| 10 \| pop-1 \|
 716 | |
 717 | | [Arguments] | ${bd_id1} | ${bd_id2} | ${subid} | ${tag_rewrite}
 718 | |
 719 | | ${dut2_status} | ${value}= | Run Keyword And Ignore Error
 720 | | ... | Variable Should Exist | ${dut2}
 721 | |
 722 | | Set interfaces in path up
 723 | |
 724 | | Run Keyword If | '${dut2_status}' == 'PASS'
 725 | | ... | Initialize VLAN dot1q sub-interfaces in circular topology
 726 | | ... | ${dut1} | ${DUT1_${int}2}[0]
 727 | | ... | ${dut2} | ${DUT2_${int}1}[0] | SUB_ID=${subid}
 728 | | ... | ELSE | Initialize VLAN dot1q sub-interfaces in circular topology
 729 | | ... | ${dut1} | ${DUT1_${int}2}[0] | SUB_ID=${subid}
 730 | | Run Keyword If | '${dut2_status}' == 'PASS'
 731 | | ... | Configure L2 tag rewrite method on interfaces
 732 | | ... | ${dut1} | ${subif_index_1}
 733 | | ... | ${dut2} | ${subif_index_2} | TAG_REWRITE_METHOD=${tag_rewrite}
 734 | | ... | ELSE | Configure L2 tag rewrite method on interfaces
 735 | | ... | ${dut1} | ${subif_index_1} | TAG_REWRITE_METHOD=${tag_rewrite}
 736 | |
 737 | | ${number}= | Set Variable | ${1}
 738 | | ${sock1}= | Set Variable | memif-DUT1_CNF
 739 | | ${sock2}= | Set Variable | memif-DUT1_CNF
 740 | | ${memif_if1_name}= | Set Variable | DUT1-memif-${number}-if1
 741 | | ${memif_if2_name}= | Set Variable | DUT1-memif-${number}-if2
 742 | | Set up memif interfaces on DUT node | ${dut1} | ${sock1} | ${sock2}
 743 | | ... | ${number} | ${memif_if1_name} | ${memif_if2_name} | ${rxq_count_int}
 744 | | ... | ${rxq_count_int}
 745 | | Add interface to bridge domain
 746 | | ... | ${dut1} | ${DUT1_${int}1}[0] | ${bd_id1}
 747 | | Add interface to bridge domain
 748 | | ... | ${dut1} | ${${memif_if1_name}} | ${bd_id1}
 749 | | Add interface to bridge domain
 750 | | ... | ${dut1} | ${${memif_if2_name}} | ${bd_id2}
 751 | | Add interface to bridge domain
 752 | | ... | ${dut1} | ${subif_index_1} | ${bd_id2}
 753 | | ${sock1}= | Run Keyword If | '${dut2_status}' == 'PASS'
 754 | | ... | Set Variable | memif-DUT2_CNF
 755 | | ${sock2}= | Run Keyword If | '${dut2_status}' == 'PASS'
 756 | | ... | Set Variable | memif-DUT2_CNF
 757 | | ${memif_if1_name}= | Run Keyword If | '${dut2_status}' == 'PASS'
 758 | | ... | Set Variable | DUT2-memif-${number}-if1
 759 | | ${memif_if2_name}= | Run Keyword If | '${dut2_status}' == 'PASS'
 760 | | ... | Set Variable | DUT2-memif-${number}-if2
 761 | | Run Keyword If | '${dut2_status}' == 'PASS'
 762 | | ... | Set up memif interfaces on DUT node | ${dut2} | ${sock1} | ${sock2}
 763 | | ... | ${number} | ${memif_if1_name} | ${memif_if2_name} | ${rxq_count_int}
 764 | | ... | ${rxq_count_int}
 765 | | Run Keyword If | '${dut2_status}' == 'PASS'
 766 | | ... | Add interface to bridge domain
 767 | | ... | ${dut2} | ${subif_index_2} | ${bd_id1}
 768 | | Run Keyword If | '${dut2_status}' == 'PASS'
 769 | | ... | Add interface to bridge domain
 770 | | ... | ${dut2} | ${${memif_if1_name}} | ${bd_id1}
 771 | | Run Keyword If | '${dut2_status}' == 'PASS'
 772 | | ... | Add interface to bridge domain
 773 | | ... | ${dut2} | ${${memif_if2_name}} | ${bd_id2}
 774 | | Run Keyword If | '${dut2_status}' == 'PASS'
 775 | | ... | Add interface to bridge domain
 776 | | ... | ${dut2} | ${DUT2_${int}2}[0] | ${bd_id2}
 777 | |
 778 | | Show Memif on all DUTs | ${nodes}
 779 | | VPP round robin RX placement on all DUTs | ${nodes} | prefix=memif
 780
 781 | Initialize L2 Bridge Domain for single memif
 782 | | [Documentation]
 783 | | ... | Create single Memif interface on all defined VPP nodes. Put Memif
 784 | | ... | interface to separate L2 bridge domain with one physical interface.
 785 | |
 786 | | ... | *Arguments:*
 787 | | ... | - number - Memif ID. Type: integer
 788 | |
 789 | | ... | *Note:*
 790 | | ... | Socket paths for Memif are defined in following format:
 791 | | ... | - /tmp/memif-DUT1_CNF\${number}-\${sid}
 792 | |
 793 | | ... | KW uses test variable ${rxq_count_int} set by KW Add worker threads
 794 | | ... | and rxqueues to all DUTs
 795 | |
 796 | | ... | *Example:*
 797 | |
 798 | | ... | \| Initialize L2 Bridge Domain for single memif \| 1 \|
 799 | |
 800 | | [Arguments] | ${number}=${1}
 801 | |
 802 | | FOR | ${dut} | IN | @{duts}
 803 | | | ${sock}= | Set Variable | memif-${dut}_CNF
 804 | | | ${sid}= | Evaluate | (${number} * ${2}) - ${1}
 805 | | | Set up single memif interface on DUT node | ${nodes['${dut}']} | ${sock}
 806 | | | ... | mid=${number} | sid=${sid} | memif_if=${dut}-memif-${number}-if1
 807 | | | ... | rxq=${rxq_count_int} | txq=${rxq_count_int}
 808 | | | Add interface to bridge domain
 809 | | | ... | ${nodes['${dut}']} | ${${dut}_${int}1}[]0 | ${number}
 810 | | | Add interface to bridge domain | ${nodes['${dut}']}
 811 | | | ... | ${${dut}-memif-${number}-if1} | ${number}
 812 | | END
 813 | | Set single interfaces in path up
 814 | | Show Memif on all DUTs | ${nodes}
 815
 816 | Initialize L2 bridge domain with MACIP ACLs on DUT1 in 3-node circular topology
 817 | | [Documentation]
 818 | | ... | Setup L2BD topology by adding two interfaces on DUT1 into bridge
 819 | | ... | domain that is created automatically with index 1. Learning is
 820 | | ... | enabled. Interfaces are brought up. Apply required MACIP ACL rules to
 821 | | ... | DUT1 interfaces.
 822 | |
 823 | | Set interfaces in path up
 824 | | VPP Add L2 Bridge Domain
 825 | | ... | ${dut1} | ${1} | ${DUT1_${int}1}[0] | ${DUT1_${int}2}[0]
 826 | | Configure L2XC
 827 | | ... | ${dut2} | ${DUT2_${int}1}[0] | ${DUT2_${int}2}[0]
 828 | | Configure MACIP ACLs
 829 | | ... | ${dut1} | ${DUT1_${int}1}[0] | ${DUT1_${int}2}[0]
 830
 831 | Initialize L2 bridge domain with IPv4 ACLs on DUT1 in 3-node circular topology
 832 | | [Documentation]
 833 | | ... | Setup L2BD topology by adding two interfaces on DUT1 into bridge
 834 | | ... | domain that is created automatically with index 1. Learning is
 835 | | ... | enabled. Interfaces are brought up. Apply required ACL rules to DUT1
 836 | | ... | interfaces.
 837 | |
 838 | | Set interfaces in path up
 839 | | VPP Add L2 Bridge Domain
 840 | | ... | ${dut1} | ${1} | ${DUT1_${int}1}[0] | ${DUT1_${int}2}[0]
 841 | | Configure L2XC
 842 | | ... | ${dut2} | ${DUT2_${int}1}[0] | ${DUT2_${int}2}[0]
 843 | | Configure IPv4 ACLs
 844 | | ... | ${dut1} | ${DUT1_${int}1}[0] | ${DUT1_${int}2}[0]