resources/libraries/robot/shared/default.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/vm/qemu.robot
  16 | Resource | resources/libraries/robot/vm/double_qemu_setup.robot
  17 | Variables | resources/libraries/python/topology.py
  18 | Variables | resources/libraries/python/VatHistory.py
  19 | Library | resources.libraries.python.topology.Topology
  20 | Library | resources.libraries.python.VatHistory
  21 | Library | resources.libraries.python.CpuUtils
  22 | Library | resources.libraries.python.DUTSetup
  23 | Library | resources.libraries.python.SchedUtils
  24 | Library | resources.libraries.python.TGSetup
  25 | Library | resources.libraries.python.L2Util
  26 | Library | resources.libraries.python.Tap
  27 | Library | resources.libraries.python.VppCounters
  28 | Library | resources.libraries.python.VPPUtil
  29 | Library | resources.libraries.python.Trace
  30 | Library | Collections
  31
  32 *** Keywords ***
  33 | Configure all DUTs before test
  34 | | [Documentation] | Setup all DUTs in topology before test execution.
  35 | | ...
  36 | | Setup All DUTs | ${nodes}
  37
  38 | Configure all TGs for traffic script
  39 | | [Documentation] | Prepare all TGs before traffic scripts execution.
  40 | | ...
  41 | | All TGs Set Interface Default Driver | ${nodes}
  42
  43 | Show Vpp Errors On All DUTs
  44 | | [Documentation] | Show VPP errors verbose on all DUTs.
  45 | | ...
  46 | | ${duts}= | Get Matches | ${nodes} | DUT*
  47 | | :FOR | ${dut} | IN | @{duts}
  48 | | | Vpp Show Errors | ${nodes['${dut}']}
  49
  50 | Show VPP trace dump on all DUTs
  51 | | [Documentation] | Save API trace and dump output on all DUTs.
  52 | | ...
  53 | | ${duts}= | Get Matches | ${nodes} | DUT*
  54 | | :FOR | ${dut} | IN | @{duts}
  55 | | | Vpp api trace save | ${nodes['${dut}']}
  56 | | | Vpp api trace dump | ${nodes['${dut}']}
  57
  58 | Show Bridge Domain Data On All DUTs
  59 | | [Documentation] | Show Bridge Domain data on all DUTs.
  60 | | ...
  61 | | ${duts}= | Get Matches | ${nodes} | DUT*
  62 | | :FOR | ${dut} | IN | @{duts}
  63 | | | Vpp Get Bridge Domain Data | ${nodes['${dut}']}
  64
  65 | Setup Scheduler Policy for Vpp On All DUTs
  66 | | [Documentation] | Set realtime scheduling policy (SCHED_RR) with priority 1
  67 | | ... | on all VPP worker threads on all DUTs.
  68 | | ...
  69 | | ${duts}= | Get Matches | ${nodes} | DUT*
  70 | | :FOR | ${dut} | IN | @{duts}
  71 | | | Set VPP Scheduling rr | ${nodes['${dut}']}
  72
  73 | Configure crypto device on all DUTs
  74 | | [Documentation] | Verify if Crypto QAT device virtual functions are
  75 | | ... | initialized on all DUTs. If parameter force_init is set to True, then
  76 | | ... | try to initialize/disable.
  77 | | ...
  78 | | ... | *Arguments:*
  79 | | ... | - force_init - Force to initialize. Type: boolean
  80 | | ... | - numvfs - Number of VFs to initialize, 0 - disable the VFs
  81 | | ... | (Optional). Type: integer, default value: ${32}
  82 | | ...
  83 | | ... | *Example:*
  84 | | ...
  85 | | ... | \| Configure crypto device on all DUTs \| ${True} \|
  86 | | ...
  87 | | [Arguments] | ${force_init}=${False} | ${numvfs}=${32}
  88 | | ...
  89 | | ${duts}= | Get Matches | ${nodes} | DUT*
  90 | | :FOR | ${dut} | IN | @{duts}
  91 | | | Crypto Device Verify | ${nodes['${dut}']} | force_init=${force_init}
  92 | | | ... | numvfs=${numvfs}
  93
  94 | Configure kernel module on all DUTs
  95 | | [Documentation] | Verify if specific kernel module is loaded on all DUTs.
  96 | | ... | If parameter force_load is set to True, then try to initialize.
  97 | | ...
  98 | | ... | *Arguments:*
  99 | | ... | - module - Module to verify. Type: string
 100 | | ... | - force_load - Try to load module. Type: boolean
 101 | | ...
 102 | | ... | *Example:*
 103 | | ...
 104 | | ... | \| Configure kernel module on all DUTs \| ${True} \|
 105 | | ...
 106 | | [Arguments] | ${module} | ${force_load}=${False}
 107 | | ...
 108 | | ${duts}= | Get Matches | ${nodes} | DUT*
 109 | | :FOR | ${dut} | IN | @{duts}
 110 | | | Kernel Module Verify | ${nodes['${dut}']} | ${module}
 111 | | | ... | force_load=${force_load}
 112
 113 | Create base startup configuration of VPP on all DUTs
 114 | | [Documentation] | Create base startup configuration of VPP to all DUTs.
 115 | | ...
 116 | | ${duts}= | Get Matches | ${nodes} | DUT*
 117 | | :FOR | ${dut} | IN | @{duts}
 118 | | | Import Library | resources.libraries.python.VppConfigGenerator
 119 | | | ... | WITH NAME | ${dut}
 120 | | | Run keyword | ${dut}.Set Node |  ${nodes['${dut}']}
 121 | | | Run keyword | ${dut}.Add Unix Log
 122 | | | Run keyword | ${dut}.Add Unix CLI Listen
 123 | | | Run keyword | ${dut}.Add Unix Nodaemon
 124 | | | Run keyword | ${dut}.Add DPDK Socketmem | "1024,1024"
 125 | | | Run keyword | ${dut}.Add DPDK No Tx Checksum Offload
 126 | | | Run keyword | ${dut}.Add Heapsize | "4G"
 127 | | | Run keyword | ${dut}.Add Plugin | disable | default
 128 | | | Run keyword | ${dut}.Add Plugin | enable | @{plugins_to_enable}
 129 | | | Run keyword | ${dut}.Add IP6 Hash Buckets | "2000000"
 130 | | | Run keyword | ${dut}.Add IP6 Heap Size | "4G"
 131 | | | Run keyword | ${dut}.Add IP Heap Size | "4G"
 132
 133 # The following keyword results in lines longer than 80 characters.
 134 # FIXME: Rename the keyword, possibly moving arguments out of the keyword name.
 135 | Add '${m}' worker threads and '${n}' rxqueues in 3-node single-link circular topology
 136 | | [Documentation] | Setup M worker threads and N rxqueues in vpp startup\
 137 | | ... | configuration on all DUTs in 3-node single-link topology.
 138 | | ...
 139 | | ${m_int}= | Convert To Integer | ${m}
 140 | | ${dut1_numa}= | Get interfaces numa node | ${dut1}
 141 | | ... | ${dut1_if1} | ${dut1_if2}
 142 | | ${dut2_numa}= | Get interfaces numa node | ${dut2}
 143 | | ... | ${dut2_if1} | ${dut2_if2}
 144 | | ${dut1_cpu_main}= | Cpu list per node str | ${dut1} | ${dut1_numa}
 145 | | ... | skip_cnt=${1} | cpu_cnt=${1}
 146 | | ${dut1_cpu_w}= | Cpu list per node str | ${dut1} | ${dut1_numa}
 147 | | ... | skip_cnt=${2} | cpu_cnt=${m_int}
 148 | | ${dut2_cpu_main}= | Cpu list per node str | ${dut2} | ${dut2_numa}
 149 | | ... | skip_cnt=${1} | cpu_cnt=${1}
 150 | | ${dut2_cpu_w}= | Cpu list per node str | ${dut2} | ${dut2_numa}
 151 | | ... | skip_cnt=${2} | cpu_cnt=${m_int}
 152 | | Run keyword | DUT1.Add CPU Main Core | ${dut1_cpu_main}
 153 | | Run keyword | DUT2.Add CPU Main Core | ${dut2_cpu_main}
 154 | | Run keyword | DUT1.Add CPU Corelist Workers | ${dut1_cpu_w}
 155 | | Run keyword | DUT2.Add CPU Corelist Workers | ${dut2_cpu_w}
 156 | | Run keyword | DUT1.Add DPDK Dev Default RXQ | ${n}
 157 | | Run keyword | DUT2.Add DPDK Dev Default RXQ | ${n}
 158
 159 | Add '${m}' worker threads and '${n}' rxqueues in 2-node single-link circular topology
 160 | | [Documentation] | Setup M worker threads and N rxqueues in vpp startup\
 161 | | ... | configuration on all DUTs in 2-node single-link topology.
 162 | | ...
 163 | | ${m_int}= | Convert To Integer | ${m}
 164 | | ${dut1_numa}= | Get interfaces numa node | ${dut1}
 165 | | ... | ${dut1_if1} | ${dut1_if2}
 166 | | ${dut1_cpu_main}= | Cpu list per node str | ${dut1} | ${dut1_numa}
 167 | | ... | skip_cnt=${1} | cpu_cnt=${1}
 168 | | ${dut1_cpu_w}= | Cpu list per node str | ${dut1} | ${dut1_numa}
 169 | | ... | skip_cnt=${2} | cpu_cnt=${m_int}
 170 | | Run keyword | DUT1.Add CPU Main Core | ${dut1_cpu_main}
 171 | | Run keyword | DUT1.Add CPU Corelist Workers | ${dut1_cpu_w}
 172 | | Run keyword | DUT1.Add DPDK Dev Default RXQ | ${n}
 173
 174 | Add '${m}' worker threads using SMT and '${n}' rxqueues in 3-node single-link circular topology
 175 | | [Documentation] | Setup M worker threads using SMT and N rxqueues in vpp\
 176 | | ... | startup configuration on all DUTs in 3-node single-link topology.
 177 | | ...
 178 | | ${m_int}= | Convert To Integer | ${m}
 179 | | ${dut1_numa}= | Get interfaces numa node | ${dut1}
 180 | | ... | ${dut1_if1} | ${dut1_if2}
 181 | | ${dut2_numa}= | Get interfaces numa node | ${dut2}
 182 | | ... | ${dut2_if1} | ${dut2_if2}
 183 | | ${dut1_cpu_main}= | Cpu list per node str | ${dut1} | ${dut1_numa}
 184 | | ... | skip_cnt=${1} | cpu_cnt=${1} | smt_used=${True}
 185 | | ${dut1_cpu_w}= | Cpu list per node str | ${dut1} | ${dut1_numa}
 186 | | ... | skip_cnt=${2} | cpu_cnt=${m_int} | smt_used=${True}
 187 | | ${dut2_cpu_main}= | Cpu list per node str | ${dut2} | ${dut2_numa}
 188 | | ... | skip_cnt=${1} | cpu_cnt=${1} | smt_used=${True}
 189 | | ${dut2_cpu_w}= | Cpu list per node str | ${dut2} | ${dut2_numa}
 190 | | ... | skip_cnt=${2} | cpu_cnt=${m_int} | smt_used=${True}
 191 | | Run keyword | DUT1.Add CPU Main Core | ${dut1_cpu_main}
 192 | | Run keyword | DUT2.Add CPU Main Core | ${dut2_cpu_main}
 193 | | Run keyword | DUT1.Add CPU Corelist Workers | ${dut1_cpu_w}
 194 | | Run keyword | DUT2.Add CPU Corelist Workers | ${dut2_cpu_w}
 195 | | Run keyword | DUT1.Add DPDK Dev Default RXQ | ${n}
 196 | | Run keyword | DUT2.Add DPDK Dev Default RXQ | ${n}
 197
 198 | Add '${m}' worker threads using SMT and '${n}' rxqueues in 2-node single-link circular topology
 199 | | [Documentation] | Setup M worker threads and N rxqueues in vpp startup\
 200 | | ... | configuration on all DUTs in 2-node single-link topology.
 201 | | ...
 202 | | ${m_int}= | Convert To Integer | ${m}
 203 | | ${dut1_numa}= | Get interfaces numa node | ${dut1}
 204 | | ... | ${dut1_if1} | ${dut1_if2}
 205 | | ${dut1_cpu_main}= | Cpu list per node str | ${dut1} | ${dut1_numa}
 206 | | ... | skip_cnt=${1} | cpu_cnt=${1} | smt_used=${True}
 207 | | ${dut1_cpu_w}= | Cpu list per node str | ${dut1} | ${dut1_numa}
 208 | | ... | skip_cnt=${2} | cpu_cnt=${m_int} | smt_used=${True}
 209 | | Run keyword | DUT1.Add CPU Main Core | ${dut1_cpu_main}
 210 | | Run keyword | DUT1.Add CPU Corelist Workers | ${dut1_cpu_w}
 211 | | Run keyword | DUT1.Add DPDK Dev Default RXQ | ${n}
 212
 213 | Add no multi seg to all DUTs
 214 | | [Documentation] | Add No Multi Seg to VPP startup configuration to all DUTs.
 215 | | ...
 216 | | ${duts}= | Get Matches | ${nodes} | DUT*
 217 | | :FOR | ${dut} | IN | @{duts}
 218 | | | Run keyword | ${dut}.Add DPDK No Multi Seg
 219
 220 | Add DPDK dev default RXD to all DUTs
 221 | | [Documentation] | Add DPDK num-rx-desc to VPP startup configuration to all
 222 | | ... | DUTs.
 223 | | ...
 224 | | ... | *Arguments:*
 225 | | ... | - rxd - Number of RX descriptors. Type: string
 226 | | ...
 227 | | ... | *Example:*
 228 | | ...
 229 | | ... | \| Add DPDK dev default RXD to all DUTs \| ${rxd} \|
 230 | | ...
 231 | | [Arguments] | ${rxd}
 232 | | ...
 233 | | ${duts}= | Get Matches | ${nodes} | DUT*
 234 | | :FOR | ${dut} | IN | @{duts}
 235 | | | Run keyword | ${dut}.Add DPDK Dev Default RXD | ${rxd}
 236
 237 | Add DPDK dev default TXD to all DUTs
 238 | | [Documentation] | Add DPDK num-tx-desc to VPP startup configuration to all
 239 | | ... | DUTs.
 240 | | ...
 241 | | ... | *Arguments:*
 242 | | ... | - txd - Number of TX descriptors. Type: string
 243 | | ...
 244 | | ... | *Example:*
 245 | | ...
 246 | | ... | \| Add DPDK dev default TXD to all DUTs \| ${txd} \|
 247 | | ...
 248 | | [Arguments] | ${txd}
 249 | | ...
 250 | | ${duts}= | Get Matches | ${nodes} | DUT*
 251 | | :FOR | ${dut} | IN | @{duts}
 252 | | | Run keyword | ${dut}.Add DPDK Dev Default TXD | ${txd}
 253
 254 | Add DPDK Uio Driver on all DUTs
 255 | | [Documentation] | Add DPDK uio driver to VPP startup configuration on all
 256 | | ... | DUTs.
 257 | | ...
 258 | | ... | *Arguments:*
 259 | | ... | - uio_driver - Required uio driver. Type: string
 260 | | ...
 261 | | ... | *Example:*
 262 | | ...
 263 | | ... | \| Add DPDK Uio Driver on all DUTs \| igb_uio \|
 264 | | ...
 265 | | [Arguments] | ${uio_driver}
 266 | | ...
 267 | | ${duts}= | Get Matches | ${nodes} | DUT*
 268 | | :FOR | ${dut} | IN | @{duts}
 269 | | | Run keyword | ${dut}.Add DPDK Uio Driver | ${uio_driver}
 270
 271 | Add NAT to all DUTs
 272 | | [Documentation] | Add NAT configuration to all DUTs.
 273 | | ...
 274 | | ${duts}= | Get Matches | ${nodes} | DUT*
 275 | | :FOR | ${dut} | IN | @{duts}
 276 | | | Run keyword | ${dut}.Add NAT
 277
 278 | Add cryptodev to all DUTs
 279 | | [Documentation] | Add Cryptodev to VPP startup configuration to all DUTs.
 280 | | ...
 281 | | ... | *Arguments:*
 282 | | ... | - count - Number of QAT devices. Type: integer
 283 | | ...
 284 | | ... | *Example:*
 285 | | ...
 286 | | ... | \| Add cryptodev to all DUTs \| ${4} \|
 287 | | ...
 288 | | [Arguments] | ${count}
 289 | | ${duts}= | Get Matches | ${nodes} | DUT*
 290 | | :FOR | ${dut} | IN | @{duts}
 291 | | | Run keyword | ${dut}.Add DPDK Cryptodev | ${count}
 292
 293 | Add DPDK SW cryptodev on DUTs in 3-node single-link circular topology
 294 | | [Documentation] | Add required number of SW crypto devices of given type
 295 | | ... | to VPP startup configuration on all DUTs in 3-node single-link
 296 | | ... | circular topology.
 297 | | ...
 298 | | ... | *Arguments:*
 299 | | ... | - sw_pmd_type - PMD type of SW crypto device. Type: string
 300 | | ... | - count - Number of SW crypto devices. Type: string
 301 | | ...
 302 | | ... | *Example:*
 303 | | ...
 304 | | ... | \| Add DPDK SW cryptodev on DUTs in 3-node single-link circular\
 305 | | ... | topology \| aesni-mb \| ${2} \|
 306 | | ...
 307 | | [Arguments] | ${sw_pmd_type} | ${count}
 308 | | ${socket_id}= | Get Interface Numa Node | ${nodes['DUT1']} | ${dut1_if2}
 309 | | Run keyword | DUT1.Add DPDK SW Cryptodev | ${sw_pmd_type} | ${socket_id}
 310 | | ... | ${count}
 311 | | ${socket_id}= | Get Interface Numa Node | ${nodes['DUT2']} | ${dut2_if1}
 312 | | Run keyword | DUT2.Add DPDK SW Cryptodev | ${sw_pmd_type} | ${socket_id}
 313 | | ... | ${count}
 314
 315 | Apply startup configuration on all VPP DUTs
 316 | | [Documentation] | Write startup configuration and restart VPP on all DUTs.
 317 | | ...
 318 | | ... | *Arguments:*
 319 | | ... | - restart_vpp - Whether to restart VPP (Optional). Type: boolean
 320 | | ...
 321 | | ... | *Example:*
 322 | | ...
 323 | | ... | \| Apply startup configuration on all VPP DUTs \| ${False} \|
 324 | | ...
 325 | | [Arguments] | ${restart_vpp}=${True}
 326 | | ...
 327 | | ${duts}= | Get Matches | ${nodes} | DUT*
 328 | | :FOR | ${dut} | IN | @{duts}
 329 | | | Run keyword | ${dut}.Apply Config | restart_vpp=${restart_vpp}
 330 | | Update All Interface Data On All Nodes | ${nodes} | skip_tg=${True}
 331
 332 | Save VPP PIDs
 333 | | [Documentation] | Get PIDs of VPP processes from all DUTs in topology and\
 334 | | ... | set it as a test variable. The PIDs are stored as dictionary items\
 335 | | ... | where the key is the host and the value is the PID.
 336 | | ...
 337 | | ${setup_vpp_pids}= | Get VPP PIDs | ${nodes}
 338 | | ${keys}= | Get Dictionary Keys | ${setup_vpp_pids}
 339 | | :FOR | ${key} | IN | @{keys}
 340 | | | ${pid}= | Get From Dictionary | ${setup_vpp_pids} | ${key}
 341 | | | Run Keyword If | $pid is None | FAIL | No VPP PID found on node ${key}
 342 | | | Run Keyword If | ',' in '${pid}'
 343 | | | ... | FAIL | More then one VPP PID found on node ${key}: ${pid}
 344 | | Set Test Variable | ${setup_vpp_pids}
 345
 346 | Verify VPP PID in Teardown
 347 | | [Documentation] | Check if the VPP PIDs on all DUTs are the same at the end\
 348 | | ... | of test as they were at the begining. If they are not, only a message\
 349 | | ... | is printed on console and to log. The test will not fail.
 350 | | ...
 351 | | ${teardown_vpp_pids}= | Get VPP PIDs | ${nodes}
 352 | | ${err_msg}= | Catenate | ${SUITE NAME} - ${TEST NAME}
 353 | | ... | \nThe VPP PIDs are not equal!\nTest Setup VPP PIDs:
 354 | | ... | ${setup_vpp_pids}\nTest Teardown VPP PIDs: ${teardown_vpp_pids}
 355 | | ${rc} | ${msg}= | Run keyword and ignore error
 356 | | ... | Dictionaries Should Be Equal
 357 | | ... | ${setup_vpp_pids} | ${teardown_vpp_pids}
 358 | | Run Keyword And Return If | '${rc}'=='FAIL' | Log | ${err_msg}
 359 | | ... | console=yes | level=WARN
 360
 361 | Set up functional test
 362 | | [Documentation] | Common test setup for functional tests.
 363 | | ...
 364 | | Configure all DUTs before test
 365 | | Save VPP PIDs
 366 | | Configure all TGs for traffic script
 367 | | Update All Interface Data On All Nodes | ${nodes}
 368 | | Reset VAT History On All DUTs | ${nodes}
 369
 370 | Tear down functional test
 371 | | [Documentation] | Common test teardown for functional tests.
 372 | | ...
 373 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
 374 | | Show Packet Trace on All DUTs | ${nodes}
 375 | | Show VAT History On All DUTs | ${nodes}
 376 | | Vpp Show Errors On All DUTs | ${nodes}
 377 | | Verify VPP PID in Teardown
 378
 379 | Tear down LISP functional test
 380 | | [Documentation] | Common test teardown for functional tests with LISP.
 381 | | ...
 382 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
 383 | | Show Packet Trace on All DUTs | ${nodes}
 384 | | Show VAT History On All DUTs | ${nodes}
 385 | | Show Vpp Settings | ${nodes['DUT1']}
 386 | | Show Vpp Settings | ${nodes['DUT2']}
 387 | | Vpp Show Errors On All DUTs | ${nodes}
 388 | | Verify VPP PID in Teardown
 389
 390 | Tear down LISP functional test with QEMU
 391 | | [Documentation] | Common test teardown for functional tests with LISP and\
 392 | | ... | QEMU.
 393 | | ...
 394 | | ... | *Arguments:*
 395 | | ... | - vm_node - VM to stop. Type: string
 396 | | ...
 397 | | ... | *Example:*
 398 | | ...
 399 | | ... | \| Tear down LISP functional test with QEMU \| ${vm_node} \|
 400 | | ...
 401 | | [Arguments] | ${vm_node}
 402 | | ...
 403 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
 404 | | Show Packet Trace on All DUTs | ${nodes}
 405 | | Show VAT History On All DUTs | ${nodes}
 406 | | Show Vpp Settings | ${nodes['DUT1']}
 407 | | Show Vpp Settings | ${nodes['DUT2']}
 408 | | Vpp Show Errors On All DUTs | ${nodes}
 409 | | Stop and clear QEMU | ${nodes['DUT1']} | ${vm_node}
 410 | | Verify VPP PID in Teardown
 411
 412 | Set up TAP functional test
 413 | | [Documentation] | Common test setup for functional tests with TAP.
 414 | | ...
 415 | | Set up functional test
 416 | | Clean Up Namespaces | ${nodes['DUT1']}
 417
 418 | Tear down TAP functional test
 419 | | [Documentation] | Common test teardown for functional tests with TAP.
 420 | | ...
 421 | | Tear down functional test
 422 | | Clean Up Namespaces | ${nodes['DUT1']}
 423
 424 | Tear down TAP functional test with Linux bridge
 425 | | [Documentation] | Common test teardown for functional tests with TAP and
 426 | | ... | a Linux bridge.
 427 | | ...
 428 | | ... | *Arguments:*
 429 | | ... | - bid_TAP - Bridge name. Type: string
 430 | | ...
 431 | | ... | *Example:*
 432 | | ...
 433 | | ... | \| Tear down TAP functional test with Linux bridge \| ${bid_TAP} \|
 434 | | ...
 435 | | [Arguments] | ${bid_TAP}
 436 | | ...
 437 | | Tear down functional test
 438 | | Linux Del Bridge | ${nodes['DUT1']} | ${bid_TAP}
 439 | | Clean Up Namespaces | ${nodes['DUT1']}
 440
 441 | Tear down FDS functional test
 442 | | [Documentation] | Common test teardown for FDS functional tests.
 443 | | ...
 444 | | ... | *Arguments:*
 445 | | ... | - dut1_node - Node Nr.1 where to clean qemu. Type: dictionary
 446 | | ... | - qemu_node1 - VM Nr.1 node info dictionary. Type: string
 447 | | ... | - dut2_node - Node Nr.2 where to clean qemu. Type: dictionary
 448 | | ... | - qemu_node2 - VM Nr.2 node info dictionary. Type: string
 449 | | ...
 450 | | ... | *Example:*
 451 | | ...
 452 | | ... | \| Tear down FDS functional test \| ${dut1_node} \| ${qemu_node1}\
 453 | | ... | \| ${dut2_node} \| ${qemu_node2} \|
 454 | | ...
 455 | | [Arguments] | ${dut1_node} | ${qemu_node1} | ${dut2_node}
 456 | | ... | ${qemu_node2}
 457 | | ...
 458 | | Tear down functional test
 459 | | Tear down QEMU | ${dut1_node} | ${qemu_node1} | qemu_node1
 460 | | Tear down QEMU | ${dut2_node} | ${qemu_node2} | qemu_node2
 461
 462 | Stop VPP Service on DUT
 463 | | [Documentation] | Stop the VPP service on the specified node.
 464 | | ...
 465 | | ... | *Arguments:*
 466 | | ... | - node - information about a DUT node. Type: dictionary
 467 | | ...
 468 | | ... | *Example:*
 469 | | ...
 470 | | ... | \| Stop VPP Service on DUT \| ${nodes['DUT1']} \|
 471 | | ...
 472 | | [Arguments] | ${node}
 473 | | Stop VPP Service | ${node}
 474
 475 | Start VPP Service on DUT
 476 | | [Documentation] | Start the VPP service on the specified node.
 477 | | ...
 478 | | ... | *Arguments:*
 479 | | ... | - node - information about a DUT node. Type: dictionary
 480 | | ...
 481 | | ... | *Example:*
 482 | | ...
 483 | | ... | \| Start VPP Service on DUT \| ${nodes['DUT1']} \|
 484 | | ...
 485 | | [Arguments] | ${node}
 486 | | Start VPP Service | ${node}