resources/libraries/robot/shared/test_teardown.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 """Keywords used in test teardowns."""
  15
  16 *** Settings ***
  17 | Resource | resources/libraries/robot/shared/container.robot
  18 | Library | resources.libraries.python.PapiHistory
  19 | Library | resources.libraries.python.topology.Topology
  20 | Variables | resources/libraries/python/Constants.py
  21 |
  22 | Documentation | Test teardown keywords.
  23
  24 *** Keywords ***
  25 | Tear down test
  26 | | [Documentation]
  27 | | ... | Common test teardown for tests.
  28 | |
  29 | | ... | *Arguments:*
  30 | | ... | - ${actions} - Additional teardown action. Type: list
  31 | |
  32 | | [Arguments] | @{actions}
  33 | |
  34 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
  35 | | Show PAPI History On All DUTs | ${nodes}
  36 | | Run Keyword If Test Failed
  37 | | ... | Get Core Files on All Nodes | ${nodes}
  38 | | Run Keyword If Test Failed
  39 | | ... | Verify VPP PID in Teardown
  40 | | FOR | ${action} | IN | @{actions}
  41 | | | Run Keyword | Additional Test Tear Down Action For ${action}
  42 | | END
  43 | | Clean Sockets On All Nodes | ${nodes}
  44
  45 | Additional Test Tear Down Action For performance
  46 | | [Documentation]
  47 | | ... | Additional teardown for tests which uses performance measurement.
  48 | |
  49 | | Run Keyword If Test Failed
  50 | | ... | Send traffic at specified rate | ${PERF_TRIAL_DURATION} | 10000pps
  51 | | ... | ${frame_size} | ${traffic_profile} | pkt_trace=${True}
  52
  53 | Additional Test Tear Down Action For packet_trace
  54 | | [Documentation]
  55 | | ... | Additional teardown for tests which uses packet trace.
  56 | |
  57 | | Show Packet Trace on All DUTs | ${nodes}
  58
  59 | Additional Test Tear Down Action For container
  60 | | [Documentation]
  61 | | ... | Additional teardown for tests which uses containers.
  62 | |
  63 | | FOR | ${container_group} | IN | @{container_groups}
  64 | | | Destroy all '${container_group}' containers
  65 | | END
  66
  67 | Additional Test Tear Down Action For vhost
  68 | | [Documentation]
  69 | | ... | Additional teardown for tests which uses vhost(s) and VM(s).
  70 | |
  71 | | Show VPP vhost on all DUTs | ${nodes}
  72 | | ${vnf_status} | ${value}= | Run Keyword And Ignore Error
  73 | | ... | Keyword Should Exist | vnf_manager.Kill All VMs
  74 | | Run Keyword If | '${vnf_status}' == 'PASS' | vnf_manager.Kill All VMs
  75
  76 | Additional Test Tear Down Action For nat
  77 | | [Documentation]
  78 | | ... | Additional teardown for tests which uses NAT feature.
  79 | |
  80 | | FOR | ${dut} | IN | @{duts}
  81 | | | Run Keyword If Test Failed
  82 | | | ... | Show NAT verbose | ${nodes['${dut}']}
  83 | | END
  84
  85 | Additional Test Tear Down Action For namespace
  86 | | [Documentation]
  87 | | ... | Additional teardown for tests which uses namespace.
  88 | |
  89 | | FOR | ${dut} | IN | @{duts}
  90 | | | Clean Up Namespaces | ${nodes['${dut}']}
  91 | | END
  92
  93 | Additional Test Tear Down Action For linux_bridge
  94 | | [Documentation]
  95 | | ... | Additional teardown for tests which uses linux_bridge.
  96 | |
  97 | | FOR | ${dut} | IN | @{duts}
  98 | | | Linux Del Bridge | ${nodes['${dut}']} | ${bid_TAP}
  99 | | END
 100
 101 | Additional Test Tear Down Action For acl
 102 | | [Documentation]
 103 | | ... | Additional teardown for tests which uses ACL feature.
 104 | |
 105 | | Run Keyword If Test Failed
 106 | | ... | Vpp Log Plugin Acl Settings | ${dut1}
 107 | | Run Keyword If Test Failed
 108 | | ... | Vpp Log Plugin Acl Interface Assignment | ${dut1}
 109
 110 | Additional Test Tear Down Action For macipacl
 111 | | [Documentation]
 112 | | ... | Additional teardown for tests which uses MACIP ACL feature.
 113 | |
 114 | | Run Keyword If Test Failed
 115 | | ... | Vpp Log Macip Acl Settings | ${dut1}
 116 | | Run Keyword If Test Failed
 117 | | ... | Vpp Log Macip Acl Interface Assignment | ${dut1}
 118
 119 | Additional Test Tear Down Action For classify
 120 | | [Documentation]
 121 | | ... | Additional teardown for tests which uses classify tables.
 122 | |
 123 | | Run Keyword If Test Failed
 124 | | ... | Show Classify Tables Verbose on all DUTs | ${nodes}
 125
 126 | Additional Test Tear Down Action For srv6
 127 | | [Documentation]
 128 | | ... | Additional teardown for tests which uses SRv6.
 129 | |
 130 | | Run Keyword If Test Failed
 131 | | ... | Show SR Policies on all DUTs | ${nodes}
 132 | | Run Keyword If Test Failed
 133 | | ... | Show SR Steering Policies on all DUTs | ${nodes}
 134 | | Run Keyword If Test Failed
 135 | | ... | Show SR LocalSIDs on all DUTs | ${nodes}