resources/libraries/robot/overlay/srv6.robot

   1 # Copyright (c) 2020 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Library | resources.libraries.python.SRv6
  16 | Documentation | Keywords for SRv6 feature in VPP.
  17
  18 *** Keywords ***
  19 | Configure SR LocalSID on DUT
  20 | | [Documentation] | Create SRv6 LocalSID and binds it to a particular\
  21 | | ... | behavior on the given DUT node.
  22 | |
  23 | | ... | *Arguments:*
  24 | | ... | - dut_node - DUT node where to create localSID on. Type: dictionary
  25 | | ... | - local_sid - LocalSID IPv6 address. Type: string
  26 | | ... | - behavior - SRv6 LocalSID function. Type: string
  27 | | ... | - interface - Interface name (Optional, default value: None; required
  28 | | ... | for L2/L3 xconnects). Type: string
  29 | | ... | - next_hop - Next hop IPv4/IPv6 address (Optional, default value:
  30 | | ... | None; required for L3 xconnects). Type: string
  31 | | ... | - fib_table - FIB table for IPv4/IPv6 lookup (Optional, default value:
  32 | | ... | None; required for L3 routing). Type: string
  33 | | ... | - out_if - Interface name of local interface for sending traffic
  34 | | ... | towards the Service Function (Optional, default value: None;
  35 | | ... | required for SRv6 endpoint to SR-unaware appliance). Type: string
  36 | | ... | - in_if - Interface name of local interface receiving the traffic
  37 | | ... | coming back from the Service Function (Optional, default value:
  38 | | ... | None; required for SRv6 endpoint to SR-unaware appliance).
  39 | | ... | Type: string
  40 | | ... | - src_addr - Source address on the packets coming back on in_if
  41 | | ... | interface (Optional, default value: None; required for SRv6 endpoint
  42 | | ... | to SR-unaware appliance via static proxy). Type: string
  43 | | ... | - sid_list - SID list (Optional, default value: []; required for SRv6
  44 | | ... | endpoint to SR-unaware appliance via static proxy). Type: list
  45 | |
  46 | | ... | *Example:*
  47 | |
  48 | | ... | \| Configure SR LocalSID on DUT \| ${nodes['DUT1']} \| B:: \| end \|
  49 | | ... | \| Configure SR LocalSID on DUT \| ${nodes['DUT1']} \| C:: \
  50 | | ... | \| end.dx2 \| interface=GigabitEthernet0/10/0 \|
  51 | | ... | \| Configure SR LocalSID on DUT \| ${nodes['DUT1']} \| D:: \
  52 | | ... | \| end.dx4 \| interface=GigabitEthernet0/8/0 \| next_hop=10.0.0.1 \|
  53 | | ... | \| Configure SR LocalSID on DUT \| ${nodes['DUT2']} \| E:: \
  54 | | ... | \| end.dt6 \| fib_table=2 \|
  55 | | ... | \| Configure SR LocalSID on DUT \| ${nodes['DUT2']} \| E:: \
  56 | | ... | \| end.ad \| next_hop=10.0.0.1 \| out_if=DUT2_VHOST1 \
  57 | | ... | \| in_if=DUT2_VHOST2 \|
  58 | | ... | \| Configure SR LocalSID on DUT \| ${nodes['DUT2']} \| E:: \
  59 | | ... | \| end.as \| next_hop=10.0.0.1 \| out_if=DUT2_VHOST1 \
  60 | | ... | \| in_if=DUT2_VHOST2 \| src_addr=B:: \| sid_list=['C::', 'D::'] \|
  61 | |
  62 | | [Arguments] | ${dut_node} | ${local_sid} | ${behavior}
  63 | | ... | ${interface}=${None} | ${next_hop}=${None} | ${fib_table}=${None}
  64 | | ... | ${out_if}=${None} | ${in_if}=${None} | ${src_addr}=${None}
  65 | | ... | @{sid_list}
  66 | |
  67 | | Configure SR LocalSID | ${dut_node} | ${local_sid} | ${behavior}
  68 | | ... | interface=${interface} | next_hop=${next_hop} | fib_table=${fib_table}
  69 | | ... | out_if=${out_if} | in_if=${in_if} | src_addr=${src_addr}
  70 | | ... | sid_list=${sid_list}
  71
  72 | Show SR LocalSIDs on DUT
  73 | | [Documentation] | Show SRv6 LocalSIDs on the given DUT node.
  74 | |
  75 | | ... | *Arguments:*
  76 | | ... | - dut_node - DUT node where to show SR localSIDs on. Type: dictionary
  77 | |
  78 | | ... | *Example:*
  79 | |
  80 | | ... | \| Show SR LocalSIDs on DUT \| ${nodes['DUT1']} \|
  81 | |
  82 | | [Arguments] | ${dut_node}
  83 | |
  84 | | Show SR LocalSIDs | ${dut_node}
  85
  86 | Configure SR Policy on DUT
  87 | | [Documentation] | Create SRv6 policy on the given DUT node.
  88 | |
  89 | | ... | *Arguments:*
  90 | | ... | - dut_node - DUT node where to create SRv6 policy on. Type: dictionary
  91 | | ... | - bsid - BindingSID - local SID IPv6 address. Type: string
  92 | | ... | - mode - Encapsulation / insertion mode. Type: string
  93 | | ... | - sid_list - SID list. Type: list
  94 | |
  95 | | ... | *Example:*
  96 | |
  97 | | ... | \| Configure SR Policy on DUT \| ${nodes['DUT2']} \| A:: \| encap \
  98 | | ... | \| B::\| C:: \|
  99 | | ... | \| Configure SR Policy on DUT \| ${nodes['DUT2']} \| D:: \| insert \
 100 | | ... | \| E::\| F:: \|
 101 | |
 102 | | [Arguments] | ${dut_node} | ${bsid} | ${mode} | @{sid_list}
 103 | |
 104 | | Configure SR Policy | ${dut_node} | ${bsid} | ${sid_list} | mode=${mode}
 105
 106 | Show SR Policies on DUT
 107 | | [Documentation] | Show SRv6 policies on the given DUT node.
 108 | |
 109 | | ... | *Arguments:*
 110 | | ... | - dut_node - DUT node where to show SR policies on. Type: dictionary
 111 | |
 112 | | ... | *Example:*
 113 | |
 114 | | ... | \| Show SR Policies on DUT \| ${nodes['DUT1']} \|
 115 | |
 116 | | [Arguments] | ${dut_node}
 117 | |
 118 | | Show SR Policies | ${dut_node}
 119
 120 | Configure SR Steer on DUT
 121 | | [Documentation] | Create SRv6 steering policy on the given DUT node.
 122 | |
 123 | | ... | *Arguments:*
 124 | | ... | - dut_node - DUT node where to create SR steering policy on.
 125 | | ... | Type: dictionary
 126 | | ... | - mode - Mode of operation - L2 or L3. Type: string
 127 | | ... | - bsid - BindingSID - local SID IPv6 address. Type: string
 128 | | ... | - interface - Interface name (Optional, default value: None; required
 129 | | ... | in case of L2 mode). Type: string
 130 | | ... | - ip_addr - IPv4/IPv6 address (Optional, default value: None; required
 131 | | ... | in case of L3 mode). Type: string
 132 | | ... | - prefix - IP address prefix (Optional, default value: None; required
 133 | | ... | for L3 mode). Type: integer
 134 | |
 135 | | ... | *Example:*
 136 | |
 137 | | ... | \| Configure SR Steer on DUT \| ${nodes['DUT1']} \| L2 \| B:: \
 138 | | ... | \| interface=GigabitEthernet0/10/0 \|
 139 | | ... | \| Configure SR Steer on DUT \| ${nodes['DUT1']} \| L3 \| C:: \
 140 | | ... | \| ip_address=2001::1 \| prefix=64 \|
 141 | |
 142 | | [Arguments] | ${dut_node} | ${mode} | ${bsid}
 143 | | ... | ${interface}=${None} | ${ip_addr}=${None} | ${prefix}=${None}
 144 | |
 145 | | Configure SR Steer | ${dut_node} | ${mode} | ${bsid}
 146 | | ... | interface=${interface} | ip_addr=${ip_addr} | prefix=${prefix}
 147
 148 | Show SR Steering Policies on DUT
 149 | | [Documentation] | Show SRv6 steering policies on the given DUT node.
 150 | |
 151 | | ... | *Arguments:*
 152 | | ... | - dut_node - DUT node where to show SR steering policies on.
 153 | | ... | Type: dictionary
 154 | |
 155 | | ... | *Example:*
 156 | |
 157 | | ... | \| Show SR Steering Policies on DUT \| ${nodes['DUT1']} \|
 158 | |
 159 | | [Arguments] | ${dut_node}
 160 | |
 161 | | Show SR Steering Policies | ${dut_node}
 162
 163 | Set SR Encaps Source Address on DUT
 164 | | [Documentation] | Set SRv6 encapsulation source address on the given DUT
 165 | | ... | node.
 166 | |
 167 | | ... | *Arguments:*
 168 | | ... | - dut_node - DUT node where to set SRv6 encapsulation source address
 169 | | ... | on. Type: dictionary
 170 | | ... | - ip6_addr - Local SID IPv6 address. Type: string
 171 | |
 172 | | ... | *Example:*
 173 | |
 174 | | ... | \| Set SR Encaps Source Address on DUT \| ${nodes['DUT1']} \| B:: \|
 175 | |
 176 | | [Arguments] | ${dut_node} | ${ip6_addr}
 177 | |
 178 | | Set SR Encaps Source Address | ${dut_node} | ip6_addr=${ip6_addr}
 179
 180 | Show SR Policies on all DUTs
 181 | | [Documentation] | Show SRv6 policies on all DUT nodes in topology.
 182 | |
 183 | | ... | *Arguments:*
 184 | | ... | - nodes - Topology. Type: dictionary
 185 | |
 186 | | ... | *Example:*
 187 | |
 188 | | ... | \| Show SR Policies on all DUTs \| ${nodes} \|
 189 | |
 190 | | [Arguments] | ${nodes}
 191 | |
 192 | | FOR | ${dut} | IN | @{duts}
 193 | | | Show SR Policies | ${nodes['${dut}']}
 194 | | END
 195
 196 | Show SR Steering Policies on all DUTs
 197 | | [Documentation] | Show SRv6 steering policies on all DUT nodes in topology.
 198 | |
 199 | | ... | *Arguments:*
 200 | | ... | - nodes - Topology. Type: dictionary
 201 | |
 202 | | ... | *Example:*
 203 | |
 204 | | ... | \| Show SR Steering Policies on all DUTs \| ${nodes} \|
 205 | |
 206 | | [Arguments] | ${nodes}
 207 | |
 208 | | FOR | ${dut} | IN | @{duts}
 209 | | | Show SR Steering Policies | ${nodes['${dut}']}
 210 | | END
 211
 212 | Show SR LocalSIDs on all DUTs
 213 | | [Documentation] | Show SRv6 LocalSIDs on all DUT nodes in topology.
 214 | |
 215 | | ... | *Arguments:*
 216 | | ... | - nodes - Topology. Type: dictionary
 217 | |
 218 | | ... | *Example:*
 219 | |
 220 | | ... | \| Show SR LocalSIDs on all DUTs \| ${nodes} \|
 221 | |
 222 | | [Arguments] | ${nodes}
 223 | |
 224 | | FOR | ${dut} | IN | @{duts}
 225 | | | Show SR LocalSIDs | ${nodes['${dut}']}
 226 | | END
 227
 228 | Initialize IPv6 forwarding over SRv6 with encapsulation with '${n}' x SID '${prepos}' decapsulation in 3-node circular topology
 229 | | [Documentation]
 230 | | ... | Set UP state on VPP interfaces in path on nodes in 3-node circular
 231 | | ... | topology. Get the interface MAC addresses and setup neighbours on all
 232 | | ... | VPP interfaces. Setup IPv6 addresses on all interfaces. Set segment
 233 | | ... | routing for IPv6 for required number of SIDs and configure IPv6 routes
 234 | | ... | on both DUT nodes.
 235 | |
 236 | | VPP Interface Set IP Address
 237 | | ... | ${dut1} | ${DUT1_${int}1}[0] | ${dut1_if1_ip6} | ${prefix}
 238 | | VPP Interface Set IP Address
 239 | | ... | ${dut1} | ${DUT1_${int}2}[0] | ${dut1_if2_ip6} | ${prefix}
 240 | | VPP Interface Set IP Address
 241 | | ... | ${dut2} | ${DUT2_${int}1}[0] | ${dut2_if1_ip6} | ${prefix}
 242 | | VPP Interface Set IP Address
 243 | | ... | ${dut2} | ${DUT2_${int}2}[0] | ${dut2_if2_ip6} | ${prefix}
 244 | | Vpp All Ra Suppress Link Layer | ${nodes}
 245 | | FOR | ${number} | IN RANGE | 2 | ${dst_addr_nr}+2
 246 | | | ${hexa_nr}= | Convert To Hex | ${number}
 247 | | | VPP Add IP Neighbor | ${dut1}
 248 | | | ... | ${DUT1_${int}1}[0] | ${tg_if1_ip6_subnet}${hexa_nr}
 249 | | | ... | ${TG_pf1_mac}[0]
 250 | | | VPP Add IP Neighbor | ${dut2}
 251 | | | ... | ${DUT2_${int}2}[0] | ${tg_if2_ip6_subnet}${hexa_nr}
 252 | | | ... | ${TG_pf2_mac}[0]
 253 | | END
 254 | | VPP Add IP Neighbor
 255 | | ... | ${dut1} | ${DUT1_${int}2}[0] | ${dut2_if1_ip6}
 256 | | ... | ${DUT2_${int}1_mac}[0]
 257 | | VPP Add IP Neighbor
 258 | | ... | ${dut2} | ${DUT2_${int}1}[0] | ${dut1_if2_ip6}
 259 | | ... | ${DUT1_${int}2_mac}[0]
 260 | | ${sid1}= | Set Variable If
 261 | | ... | "${n}" == "1" | ${dut2_sid1}
 262 | | ... | "${n}" == "2" | ${dut2_sid1_1}
 263 | | ${sid2}= | Set Variable If
 264 | | ... | "${n}" == "1" | ${dut1_sid2}
 265 | | ... | "${n}" == "2" | ${dut1_sid2_1}
 266 | | Vpp Route Add | ${dut1} | ${sid1} | ${sid_prefix} | gateway=${dut2_if1_ip6}
 267 | | ... | interface=${DUT1_${int}2}[0]
 268 | | Vpp Route Add | ${dut2} | ${sid2} | ${sid_prefix} | gateway=${dut1_if2_ip6}
 269 | | ... | interface=${DUT2_${int}1}[0]
 270 # Configure SRv6 for direction0
 271 | | Set SR Encaps Source Address on DUT | ${dut1} | ${dut1_sid1}
 272 | | @{sid_list_dir0}= | Run Keyword If | "${n}" == "1"
 273 | | ... | Create List | ${dut2_sid1}
 274 | | ... | ELSE IF | "${n}" == "2"
 275 | | ... | Create List | ${dut2_sid1_1} | ${dut2_sid1_2}
 276 | | Configure SR Policy on DUT | ${dut1} | ${dut1_bsid} | encap
 277 | | ... | @{sid_list_dir0}
 278 | | Configure SR Steer on DUT | ${dut1} | L3 | ${dut1_bsid}
 279 | | ... | ip_addr=${tg_if2_ip6_subnet} | prefix=${sid_prefix}
 280 | | Run Keyword If | "${n}" == "1"
 281 | | ... | Configure SR LocalSID on DUT | ${dut2} | ${dut2_sid1} | end.dx6
 282 | | ... | interface=${DUT2_${int}2}[0] | next_hop=${tg_if2_ip6_subnet}2
 283 | | Run Keyword If | "${n}" == "2"
 284 | | ... | Configure SR LocalSID on DUT | ${dut2} | ${dut2_sid1_1} | end
 285 | | Run Keyword If | "${n}" == "2" and "${prepos}" != "without"
 286 | | ... | Configure SR LocalSID on DUT | ${dut2} | ${dut2_sid1_2} | end.dx6
 287 | | ... | interface=${DUT2_${int}2}[0] | next_hop=${tg_if2_ip6_subnet}2
 288 | | Run Keyword If | "${n}" == "2" and "${prepos}" == "without"
 289 | | ... | Vpp Route Add | ${dut2} | ${dut2_sid1_2} | ${sid_prefix}
 290 | | ... | gateway=${tg_if2_ip6_subnet}2 | interface=${DUT2_${int}2}[0]
 291 # Configure SRv6 for direction1
 292 | | Set SR Encaps Source Address on DUT | ${dut2} | ${dut2_sid2}
 293 | | @{sid_list_dir1}= | Run Keyword If | "${n}" == "1"
 294 | | ... | Create List | ${dut1_sid2}
 295 | | ... | ELSE IF | "${n}" == "2"
 296 | | ... | Create List | ${dut1_sid2_1} | ${dut1_sid2_2}
 297 | | Configure SR Policy on DUT | ${dut2} | ${dut2_bsid} | encap
 298 | | ... | @{sid_list_dir1}
 299 | | Configure SR Steer on DUT | ${dut2} | L3 | ${dut2_bsid}
 300 | | ... | ip_addr=${tg_if1_ip6_subnet} | prefix=${sid_prefix}
 301 | | Run Keyword If | "${n}" == "1"
 302 | | ... | Configure SR LocalSID on DUT | ${dut1} | ${dut1_sid2} | end.dx6
 303 | | ... | interface=${DUT1_${int}1}[0] | next_hop=${tg_if1_ip6_subnet}2
 304 | | Run Keyword If | "${n}" == "2"
 305 | | ... | Configure SR LocalSID on DUT | ${dut1} | ${dut1_sid2_1} | end
 306 | | Run Keyword If | "${n}" == "2" and "${prepos}" != "without"
 307 | | ... | Configure SR LocalSID on DUT | ${dut1} | ${dut1_sid2_2} | end.dx6
 308 | | ... | interface=${DUT1_${int}1}[0] | next_hop=${tg_if1_ip6_subnet}2
 309 | | Run Keyword If | "${n}" == "2" and "${prepos}" == "without"
 310 | | ... | Vpp Route Add | ${dut1} | ${dut1_sid2_2} | ${sid_prefix}
 311 | | ... | gateway=${tg_if1_ip6_subnet}2 | interface=${DUT1_${int}1}[0]
 312 | | Set interfaces in path up
 313
 314 | Initialize IPv6 forwarding over SRv6 with endpoint to SR-unaware Service Function via '${behavior}' behaviour in 3-node circular topology
 315 | | [Documentation]
 316 | | ... | Create pair of Memif interfaces on all defined VPP nodes. Set UP
 317 | | ... | state on VPP interfaces in path on nodes in 3-node circular topology.
 318 | | ... | Get the interface MAC addresses and setup neighbours on all VPP
 319 | | ... | interfaces. Setup IPv6 addresses on all interfaces. Set segment
 320 | | ... | routing for IPv6 with defined behaviour function and configure IPv6
 321 | | ... | routes on both DUT nodes.
 322 | |
 323 | | ... | *Note:*
 324 | | ... | KW uses test variable rxq_count_int set by KW Add worker threads
 325 | | ... | and rxqueues to all DUTs
 326 | |
 327 | | ${sock1}= | Set Variable | memif-DUT1_CNF
 328 | | ${sock2}= | Set Variable | memif-DUT2_CNF
 329 | | Set up memif interfaces on DUT node | ${dut1} | ${sock1} | ${sock1}
 330 | | ... | ${1} | dut1-memif-1-if1 | dut1-memif-1-if2 | ${rxq_count_int}
 331 | | ... | ${rxq_count_int}
 332 | | VPP Set interface MTU | ${dut1} | ${dut1-memif-1-if1}
 333 | | VPP Set interface MTU | ${dut1} | ${dut1-memif-1-if2}
 334 | | Set up memif interfaces on DUT node | ${dut2} | ${sock2} | ${sock2}
 335 | | ... | ${1} | dut2-memif-1-if1 | dut2-memif-1-if2 | ${rxq_count_int}
 336 | | ... | ${rxq_count_int}
 337 | | VPP Set interface MTU | ${dut2} | ${dut2-memif-1-if1}
 338 | | VPP Set interface MTU | ${dut2} | ${dut2-memif-1-if2}
 339 | | FOR | ${dut} | IN | @{duts}
 340 | | | Show Memif | ${nodes['${dut}']}
 341 | | END
 342 | | VPP Interface Set IP Address
 343 | | ... | ${dut1} | ${DUT1_${int}1}[0] | ${dut1_if1_ip6} | ${prefix}
 344 | | VPP Interface Set IP Address
 345 | | ... | ${dut1} | ${DUT1_${int}2}[0] | ${dut1_if2_ip6} | ${prefix}
 346 | | VPP Interface Set IP Address | ${dut1} | ${dut1-memif-1-if1}
 347 | | ... | ${dut1-memif-1-if1_ip6} | ${mem_prefix}
 348 | | VPP Interface Set IP Address | ${dut1} | ${dut1-memif-1-if2}
 349 | | ... | ${dut1-memif-1-if2_ip6} | ${mem_prefix}
 350 | | VPP Interface Set IP Address
 351 | | ... | ${dut2} | ${DUT2_${int}1}[0] | ${dut2_if1_ip6} | ${prefix}
 352 | | VPP Interface Set IP Address
 353 | | ... | ${dut2} | ${DUT2_${int}2}[0] | ${dut2_if2_ip6} | ${prefix}
 354 | | VPP Interface Set IP Address | ${dut2} | ${dut2-memif-1-if1}
 355 | | ... | ${dut2-memif-1-if1_ip6} | ${mem_prefix}
 356 | | VPP Interface Set IP Address | ${dut2} | ${dut2-memif-1-if2}
 357 | | ... | ${dut2-memif-1-if2_ip6} | ${mem_prefix}
 358 | | Vpp All Ra Suppress Link Layer | ${nodes}
 359 | | VPP Add IP Neighbor
 360 | | ... | ${dut1} | ${DUT1_${int}2}[0] | ${dut2_if1_ip6}
 361 | | ... | ${DUT2_${int}1_mac}[0]
 362 | | VPP Add IP Neighbor
 363 | | ... | ${dut2} | ${DUT2_${int}1}[0] | ${dut1_if2_ip6}
 364 | | ... | ${DUT1_${int}2_mac}[0]
 365 | | VPP Add IP Neighbor
 366 | | ... | ${dut1} | ${DUT1_${int}1}[0] | ${tg_if1_ip6_subnet}2
 367 | | ... | ${TG_pf1_mac}[0]
 368 | | VPP Add IP Neighbor
 369 | | ... | ${dut2} | ${DUT2_${int}2}[0] | ${tg_if2_ip6_subnet}2
 370 | | ... | ${TG_pf2_mac}[0]
 371 | | ${dut1-memif-1-if2_mac}= | Get Interface MAC | ${dut1} | memif2
 372 | | ${dut2-memif-1-if2_mac}= | Get Interface MAC | ${dut2} | memif2
 373 | | VPP Add IP Neighbor | ${dut1}
 374 | | ... | ${dut1-memif-1-if1} | ${dut1_nh} | ${dut1-memif-1-if2_mac}
 375 | | VPP Add IP Neighbor | ${dut2}
 376 | | ... | ${dut2-memif-1-if1} | ${dut2_nh} | ${dut2-memif-1-if2_mac}
 377 | | Vpp Route Add | ${dut1} | ${dut2_sid1} | ${sid_prefix}
 378 | | ... | gateway=${dut2_if1_ip6} | interface=${dut1_if2}
 379 | | Vpp Route Add | ${dut1} | ${out_sid2_1} | ${sid_prefix}
 380 | | ... | gateway=${tg_if1_ip6_subnet}2 | interface=${dut1_if1}
 381 | | Vpp Route Add | ${dut2} | ${dut1_sid2} | ${sid_prefix}
 382 | | ... | gateway=${dut1_if2_ip6} | interface=${dut2_if1}
 383 | | Vpp Route Add | ${dut2} | ${out_sid1_1} | ${sid_prefix}
 384 | | ... | gateway=${tg_if2_ip6_subnet}2 | interface=${dut2_if2}
 385 # Configure SRv6 for direction0 on DUT1
 386 | | Set SR Encaps Source Address on DUT | ${dut1} | ${dut1_sid1}
 387 | | @{sid_list_dir0}= | Create List | ${dut2_sid1} | ${out_sid1_1}
 388 | | ... | ${out_sid1_2}
 389 | | Configure SR Policy on DUT | ${dut1} | ${dut1_bsid} | encap
 390 | | ... | @{sid_list_dir0}
 391 | | Configure SR Steer on DUT | ${dut1} | L3 | ${dut1_bsid}
 392 | | ... | ip_addr=${tg_if2_ip6_subnet} | prefix=${sid_prefix}
 393 # Configure SRv6 for direction1 on DUT2
 394 | | Set SR Encaps Source Address on DUT | ${dut2} | ${dut2_sid2}
 395 | | @{sid_list_dir1}= | Create List | ${dut1_sid2} | ${out_sid2_1}
 396 | | ... | ${out_sid2_2}
 397 | | Configure SR Policy on DUT | ${dut2} | ${dut2_bsid} | encap
 398 | | ... | @{sid_list_dir1}
 399 | | Configure SR Steer on DUT | ${dut2} | L3 | ${dut2_bsid}
 400 | | ... | ip_addr=${tg_if1_ip6_subnet} | prefix=${sid_prefix}
 401 # Configure SRv6 for direction0 on DUT2
 402 | | ${dut2_out_if}= | Get Interface Name | ${dut2} | memif1
 403 | | ${dut2_in_if}= | Get Interface Name | ${dut2} | memif2
 404 | | Remove Values From List | ${sid_list_dir0} | ${dut2_sid1}
 405 | | Run Keyword If | "${behavior}" == "static_proxy"
 406 | | ... | Configure SR LocalSID on DUT | ${dut2} | ${dut2_sid1} | end.as
 407 | | ... | ${NONE} | ${dut2_nh} | ${NONE} | ${dut2_out_if} | ${dut2_in_if}
 408 | | ... | ${dut1_sid1} | @{sid_list_dir0}
 409 | | ... | ELSE IF | "${behavior}" == "dynamic_proxy"
 410 | | ... | Configure SR LocalSID on DUT | ${dut2} | ${dut2_sid1} | end.ad
 411 | | ... | next_hop=${dut2_nh} | out_if=${dut2_out_if} | in_if=${dut2_in_if}
 412 | | ... | ELSE IF | "${behavior}" == "masquerading"
 413 | | ... | Configure SR LocalSID on DUT | ${dut2} | ${dut2_sid1} | end.am
 414 | | ... | next_hop=${dut2_nh} | out_if=${dut2_out_if} | in_if=${dut2_in_if}
 415 | | ... | ELSE | Fail | Unsupported behaviour: ${behavior}
 416 # Configure SRv6 for direction1 on DUT1
 417 | | ${dut1_out_if}= | Get Interface Name | ${dut1} | memif1
 418 | | ${dut1_in_if}= | Get Interface Name | ${dut1} | memif2
 419 | | Remove Values From List | ${sid_list_dir1} | ${dut1_sid2}
 420 | | Run Keyword If | "${behavior}" == "static_proxy"
 421 | | ... | Configure SR LocalSID on DUT | ${dut1} | ${dut1_sid2} | end.as
 422 | | ... | ${NONE} | ${dut1_nh} | ${NONE} | ${dut1_out_if} | ${dut1_in_if}
 423 | | ... | ${dut2_sid2} | @{sid_list_dir1}
 424 | | ... | ELSE IF | "${behavior}" == "dynamic_proxy"
 425 | | ... | Configure SR LocalSID on DUT | ${dut1} | ${dut1_sid2} | end.ad
 426 | | ... | next_hop=${dut1_nh} | out_if=${dut1_out_if} | in_if=${dut1_in_if}
 427 | | ... | ELSE IF | "${behavior}" == "masquerading"
 428 | | ... | Configure SR LocalSID on DUT | ${dut1} | ${dut1_sid2} | end.am
 429 | | ... | next_hop=${dut1_nh} | out_if=${dut1_out_if} | in_if=${dut1_in_if}
 430 | | ... | ELSE | Fail | Unsupported behaviour: ${behavior}
 431 | | Set interfaces in path up