tests/vpp/device/crypto/eth2p-ethip4ipsec1tptsw-ip4base-policy-aes-128-cbc-sha-512-256-dev.robot

   1 # Copyright (c) 2020 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 |
  17 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | DEVICETEST | HW_ENV | DCR_ENV | SCAPY
  18 | ... | NIC_Virtual | IP4FWD | IPSEC | IPSECSW | IPSECTPT | IP4BASE
  19 | ... | AES_128_CBC | HMAC_SHA_512 | HMAC | AES | DRV_VFIO_PCI
  20 | ... | RXQ_SIZE_0 | TXQ_SIZE_0
  21 | ... | ethip4ipsec1tptsw-ip4base-policy-aes-128-cbc-sha-512-256
  22 |
  23 | Suite Setup | Setup suite single link | scapy
  24 | Test Setup | Setup test
  25 | Test Teardown | Tear down test | packet_trace
  26 |
  27 | Test Template | Local Template
  28 |
  29 | Documentation | *IPv4 IPsec transport mode test suite.*
  30 |
  31 | ... | *[Top] Network topologies:* TG-DUT1 2-node topology with one link\
  32 | ... | between nodes.
  33 | ... | *[Cfg] DUT configuration:* On DUT1 create loopback interface, configure\
  34 | ... | loopback an physical interface IPv4 addresses, static ARP record, route\
  35 | ... | and IPsec manual keyed connection in transport mode.
  36 | ... | *[Ver] TG verification:* ESP packet is sent from TG to DUT1. ESP packet\
  37 | ... | is received on TG from DUT1.
  38 | ... | *[Ref] Applicable standard specifications:* RFC4303.
  39
  40 *** Variables ***
  41 | @{plugins_to_enable}= | dpdk_plugin.so | crypto_native_plugin.so
  42 | ... | crypto_ipsecmb_plugin.so | crypto_openssl_plugin.so
  43 | ${crypto_type}= | ${None}
  44 | ${nic_name}= | virtual
  45 | ${nic_driver}= | vfio-pci
  46 | ${nic_rxq_size}= | 0
  47 | ${nic_txq_size}= | 0
  48 | ${overhead}= | ${54}
  49 | ${tg_spi}= | ${1000}
  50 | ${dut_spi}= | ${1001}
  51 | ${ESP_PROTO}= | ${50}
  52 | ${tg_if1_ip4}= | 192.168.100.2
  53 | ${tg_if2_ip4}= | 192.168.4.4
  54 | ${dut_if1_ip4}= | 192.168.100.3
  55 | ${dut_if2_ip4}= | 192.168.4.3
  56 | ${tg_host_ip4}= | 192.168.3.3
  57 | ${ip4_plen}= | ${24}
  58
  59 *** Keywords ***
  60 | Local Template
  61 | | [Documentation]
  62 | | ... | [Cfg] On DUT1 configure IPsec manual keyed connection with encryption\
  63 | | ... | algorithm AES_128_CBC and integrity algorithm HMAC_SHA_512 in\
  64 | | ... | transport mode.
  65 | |
  66 | | ... | *Arguments:*
  67 | | ... | - frame_size - Framesize in Bytes in integer. Type: integer
  68 | | ... | - phy_cores - Number of physical cores. Type: integer
  69 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  70 | |
  71 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  72 | |
  73 | | Set Test Variable | \${frame_size}
  74 | |
  75 | | # These are enums (not strings) so they cannot be in Variables table.
  76 | | ${encr_alg}= | Crypto Alg AES CBC 128
  77 | | ${auth_alg}= | Integ Alg SHA 512 256
  78 | |
  79 | | Given Set Max Rate And Jumbo
  80 | | And Add worker threads to all DUTs | ${phy_cores} | ${rxq}
  81 | | And Pre-initialize layer driver | ${nic_driver}
  82 | | And Apply startup configuration on all VPP DUTs | with_trace=${True}
  83 | | When Initialize layer driver | ${nic_driver}
  84 | | And Initialize layer interface
  85 | | And Configure topology for IPv4 IPsec testing
  86 | | And Generate keys for IPSec | ${encr_alg} | ${auth_alg}
  87 | | And Configure manual keyed connection for IPSec
  88 | | ... | ${dut1} | ${dut1_if1} | ${encr_alg} | ${encr_key} | ${auth_alg}
  89 | | ... | ${auth_key} | ${dut_spi} | ${tg_spi} | ${tg_dst_ip} | ${tg_src_ip}
  90 | | Then Send IPsec Packet and verify ESP encapsulation in received packet
  91 | | ... | ${tg} | ${tg_if1} | ${tg_if2} | ${dut1_if1_mac} | ${dut1_if2_mac}
  92 | | ... | ${encr_alg} | ${encr_key} | ${auth_alg} | ${auth_key} | ${tg_spi}
  93 | | ... | ${dut_spi} | ${tg_src_ip} | ${tg_dst_ip}
  94
  95 *** Test Cases ***
  96 | tc01-110B-ethip4ipsec1tptsw-ip4base-policy-aes-128-cbc-sha-512-256-dev
  97 | | [Tags] | 110B
  98 | | frame_size=${110} | phy_cores=${0}