tests/vpp/device/ip4/eth2p-ethip4-ip4base-ipolicemarkbase-dev.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 |
  17 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | DEVICETEST | HW_ENV | DCR_ENV | SCAPY
  18 | ... | NIC_Virtual | ETH | IP4FWD | FEATURE | POLICE_MARK | DRV_VFIO_PCI
  19 |
  20 | Suite Setup | Setup suite single link | scapy
  21 | Test Setup | Setup test
  22 | Test Teardown | Tear down test | packet_trace | classify
  23 |
  24 | Test Template | Local Template
  25 |
  26 | Documentation | *IPv4 policer test cases*
  27 |
  28 | ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology\
  29 | ... | with single links between nodes.
  30 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 on all links.
  31 | ... | *[Cfg] DUT configuration:* On DUT1 configure interfaces IPv4 adresses, \
  32 | ... | and static ARP record on the second interface. On DUT1 configure 2R3C \
  33 | ... | color-aware policer on the first interface.
  34 | ... | *[Ver] TG verification:* Test packet is sent from TG on the first link \
  35 | ... | to DUT1. Packet is received on TG on the second link from DUT1.
  36 | ... | *[Ref] Applicable standard specifications:* RFC2474, RFC2697, RFC2698.
  37
  38 *** Variables ***
  39 | @{plugins_to_enable}= | dpdk_plugin.so
  40 | ${crypto_type}= | ${None}
  41 | ${nic_name}= | virtual
  42 | ${nic_driver}= | vfio-pci
  43 | ${overhead}= | ${0}
  44 | ${cir}= | ${100}
  45 | ${eir}= | ${150}
  46 | ${dscp}= | AF22
  47
  48 *** Keywords ***
  49 | Local Template
  50 | | [Documentation]
  51 | | ... | [Ver] Test packet is sent from TG on the first link to DUT1. \
  52 | | ... | Packet is received on TG on the second link from DUT1.
  53 | |
  54 | | ... | *Arguments:*
  55 | | ... | - frame_size - Framesize in Bytes in integer. Type: integer
  56 | | ... | - phy_cores - Number of physical cores. Type: integer
  57 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  58 | |
  59 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  60 | |
  61 | | Set Test Variable | \${frame_size}
  62 | | Set Test Variable | \${cb} | ${frame_size}
  63 | | Set Test Variable | \${eb} | ${frame_size}
  64 | |
  65 | | Given Set Max Rate And Jumbo
  66 | | And Add worker threads to all DUTs | ${phy_cores} | ${rxq}
  67 | | And Pre-initialize layer driver | ${nic_driver}
  68 | | And Apply startup configuration on all VPP DUTs | with_trace=${True}
  69 | | When Initialize layer driver | ${nic_driver}
  70 | | And Initialize layer interface
  71 | | And Initialize IPv4 forwarding in circular topology
  72 | | And Initialize IPv4 policer 2r3c-'ca' in circular topology
  73 | | Then Send packet and verify marking
  74 | | ... | ${tg} | ${tg_if1} | ${tg_if2} | ${tg_if1_mac} | ${dut1_if1_mac}
  75 | | ... | 10.10.10.2 | 20.20.20.2
  76
  77 *** Test Cases ***
  78 | tc01-64B-ethip4-ip4base-ipolicemarkbase-dev
  79 | | [Tags] | 64B
  80 | | frame_size=${64} | phy_cores=${0}