resources/libraries/robot/shared/test_teardown.robot

   1 # Copyright (c) 2020 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 """Keywords used in test teardowns."""
  15
  16 *** Settings ***
  17 | Resource | resources/libraries/robot/shared/container.robot
  18 | Library | resources.libraries.python.PapiHistory
  19 | Library | resources.libraries.python.topology.Topology
  20 | Variables | resources/libraries/python/Constants.py
  21 |
  22 | Documentation | Test teardown keywords.
  23
  24 *** Keywords ***
  25 | Tear down test
  26 | | [Documentation]
  27 | | ... | Common test teardown for tests.
  28 | |
  29 | | ... | *Arguments:*
  30 | | ... | - ${actions} - Additional teardown action. Type: list
  31 | |
  32 | | [Arguments] | @{actions}
  33 | |
  34 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
  35 | | Show PAPI History On All DUTs | ${nodes}
  36 | | Run Keyword If Test Failed
  37 | | ... | Show Log On All DUTs | ${nodes}
  38 | | Run Keyword If Test Failed
  39 | | ... | Get Core Files on All Nodes | ${nodes}
  40 | | Run Keyword If Test Failed
  41 | | ... | Verify VPP PID in Teardown
  42 | | Run Keyword If Test Failed
  43 | | ... | VPP Show Memory On All DUTs | ${nodes}
  44 | | FOR | ${action} | IN | @{actions}
  45 | | | Run Keyword | Additional Test Tear Down Action For ${action}
  46 | | END
  47 | | Clean Sockets On All Nodes | ${nodes}
  48
  49 | Additional Test Tear Down Action For performance
  50 | | [Documentation]
  51 | | ... | Additional teardown for tests which uses performance measurement.
  52 | |
  53 | | Run Keyword If Test Failed
  54 | | ... | Send traffic at specified rate | ${1.0} | 10000pps
  55 | | ... | ${frame_size} | ${traffic_profile} | trial_multiplicity=${1}
  56 | | ... | extended_debug=${True}
  57
  58 | Additional Test Tear Down Action For packet_trace
  59 | | [Documentation]
  60 | | ... | Additional teardown for tests which uses packet trace.
  61 | |
  62 | | Show Packet Trace on All DUTs | ${nodes}
  63
  64 | Additional Test Tear Down Action For container
  65 | | [Documentation]
  66 | | ... | Additional teardown for tests which uses containers.
  67 | |
  68 | | FOR | ${container_group} | IN | @{container_groups}
  69 | | | Destroy all '${container_group}' containers
  70 | | END
  71
  72 | Additional Test Tear Down Action For vhost
  73 | | [Documentation]
  74 | | ... | Additional teardown for tests which uses vhost(s) and VM(s).
  75 | |
  76 | | Show VPP vhost on all DUTs | ${nodes}
  77 | | ${vnf_status} | ${value}= | Run Keyword And Ignore Error
  78 | | ... | Keyword Should Exist | vnf_manager.Kill All VMs
  79 | | Run Keyword If | '${vnf_status}' == 'PASS' | vnf_manager.Kill All VMs
  80
  81 | Additional Test Tear Down Action For nat
  82 | | [Documentation]
  83 | | ... | Additional teardown for tests which uses NAT feature.
  84 | |
  85 | | FOR | ${dut} | IN | @{duts}
  86 | | | Run Keyword If Test Failed
  87 | | | ... | Show NAT verbose | ${nodes['${dut}']}
  88 | | END
  89
  90 | Additional Test Tear Down Action For namespace
  91 | | [Documentation]
  92 | | ... | Additional teardown for tests which uses namespace.
  93 | |
  94 | | FOR | ${dut} | IN | @{duts}
  95 | | | Clean Up Namespaces | ${nodes['${dut}']}
  96 | | END
  97
  98 | Additional Test Tear Down Action For linux_bridge
  99 | | [Documentation]
 100 | | ... | Additional teardown for tests which uses linux_bridge.
 101 | |
 102 | | FOR | ${dut} | IN | @{duts}
 103 | | | Linux Del Bridge | ${nodes['${dut}']} | ${bid_TAP}
 104 | | END
 105
 106 | Additional Test Tear Down Action For acl
 107 | | [Documentation]
 108 | | ... | Additional teardown for tests which uses ACL feature.
 109 | |
 110 | | Run Keyword If Test Failed
 111 | | ... | Vpp Log Plugin Acl Settings | ${dut1}
 112 | | Run Keyword If Test Failed
 113 | | ... | Vpp Log Plugin Acl Interface Assignment | ${dut1}
 114
 115 | Additional Test Tear Down Action For macipacl
 116 | | [Documentation]
 117 | | ... | Additional teardown for tests which uses MACIP ACL feature.
 118 | |
 119 | | Run Keyword If Test Failed
 120 | | ... | Vpp Log Macip Acl Settings | ${dut1}
 121 | | Run Keyword If Test Failed
 122 | | ... | Vpp Log Macip Acl Interface Assignment | ${dut1}
 123
 124 | Additional Test Tear Down Action For classify
 125 | | [Documentation]
 126 | | ... | Additional teardown for tests which uses classify tables.
 127 | |
 128 | | Run Keyword If Test Failed
 129 | | ... | Show Classify Tables Verbose on all DUTs | ${nodes}
 130
 131 | Additional Test Tear Down Action For srv6
 132 | | [Documentation]
 133 | | ... | Additional teardown for tests which uses SRv6.
 134 | |
 135 | | Run Keyword If Test Failed
 136 | | ... | Show SR Policies on all DUTs | ${nodes}
 137 | | Run Keyword If Test Failed
 138 | | ... | Show SR Steering Policies on all DUTs | ${nodes}
 139 | | Run Keyword If Test Failed
 140 | | ... | Show SR LocalSIDs on all DUTs | ${nodes}