tests/vpp/device/ip4_tunnels/lisp/2n1l-10ge2p1x710-ethip4lispgpe-ip6base-scapy.robot

   1 # Copyright (c) 2022 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 |
  17 | Variables | resources/test_data/lisp/lisp.py
  18 |
  19 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | DEVICETEST | HW_ENV | DCR_ENV | SCAPY
  20 | ... | NIC_Intel-X710 | IP4FWD | LISP | LISPGPE_IP6o4 | DRV_VFIO_PCI
  21 | ... | RXQ_SIZE_0 | TXQ_SIZE_0
  22 | ... | ethip4lispgpe-ip6base
  23 |
  24 | Suite Setup | Setup suite topology interfaces | scapy
  25 | Test Setup | Setup test
  26 | Test Teardown | Tear down test | packet_trace | telemetry
  27 |
  28 | Test Template | Local Template
  29 |
  30 | Documentation | **ip4-lispgpe-ip6 encapsulation test cases**
  31 | ... |
  32 | ... | - **[Top] Network Topologies:** TG(if1)-DUT1-TG(if2) 2-node \
  33 | ... | circular with single links between nodes.
  34 | ... |
  35 | ... | - **[Enc] Packet Encapsulations:** Eth-IPv4-LISPGPE-IPv6-ICMPv6 \
  36 | ... | on DUT1-TG(if2),Eth-IPv6-ICMPv6 on TG-DUTn for IPv6 \
  37 | ... | routing over LISPoIPv4 tunnel.
  38 | ... |
  39 | ... | - **[Cfg] DUT configuration:** DUT1 and TG(if2) are configured \
  40 | ... | with IPv6 routing and static routes. LISPoIPv4 tunnel is \
  41 | ... | configured between DUT1 and TG(if2).
  42 | ... |
  43 | ... | - **[Ver] TG verification:** Test ICMPv6 Echo Request packets \
  44 | ... | are sent in if1 by TG on links to DUT1; on receive \
  45 | ... | TG verifies packets for correctness and their IPv6 src-addr, \
  46 | ... | dst-addr and MAC addresses.
  47 | ... |
  48 | ... | - **[Ref] Applicable standard specifications:** RFC6830.
  49
  50 *** Variables ***
  51 | @{plugins_to_enable}= | dpdk_plugin.so | perfmon_plugin.so | lisp_plugin.so
  52 | ${crypto_type}= | ${None}
  53 | ${nic_name}= | Intel-X710
  54 | ${nic_driver}= | vfio-pci
  55 | ${nic_rxq_size}= | 0
  56 | ${nic_txq_size}= | 0
  57 | ${nic_pfs}= | 2
  58 | ${nic_vfs}= | 0
  59 | ${overhead}= | ${54}
  60 | ${ot_mode}= | 6to4
  61 | ${is_gpe}= | ${1}
  62 # Telemetry
  63 | ${telemetry_profile}= | vppctl_test_teardown
  64
  65 *** Keywords ***
  66 | Local Template
  67 | | [Documentation]
  68 | | ... | - **[Cfg]** On DUT1 configure LISPGPE.
  69 | |
  70 | | ... | *Arguments:*
  71 | | ... | - frame_size - Framesize in Bytes in integer. Type: integer
  72 | | ... | - phy_cores - Number of physical cores. Type: integer
  73 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  74 | |
  75 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  76 | |
  77 | | Set Test Variable | \${frame_size}
  78 | |
  79 | | Given Set Max Rate And Jumbo
  80 | | And Add worker threads to all DUTs | ${phy_cores} | ${rxq}
  81 | | And Pre-initialize layer driver | ${nic_driver}
  82 | | And Apply startup configuration on all VPP DUTs | with_trace=${True}
  83 | | When Initialize layer driver | ${nic_driver}
  84 | | And Initialize layer interface
  85 | | And Configure topology for IPv6 LISPoIP4 testing
  86 | | And Vpp Interfaces RA Suppress On All Nodes | ${nodes}
  87 | | And Configure LISP in 2-node circular topology
  88 | | ... | ${dut1} | ${DUT1_${int}2}[0] | ${NONE}
  89 | | ... | ${duts_locator_set} | ${dut1_ip6o4_eid}
  90 | | ... | ${dut1_ip6o4_static_adjacency} | ${is_gpe}
  91 | | Then Send packet and verify LISPoTunnel encap
  92 | | ... | ${tg} | ${tg_if1_ip6} | ${dst_ip6}
  93 | | ... | ${TG_pf1}[0] | ${TG_pf1_mac}[0] | ${DUT1_vf1_mac}[0]
  94 | | ... | ${TG_pf2}[0] | ${DUT1_vf2_mac}[0] | ${TG_pf2_mac}[0]
  95 | | ... | ${src_rloc4} | ${dst_rloc4} | ${ot_mode}
  96
  97 *** Test Cases ***
  98 | 64B-0c-ethip4lispgpe-ip6base-scapy
  99 | | [Tags] | 64B | 0C
 100 | | frame_size=${64} | phy_cores=${0}