resources/libraries/robot/overlay/srv6.robot

   1 # Copyright (c) 2020 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Library | resources.libraries.python.SRv6
  16 | Documentation | Keywords for SRv6 feature in VPP.
  17
  18 *** Keywords ***
  19 | Configure SR LocalSID on DUT
  20 | | [Documentation] | Create SRv6 LocalSID and binds it to a particular\
  21 | | ... | behavior on the given DUT node.
  22 | |
  23 | | ... | *Arguments:*
  24 | | ... | - dut_node - DUT node where to create localSID on. Type: dictionary
  25 | | ... | - local_sid - LocalSID IPv6 address. Type: string
  26 | | ... | - behavior - SRv6 LocalSID function. Type: string
  27 | | ... | - interface - Interface name (Optional, default value: None; required
  28 | | ... | for L2/L3 xconnects). Type: string
  29 | | ... | - next_hop - Next hop IPv4/IPv6 address (Optional, default value:
  30 | | ... | None; required for L3 xconnects). Type: string
  31 | | ... | - fib_table - FIB table for IPv4/IPv6 lookup (Optional, default value:
  32 | | ... | None; required for L3 routing). Type: string
  33 | | ... | - out_if - Interface name of local interface for sending traffic
  34 | | ... | towards the Service Function (Optional, default value: None;
  35 | | ... | required for SRv6 endpoint to SR-unaware appliance). Type: string
  36 | | ... | - in_if - Interface name of local interface receiving the traffic
  37 | | ... | coming back from the Service Function (Optional, default value:
  38 | | ... | None; required for SRv6 endpoint to SR-unaware appliance).
  39 | | ... | Type: string
  40 | | ... | - src_addr - Source address on the packets coming back on in_if
  41 | | ... | interface (Optional, default value: None; required for SRv6 endpoint
  42 | | ... | to SR-unaware appliance via static proxy). Type: string
  43 | | ... | - sid_list - SID list (Optional, default value: []; required for SRv6
  44 | | ... | endpoint to SR-unaware appliance via static proxy). Type: list
  45 | |
  46 | | ... | *Example:*
  47 | |
  48 | | ... | \| Configure SR LocalSID on DUT \| ${nodes['DUT1']} \| B:: \| end \|
  49 | | ... | \| Configure SR LocalSID on DUT \| ${nodes['DUT1']} \| C:: \
  50 | | ... | \| end.dx2 \| interface=GigabitEthernet0/10/0 \|
  51 | | ... | \| Configure SR LocalSID on DUT \| ${nodes['DUT1']} \| D:: \
  52 | | ... | \| end.dx4 \| interface=GigabitEthernet0/8/0 \| next_hop=10.0.0.1 \|
  53 | | ... | \| Configure SR LocalSID on DUT \| ${nodes['DUT2']} \| E:: \
  54 | | ... | \| end.dt6 \| fib_table=2 \|
  55 | | ... | \| Configure SR LocalSID on DUT \| ${nodes['DUT2']} \| E:: \
  56 | | ... | \| end.ad \| next_hop=10.0.0.1 \| out_if=DUT2_VHOST1 \
  57 | | ... | \| in_if=DUT2_VHOST2 \|
  58 | | ... | \| Configure SR LocalSID on DUT \| ${nodes['DUT2']} \| E:: \
  59 | | ... | \| end.as \| next_hop=10.0.0.1 \| out_if=DUT2_VHOST1 \
  60 | | ... | \| in_if=DUT2_VHOST2 \| src_addr=B:: \| sid_list=['C::', 'D::'] \|
  61 | |
  62 | | [Arguments] | ${dut_node} | ${local_sid} | ${behavior}
  63 | | ... | ${interface}=${None} | ${next_hop}=${None} | ${fib_table}=${None}
  64 | | ... | ${out_if}=${None} | ${in_if}=${None} | ${src_addr}=${None}
  65 | | ... | @{sid_list}
  66 | |
  67 | | Configure SR LocalSID | ${dut_node} | ${local_sid} | ${behavior}
  68 | | ... | interface=${interface} | next_hop=${next_hop} | fib_table=${fib_table}
  69 | | ... | out_if=${out_if} | in_if=${in_if} | src_addr=${src_addr}
  70 | | ... | sid_list=${sid_list}
  71
  72 | Show SR LocalSIDs on DUT
  73 | | [Documentation] | Show SRv6 LocalSIDs on the given DUT node.
  74 | |
  75 | | ... | *Arguments:*
  76 | | ... | - dut_node - DUT node where to show SR localSIDs on. Type: dictionary
  77 | |
  78 | | ... | *Example:*
  79 | |
  80 | | ... | \| Show SR LocalSIDs on DUT \| ${nodes['DUT1']} \|
  81 | |
  82 | | [Arguments] | ${dut_node}
  83 | |
  84 | | Show SR LocalSIDs | ${dut_node}
  85
  86 | Configure SR Policy on DUT
  87 | | [Documentation] | Create SRv6 policy on the given DUT node.
  88 | |
  89 | | ... | *Arguments:*
  90 | | ... | - dut_node - DUT node where to create SRv6 policy on. Type: dictionary
  91 | | ... | - bsid - BindingSID - local SID IPv6 address. Type: string
  92 | | ... | - mode - Encapsulation / insertion mode. Type: string
  93 | | ... | - sid_list - SID list. Type: list
  94 | |
  95 | | ... | *Example:*
  96 | |
  97 | | ... | \| Configure SR Policy on DUT \| ${nodes['DUT2']} \| A:: \| encap \
  98 | | ... | \| B::\| C:: \|
  99 | | ... | \| Configure SR Policy on DUT \| ${nodes['DUT2']} \| D:: \| insert \
 100 | | ... | \| E::\| F:: \|
 101 | |
 102 | | [Arguments] | ${dut_node} | ${bsid} | ${mode} | @{sid_list}
 103 | |
 104 | | Configure SR Policy | ${dut_node} | ${bsid} | ${sid_list} | mode=${mode}
 105
 106 | Show SR Policies on DUT
 107 | | [Documentation] | Show SRv6 policies on the given DUT node.
 108 | |
 109 | | ... | *Arguments:*
 110 | | ... | - dut_node - DUT node where to show SR policies on. Type: dictionary
 111 | |
 112 | | ... | *Example:*
 113 | |
 114 | | ... | \| Show SR Policies on DUT \| ${nodes['DUT1']} \|
 115 | |
 116 | | [Arguments] | ${dut_node}
 117 | |
 118 | | Show SR Policies | ${dut_node}
 119
 120 | Configure SR Steer on DUT
 121 | | [Documentation] | Create SRv6 steering policy on the given DUT node.
 122 | |
 123 | | ... | *Arguments:*
 124 | | ... | - dut_node - DUT node where to create SR steering policy on.
 125 | | ... | Type: dictionary
 126 | | ... | - mode - Mode of operation - L2 or L3. Type: string
 127 | | ... | - bsid - BindingSID - local SID IPv6 address. Type: string
 128 | | ... | - interface - Interface name (Optional, default value: None; required
 129 | | ... | in case of L2 mode). Type: string
 130 | | ... | - ip_addr - IPv4/IPv6 address (Optional, default value: None; required
 131 | | ... | in case of L3 mode). Type: string
 132 | | ... | - prefix - IP address prefix (Optional, default value: None; required
 133 | | ... | for L3 mode). Type: integer
 134 | |
 135 | | ... | *Example:*
 136 | |
 137 | | ... | \| Configure SR Steer on DUT \| ${nodes['DUT1']} \| L2 \| B:: \
 138 | | ... | \| interface=GigabitEthernet0/10/0 \|
 139 | | ... | \| Configure SR Steer on DUT \| ${nodes['DUT1']} \| L3 \| C:: \
 140 | | ... | \| ip_address=2001::1 \| prefix=64 \|
 141 | |
 142 | | [Arguments] | ${dut_node} | ${mode} | ${bsid}
 143 | | ... | ${interface}=${None} | ${ip_addr}=${None} | ${prefix}=${None}
 144 | |
 145 | | Configure SR Steer | ${dut_node} | ${mode} | ${bsid}
 146 | | ... | interface=${interface} | ip_addr=${ip_addr} | prefix=${prefix}
 147
 148 | Show SR Steering Policies on DUT
 149 | | [Documentation] | Show SRv6 steering policies on the given DUT node.
 150 | |
 151 | | ... | *Arguments:*
 152 | | ... | - dut_node - DUT node where to show SR steering policies on.
 153 | | ... | Type: dictionary
 154 | |
 155 | | ... | *Example:*
 156 | |
 157 | | ... | \| Show SR Steering Policies on DUT \| ${nodes['DUT1']} \|
 158 | |
 159 | | [Arguments] | ${dut_node}
 160 | |
 161 | | Show SR Steering Policies | ${dut_node}
 162
 163 | Set SR Encaps Source Address on DUT
 164 | | [Documentation] | Set SRv6 encapsulation source address on the given DUT
 165 | | ... | node.
 166 | |
 167 | | ... | *Arguments:*
 168 | | ... | - dut_node - DUT node where to set SRv6 encapsulation source address
 169 | | ... | on. Type: dictionary
 170 | | ... | - ip6_addr - Local SID IPv6 address. Type: string
 171 | |
 172 | | ... | *Example:*
 173 | |
 174 | | ... | \| Set SR Encaps Source Address on DUT \| ${nodes['DUT1']} \| B:: \|
 175 | |
 176 | | [Arguments] | ${dut_node} | ${ip6_addr}
 177 | |
 178 | | Set SR Encaps Source Address | ${dut_node} | ip6_addr=${ip6_addr}
 179
 180 | Show SR Policies on all DUTs
 181 | | [Documentation] | Show SRv6 policies on all DUT nodes in topology.
 182 | |
 183 | | ... | *Arguments:*
 184 | | ... | - nodes - Topology. Type: dictionary
 185 | |
 186 | | ... | *Example:*
 187 | |
 188 | | ... | \| Show SR Policies on all DUTs \| ${nodes} \|
 189 | |
 190 | | [Arguments] | ${nodes}
 191 | |
 192 | | FOR | ${dut} | IN | @{duts}
 193 | | | Show SR Policies | ${nodes['${dut}']}
 194 | | END
 195
 196 | Show SR Steering Policies on all DUTs
 197 | | [Documentation] | Show SRv6 steering policies on all DUT nodes in topology.
 198 | |
 199 | | ... | *Arguments:*
 200 | | ... | - nodes - Topology. Type: dictionary
 201 | |
 202 | | ... | *Example:*
 203 | |
 204 | | ... | \| Show SR Steering Policies on all DUTs \| ${nodes} \|
 205 | |
 206 | | [Arguments] | ${nodes}
 207 | |
 208 | | FOR | ${dut} | IN | @{duts}
 209 | | | Show SR Steering Policies | ${nodes['${dut}']}
 210 | | END
 211
 212 | Show SR LocalSIDs on all DUTs
 213 | | [Documentation] | Show SRv6 LocalSIDs on all DUT nodes in topology.
 214 | |
 215 | | ... | *Arguments:*
 216 | | ... | - nodes - Topology. Type: dictionary
 217 | |
 218 | | ... | *Example:*
 219 | |
 220 | | ... | \| Show SR LocalSIDs on all DUTs \| ${nodes} \|
 221 | |
 222 | | [Arguments] | ${nodes}
 223 | |
 224 | | FOR | ${dut} | IN | @{duts}
 225 | | | Show SR LocalSIDs | ${nodes['${dut}']}
 226 | | END
 227
 228 | Initialize SRv6 encapsulation with '${n}' x SID '${prepos}' decapsulation
 229 | | [Documentation]
 230 | | ... | Set UP state on VPP interfaces in path on node(s) in circular
 231 | | ... | topology. Get the interface MAC addresses and setup neighbours on all
 232 | | ... | VPP interfaces. Setup IPv6 addresses on all interfaces. Set segment
 233 | | ... | routing for IPv6 for required number of SIDs and configure IPv6 routes
 234 | | ... | on DUT node(s).
 235 | |
 236 | | ${status} | ${value}= | Run Keyword And Ignore Error
 237 | | ... | Variable Should Exist | ${dut2}
 238 | | ${dut2_status}= | Set Variable If | '${status}' == 'PASS' | ${True}
 239 | | ... | ${False}
 240 | |
 241 | | VPP Interface Set IP Address
 242 | | ... | ${dut1} | ${DUT1_${int}1}[0] | ${dut1_if1_ip6} | ${prefix}
 243 | | VPP Interface Set IP Address
 244 | | ... | ${dut1} | ${DUT1_${int}2}[0] | ${dut1_if2_ip6} | ${prefix}
 245 | | Run Keyword If | ${dut2_status}
 246 | | ... | VPP Interface Set IP Address
 247 | | ... | ${dut2} | ${DUT2_${int}1}[0] | ${dut2_if1_ip6} | ${prefix}
 248 | | Run Keyword If | ${dut2_status}
 249 | | ... | VPP Interface Set IP Address
 250 | | ... | ${dut2} | ${DUT2_${int}2}[0] | ${dut2_if2_ip6} | ${prefix}
 251 | | Vpp All Ra Suppress Link Layer | ${nodes}
 252 | | FOR | ${number} | IN RANGE | 2 | ${dst_addr_nr}+2
 253 | | | ${hexa_nr}= | Convert To Hex | ${number}
 254 | | | VPP Add IP Neighbor
 255 | | | ... | ${dut1} | ${DUT1_${int}1}[0] | ${tg_if1_ip6_subnet}${hexa_nr}
 256 | | | ... | ${TG_pf1_mac}[0]
 257 | | | Run Keyword If | ${dut2_status}
 258 | | | ... | VPP Add IP Neighbor
 259 | | | ... | ${dut2} | ${DUT2_${int}2}[0] | ${tg_if2_ip6_subnet}${hexa_nr}
 260 | | | ... | ${TG_pf2_mac}[0]
 261 | | END
 262 | | Run Keyword If | ${dut2_status}
 263 | | ... | VPP Add IP Neighbor
 264 | | ... | ${dut1} | ${DUT1_${int}2}[0] | ${dut2_if1_ip6}
 265 | | ... | ${DUT2_${int}1_mac}[0]
 266 | | Run Keyword Unless | ${dut2_status}
 267 | | ... | VPP Add IP Neighbor
 268 | | ... | ${dut1} | ${DUT1_${int}2}[0] | ${dut2_if1_ip6} | ${TG_pf2_mac}[0]
 269 | | Run Keyword If | ${dut2_status}
 270 | | ... | VPP Add IP Neighbor
 271 | | ... | ${dut2} | ${DUT2_${int}1}[0] | ${dut1_if2_ip6}| ${DUT1_${int}2_mac}[0]
 272 | | ${sid1}= | Set Variable If
 273 | | ... | "${n}" == "1" | ${dut2_sid1}
 274 | | ... | "${n}" == "2" | ${dut2_sid1_1}
 275 | | ${sid2}= | Set Variable If
 276 | | ... | "${n}" == "1" | ${dut1_sid2}
 277 | | ... | "${n}" == "2" | ${dut1_sid2_1}
 278 | | Vpp Route Add
 279 | | ... | ${dut1} | ${sid1} | ${sid_prefix} | gateway=${dut2_if1_ip6}
 280 | | ... | interface=${DUT1_${int}2}[0]
 281 | | Run Keyword If | ${dut2_status}
 282 | | ... | Vpp Route Add
 283 | | ... | ${dut2} | ${sid2} | ${sid_prefix} | gateway=${dut1_if2_ip6}
 284 | | ... | interface=${DUT2_${int}1}[0]
 285 # Configure SRv6 for direction0
 286 | | Set SR Encaps Source Address on DUT
 287 | | ... | ${dut1} | ${dut1_sid1}
 288 | | @{sid_list_dir0}= | Run Keyword If | '${n}' == '1'
 289 | | ... | Create List | ${dut2_sid1}
 290 | | ... | ELSE IF | '${n}' == '2'
 291 | | ... | Create List | ${dut2_sid1_1} | ${dut2_sid1_2}
 292 | | Configure SR Policy on DUT
 293 | | ... | ${dut1} | ${dut1_bsid} | encap | @{sid_list_dir0}
 294 | | Configure SR Steer on DUT
 295 | | ... | ${dut1} | L3 | ${dut1_bsid} | ip_addr=${tg_if2_ip6_subnet}
 296 | | ... | prefix=${sid_prefix}
 297 | | Run Keyword If | ${dut2_status} and '${n}' == '1'
 298 | | ... | Configure SR LocalSID on DUT
 299 | | ... | ${dut2} | ${dut2_sid1} | end.dx6 | interface=${DUT2_${int}2}[0]
 300 | | ... | next_hop=${tg_if2_ip6_subnet}2
 301 | | Run Keyword If | ${dut2_status} and '${n}' == '2'
 302 | | ... | Configure SR LocalSID on DUT
 303 | | ... | ${dut2} | ${dut2_sid1_1} | end
 304 | | Run Keyword If
 305 | | ... | ${dut2_status} and '${n}' == '2' and '${prepos}' != 'without'
 306 | | ... | Configure SR LocalSID on DUT
 307 | | ... | ${dut2} | ${dut2_sid1_2} | end.dx6
 308 | | ... | interface=${DUT2_${int}2}[0] | next_hop=${tg_if2_ip6_subnet}2
 309 | | Run Keyword If
 310 | | ... | ${dut2_status} and '${n}' == '2' and '${prepos}' == 'without'
 311 | | ... | Vpp Route Add
 312 | | ... | ${dut2} | ${dut2_sid1_2} | ${sid_prefix}
 313 | | ... | gateway=${tg_if2_ip6_subnet}2 | interface=${DUT2_${int}2}[0]
 314 # Configure SRv6 for direction1
 315 | | Run Keyword If | ${dut2_status}
 316 | | ... | Set SR Encaps Source Address on DUT
 317 | | ... | ${dut2} | ${dut2_sid2}
 318 | | @{sid_list_dir1}= | Run Keyword If | '${n}' == '1'
 319 | | ... | Create List | ${dut1_sid2}
 320 | | ... | ELSE IF | '${n}' == '2'
 321 | | ... | Create List | ${dut1_sid2_1} | ${dut1_sid2_2}
 322 | | Run Keyword If | ${dut2_status}
 323 | | ... | Configure SR Policy on DUT
 324 | | ... | ${dut2} | ${dut2_bsid} | encap | @{sid_list_dir1}
 325 | | Run Keyword If | ${dut2_status}
 326 | | ... | Configure SR Steer on DUT
 327 | | ... | ${dut2} | L3 | ${dut2_bsid} | ip_addr=${tg_if1_ip6_subnet}
 328 | | ... | prefix=${sid_prefix}
 329 | | Run Keyword If | '${n}' == '1'
 330 | | ... | Configure SR LocalSID on DUT
 331 | | ... | ${dut1} | ${dut1_sid2} | end.dx6 | interface=${DUT1_${int}1}[0]
 332 | | ... | next_hop=${tg_if1_ip6_subnet}2
 333 | | Run Keyword If | '${n}' == '2'
 334 | | ... | Configure SR LocalSID on DUT
 335 | | ... | ${dut1} | ${dut1_sid2_1} | end
 336 | | Run Keyword If | '${n}' == '2' and '${prepos}' != 'without'
 337 | | ... | Configure SR LocalSID on DUT
 338 | | ... | ${dut1} | ${dut1_sid2_2} | end.dx6 | interface=${DUT1_${int}1}[0]
 339 | | ... | next_hop=${tg_if1_ip6_subnet}2
 340 | | Run Keyword If | '${n}' == '2' and '${prepos}' == 'without'
 341 | | ... | Vpp Route Add
 342 | | ... | ${dut1} | ${dut1_sid2_2} | ${sid_prefix}
 343 | | ... | gateway=${tg_if1_ip6_subnet}2 | interface=${DUT1_${int}1}[0]
 344 | | Set interfaces in path up
 345
 346 | Initialize SRv6 with '${behavior}' SR-unaware Service Function
 347 | | [Documentation]
 348 | | ... | Create pair of Memif interfaces on all defined VPP nodes. Set UP
 349 | | ... | state on VPP interfaces in path on node(s) in circular topology.
 350 | | ... | Get the interface MAC addresses and setup neighbours on all VPP
 351 | | ... | interfaces. Setup IPv6 addresses on all interfaces. Set segment
 352 | | ... | routing for IPv6 with defined behaviour function and configure IPv6
 353 | | ... | routes on DUT node(s).
 354 | |
 355 | | ... | *Note:*
 356 | | ... | KW uses test variable rxq_count_int set by KW Add worker threads
 357 | | ... | and rxqueues to all DUTs
 358 | |
 359 | | ${status} | ${value}= | Run Keyword And Ignore Error
 360 | | ... | Variable Should Exist | ${dut2}
 361 | | ${dut2_status}= | Set Variable If | '${status}' == 'PASS' | ${True}
 362 | | ... | ${False}
 363 | |
 364 | | ${sock1}= | Set Variable | memif-DUT1_CNF
 365 | | ${sock2}= | Set Variable | memif-DUT2_CNF
 366 | | Set up memif interfaces on DUT node | ${dut1} | ${sock1} | ${sock1}
 367 | | ... | ${1} | dut1-memif-1-if1 | dut1-memif-1-if2 | ${rxq_count_int}
 368 | | ... | ${rxq_count_int}
 369 | | VPP Set interface MTU | ${dut1} | ${dut1-memif-1-if1}
 370 | | VPP Set interface MTU | ${dut1} | ${dut1-memif-1-if2}
 371 | | Run Keyword If | ${dut2_status}
 372 | | ... | Set up memif interfaces on DUT node | ${dut2} | ${sock2} | ${sock2}
 373 | | ... | ${1} | dut2-memif-1-if1 | dut2-memif-1-if2 | ${rxq_count_int}
 374 | | ... | ${rxq_count_int}
 375 | | Run Keyword If | ${dut2_status}
 376 | | ... | VPP Set interface MTU | ${dut2} | ${dut2-memif-1-if1}
 377 | | Run Keyword If | ${dut2_status}
 378 | | ... | VPP Set interface MTU | ${dut2} | ${dut2-memif-1-if2}
 379 | | FOR | ${dut} | IN | @{duts}
 380 | | | Show Memif | ${nodes['${dut}']}
 381 | | END
 382 | | VPP Interface Set IP Address
 383 | | ... | ${dut1} | ${DUT1_${int}1}[0] | ${dut1_if1_ip6} | ${prefix}
 384 | | VPP Interface Set IP Address
 385 | | ... | ${dut1} | ${DUT1_${int}2}[0] | ${dut1_if2_ip6} | ${prefix}
 386 | | VPP Interface Set IP Address | ${dut1} | ${dut1-memif-1-if1}
 387 | | ... | ${dut1-memif-1-if1_ip6} | ${mem_prefix}
 388 | | VPP Interface Set IP Address | ${dut1} | ${dut1-memif-1-if2}
 389 | | ... | ${dut1-memif-1-if2_ip6} | ${mem_prefix}
 390 | | Run Keyword If | ${dut2_status}
 391 | | ... | VPP Interface Set IP Address
 392 | | ... | ${dut2} | ${DUT2_${int}1}[0] | ${dut2_if1_ip6} | ${prefix}
 393 | | Run Keyword If | ${dut2_status}
 394 | | ... | VPP Interface Set IP Address
 395 | | ... | ${dut2} | ${DUT2_${int}2}[0] | ${dut2_if2_ip6} | ${prefix}
 396 | | Run Keyword If | ${dut2_status}
 397 | | ... | VPP Interface Set IP Address | ${dut2} | ${dut2-memif-1-if1}
 398 | | ... | ${dut2-memif-1-if1_ip6} | ${mem_prefix}
 399 | | Run Keyword If | ${dut2_status}
 400 | | ... | VPP Interface Set IP Address | ${dut2} | ${dut2-memif-1-if2}
 401 | | ... | ${dut2-memif-1-if2_ip6} | ${mem_prefix}
 402 | | Vpp All Ra Suppress Link Layer | ${nodes}
 403 | | Run Keyword If | ${dut2_status}
 404 | | ... | VPP Add IP Neighbor
 405 | | ... | ${dut1} | ${DUT1_${int}2}[0] | ${dut2_if1_ip6}
 406 | | ... | ${DUT2_${int}1_mac}[0]
 407 | | Run Keyword Unless | ${dut2_status}
 408 | | ... | VPP Add IP Neighbor
 409 | | ... | ${dut1} | ${DUT1_${int}2}[0] | ${dut2_if1_ip6} | ${TG_pf2_mac}[0]
 410 | | Run Keyword If | ${dut2_status}
 411 | | ... | VPP Add IP Neighbor
 412 | | ... | ${dut2} | ${DUT2_${int}1}[0] | ${dut1_if2_ip6}
 413 | | ... | ${DUT1_${int}2_mac}[0]
 414 | | VPP Add IP Neighbor
 415 | | ... | ${dut1} | ${DUT1_${int}1}[0] | ${tg_if1_ip6_subnet}2
 416 | | ... | ${TG_pf1_mac}[0]
 417 | | Run Keyword If | ${dut2_status}
 418 | | ... | VPP Add IP Neighbor
 419 | | ... | ${dut2} | ${DUT2_${int}2}[0] | ${tg_if2_ip6_subnet}2
 420 | | ... | ${TG_pf2_mac}[0]
 421 | | ${dut1-memif-1-if2_mac}= | Get Interface MAC | ${dut1} | memif2
 422 | | ${dut2-memif-1-if2_mac}= | Run Keyword If | ${dut2_status}
 423 | | ... | Get Interface MAC | ${dut2} | memif2
 424 | | VPP Add IP Neighbor | ${dut1}
 425 | | ... | ${dut1-memif-1-if1} | ${dut1_nh} | ${dut1-memif-1-if2_mac}
 426 | | Run Keyword If | ${dut2_status}
 427 | | ... | VPP Add IP Neighbor | ${dut2}
 428 | | ... | ${dut2-memif-1-if1} | ${dut2_nh} | ${dut2-memif-1-if2_mac}
 429 | | Vpp Route Add | ${dut1} | ${dut2_sid1} | ${sid_prefix}
 430 | | ... | gateway=${dut2_if1_ip6} | interface=${dut1_if2}
 431 | | Vpp Route Add | ${dut1} | ${out_sid2_1} | ${sid_prefix}
 432 | | ... | gateway=${tg_if1_ip6_subnet}2 | interface=${dut1_if1}
 433 | | Run Keyword If | ${dut2_status}
 434 | | ... | Vpp Route Add | ${dut2} | ${dut1_sid2} | ${sid_prefix}
 435 | | ... | gateway=${dut1_if2_ip6} | interface=${dut2_if1}
 436 | | Run Keyword If | ${dut2_status}
 437 | | ... | Vpp Route Add | ${dut2} | ${out_sid1_1} | ${sid_prefix}
 438 | | ... | gateway=${tg_if2_ip6_subnet}2 | interface=${dut2_if2}
 439 # Configure SRv6 for direction0 on DUT1
 440 | | Set SR Encaps Source Address on DUT | ${dut1} | ${dut1_sid1}
 441 | | @{sid_list_dir0}= | Create List | ${dut2_sid1} | ${out_sid1_1}
 442 | | ... | ${out_sid1_2}
 443 | | Configure SR Policy on DUT | ${dut1} | ${dut1_bsid} | encap
 444 | | ... | @{sid_list_dir0}
 445 | | Configure SR Steer on DUT | ${dut1} | L3 | ${dut1_bsid}
 446 | | ... | ip_addr=${tg_if2_ip6_subnet} | prefix=${sid_prefix}
 447 # Configure SRv6 for direction1 on DUT2
 448 | | Run Keyword If | ${dut2_status}
 449 | | ... | Set SR Encaps Source Address on DUT | ${dut2} | ${dut2_sid2}
 450 | | @{sid_list_dir1}= | Create List | ${dut1_sid2} | ${out_sid2_1}
 451 | | ... | ${out_sid2_2}
 452 | | Run Keyword If | ${dut2_status}
 453 | | ... | Configure SR Policy on DUT | ${dut2} | ${dut2_bsid} | encap
 454 | | ... | @{sid_list_dir1}
 455 | | Run Keyword If | ${dut2_status}
 456 | | ... | Configure SR Steer on DUT | ${dut2} | L3 | ${dut2_bsid}
 457 | | ... | ip_addr=${tg_if1_ip6_subnet} | prefix=${sid_prefix}
 458 # Configure SRv6 for direction0 on DUT2
 459 | | ${dut2_out_if}= | Run Keyword If | ${dut2_status}
 460 | | ... | Get Interface Name | ${dut2} | memif1
 461 | | ${dut2_in_if}= | Run Keyword If | ${dut2_status}
 462 | | ... | Get Interface Name | ${dut2} | memif2
 463 | | Remove Values From List | ${sid_list_dir0} | ${dut2_sid1}
 464 | | Run Keyword If | ${dut2_status} and '${behavior}' == 'static_proxy'
 465 | | ... | Configure SR LocalSID on DUT | ${dut2} | ${dut2_sid1} | end.as
 466 | | ... | ${NONE} | ${dut2_nh} | ${NONE} | ${dut2_out_if} | ${dut2_in_if}
 467 | | ... | ${dut1_sid1} | @{sid_list_dir0}
 468 | | ... | ELSE IF | ${dut2_status} and '${behavior}' == 'dynamic_proxy'
 469 | | ... | Configure SR LocalSID on DUT | ${dut2} | ${dut2_sid1} | end.ad
 470 | | ... | next_hop=${dut2_nh} | out_if=${dut2_out_if} | in_if=${dut2_in_if}
 471 | | ... | ELSE IF | ${dut2_status} and '${behavior}' == 'masquerading'
 472 | | ... | Configure SR LocalSID on DUT | ${dut2} | ${dut2_sid1} | end.am
 473 | | ... | next_hop=${dut2_nh} | out_if=${dut2_out_if} | in_if=${dut2_in_if}
 474 | | ... | ELSE IF | ${dut2_status}
 475 | | ... | Fail | Unsupported behaviour: ${behavior}
 476 # Configure SRv6 for direction1 on DUT1
 477 | | ${dut1_out_if}= | Get Interface Name | ${dut1} | memif1
 478 | | ${dut1_in_if}= | Get Interface Name | ${dut1} | memif2
 479 | | Remove Values From List | ${sid_list_dir1} | ${dut1_sid2}
 480 | | Run Keyword If | '${behavior}' == 'static_proxy'
 481 | | ... | Configure SR LocalSID on DUT | ${dut1} | ${dut1_sid2} | end.as
 482 | | ... | ${NONE} | ${dut1_nh} | ${NONE} | ${dut1_out_if} | ${dut1_in_if}
 483 | | ... | ${dut2_sid2} | @{sid_list_dir1}
 484 | | ... | ELSE IF | '${behavior}' == 'dynamic_proxy'
 485 | | ... | Configure SR LocalSID on DUT | ${dut1} | ${dut1_sid2} | end.ad
 486 | | ... | next_hop=${dut1_nh} | out_if=${dut1_out_if} | in_if=${dut1_in_if}
 487 | | ... | ELSE IF | '${behavior}' == 'masquerading'
 488 | | ... | Configure SR LocalSID on DUT | ${dut1} | ${dut1_sid2} | end.am
 489 | | ... | next_hop=${dut1_nh} | out_if=${dut1_out_if} | in_if=${dut1_in_if}
 490 | | ... | ELSE | Fail | Unsupported behaviour: ${behavior}
 491 | | Set interfaces in path up