tests/vpp/device/ip4_tunnels/lisp/eth2p-ethip4lispgpe-ip6base-dev.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 | ...
  17 # import additional Lisp settings from resource file
  18 | Variables | resources/test_data/lisp/lisp.py
  19 | ...
  20 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | DEVICETEST | HW_ENV | DCR_ENV | SCAPY
  21 | ... | NIC_Virtual | IP4FWD | LISPGPE_IP6o4
  22 | ...
  23 | Suite Setup | Setup suite single link | scapy
  24 | Test Setup | Setup test
  25 | Test Teardown | Tear down test | packet_trace
  26 | ...
  27 | Test Template | Local Template
  28 | ...
  29 | Documentation | *ip4-lispgpe-ip6 encapsulation test cases*
  30 | ...
  31 | ... | *[Top] Network Topologies:* TG(if1)-DUT1-TG(if2) 2-node\
  32 | ... | circular topology with single links between nodes.
  33 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4-LISPGPE-IPv6-ICMPv6\
  34 | ... | on DUT1-TG(if2),Eth-IPv6-ICMPv6 on TG-DUTn for IPv6\
  35 | ... | routing over LISPoIPv4 tunnel.
  36 | ... | *[Cfg] DUT configuration:* DUT1 and TG(if2) are configured\
  37 | ... | with IPv6 routing and static routes. LISPoIPv4 tunnel is\
  38 | ... | configured between DUT1 and TG(if2).
  39 | ... | *[Ver] TG verification:* Test ICMPv6 Echo Request packets\
  40 | ... | are sent in if1 by TG on links to DUT1; on receive\
  41 | ... | TG verifies packets for correctness and their IPv6 src-addr,\
  42 | ... | dst-addr and MAC addresses.
  43 | ... | *[Ref] Applicable standard specifications:* RFC6830.
  44
  45 *** Variables ***
  46 | @{plugins_to_enable}= | dpdk_plugin.so
  47 | ${nic_name}= | virtual
  48 | ${overhead}= | ${54}
  49 | ${ot_mode}= | 6to4
  50 | ${is_gpe}= | ${1}
  51
  52 *** Keywords ***
  53 | Local Template
  54 | | [Documentation]
  55 | | ... | [Cfg] On DUT1 configure LISPGPE\
  56 | | ...
  57 | | ... | *Arguments:*
  58 | | ... | - frame_size - Framesize in Bytes in integer. Type: integer
  59 | | ... | - phy_cores - Number of physical cores. Type: integer
  60 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  61 | | ...
  62 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  63 | | ...
  64 | | Set Test Variable | \${frame_size}
  65 | | ...
  66 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  67 | | And Add PCI devices to all DUTs
  68 | | And Set Max Rate And Jumbo And Handle Multi Seg
  69 | | And Apply startup configuration on all VPP DUTs | with_trace=${True}
  70 | | When Configure topology for IPv6 LISPoIP4 testing
  71 | | And Vpp All RA Suppress Link Layer | ${nodes}
  72 | | And Configure LISP in 2-node circular topology
  73 | | ... | ${dut1} | ${dut1_if2} | ${NONE}
  74 | | ... | ${duts_locator_set} | ${dut1_ip6o4_eid}
  75 | | ... | ${dut1_ip6o4_static_adjacency} | ${is_gpe}
  76 | | Then Send packet and verify LISPoTunnel encap
  77 | | ... | ${tg} | ${tg_if1_ip6} | ${dst_ip6}
  78 | | ... | ${tg_if1} | ${tg_if1_mac} | ${dut1_if1_mac}
  79 | | ... | ${tg_if2} | ${dut1_if2_mac} | ${tg_if2_mac}
  80 | | ... | ${src_rloc4} | ${dst_rloc4} | ${ot_mode}
  81
  82 *** Test Cases ***
  83 | tc01-62B-ethip4lispgpe-ip6base-dev
  84 | | [Tags] | 62B
  85 | | frame_size=${62} | phy_cores=${0}