FIB table add/delete
[csit.git] / tests / vpp / func / ip6_tunnels / lisp / eth2p-ethip6lispgpe-ip6basevrf-func.robot
1 # Copyright (c) 2016 Cisco and/or its affiliates.
2 # Licensed under the Apache License, Version 2.0 (the "License");
3 # you may not use this file except in compliance with the License.
4 # You may obtain a copy of the License at:
5 #
6 #     http://www.apache.org/licenses/LICENSE-2.0
7 #
8 # Unless required by applicable law or agreed to in writing, software
9 # distributed under the License is distributed on an "AS IS" BASIS,
10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
11 # See the License for the specific language governing permissions and
12 # limitations under the License.
13
14 *** Settings ***
15 | Library | resources.libraries.python.topology.Topology
16 | Library | resources.libraries.python.NodePath
17 | Library | resources.libraries.python.Trace
18 | Library | resources.libraries.python.IPUtil
19 | Library | resources.libraries.python.IPv6Setup
20 | Library | resources.libraries.python.VPPUtil
21 | Resource | resources/libraries/robot/shared/traffic.robot
22 | Resource | resources/libraries/robot/shared/default.robot
23 | Resource | resources/libraries/robot/shared/interfaces.robot
24 | Resource | resources/libraries/robot/shared/testing_path.robot
25 | Resource | resources/libraries/robot/vm/qemu.robot
26 | Resource | resources/libraries/robot/l2/l2_bridge_domain.robot
27 | Resource | resources/libraries/robot/overlay/lispgpe.robot
28 # Import configuration and test data:
29 | Variables | resources/test_data/lisp/ipv6_lispgpe_ipv6/ipv6_lispgpe_ipv6.py
30 | ...
31 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | VM_ENV | LISP
32 | ...
33 | Test Setup | Run Keywords | Set up functional test
34 | ... | AND  | Vpp All Ra Suppress Link Layer | ${nodes}
35 | ...
36 | Test Teardown | Tear down LISP functional test
37 | ...
38 | Documentation | *ip6-lispgpe-ip6 encapsulation test cases*
39 | ...
40 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology\
41 | ... | with single links between nodes.
42 | ... | *[Enc] Packet Encapsulations:* Eth-IPv6-LISP-IPv6-ICMPv6 on DUT1-DUT2,\
43 | ... | Eth-IPv6-ICMPv6 on TG-DUTn for IPv6 routing over LISPoIPv6 tunnel.
44 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with IPv6\
45 | ... | routing and static routes. LISPoIPv6 tunnel is configured between\
46 | ... | DUT1 and DUT2.
47 | ... | *[Ver] TG verification:* Test ICMPv6 Echo Request packets are sent in\
48 | ... | both directions by TG on links to DUT1 and DUT2; on receive\
49 | ... | TG verifies packets for correctness and their IPv6 src-addr, dst-addr\
50 | ... | and MAC addresses.
51 | ... | *[Ref] Applicable standard specifications:* RFC6830.
52
53 *** Test Cases ***
54 | TC01: DUT1 and DUT2 route IPv6 bidirectionally over LISP GPE tunnel using physical interfaces and VRF is enabled
55 | | [Documentation]
56 | | ... | [Top] TG-DUT1-DUT2-TG.
57 | | ... | [Enc] Eth-IPv6-LISPGPE-IPv6-ICMPv6 on DUT1-DUT2, Eth-IPv6-ICMPv6 on\
58 | | ... | TG-DUTn.
59 | | ... | [Cfg] Configure IPv6 LISP static adjacencies on DUT1 and DUT2.
60 | | ... | [Ver] Case: ip6-lispgpe-ip6 - vrf, phy2lisp
61 | | ... | Make TG send ICMPv6 Echo Req between its interfaces across both\
62 | | ... | DUTs and LISP GPE tunnel between them; verify IPv6 headers on\
63 | | ... | received packets are correct.
64 | | ... | [Ref] RFC6830.
65 | | ...
66 | | Given Configure path in 3-node circular topology
67 | | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
68 | | And Set interfaces in 3-node circular topology up
69 | | And Add Fib Table | ${dut1_node} | ${fib_table_1} | ip6=${TRUE}
70 | | And Add Fib Table | ${dut2_node} | ${fib_table_1} | ip6=${TRUE}
71 | | And Assign Interface To Fib Table | ${dut1_node}
72 | | ... | ${dut1_to_tg} | ${fib_table_1} | ipv6=${TRUE}
73 | | And Assign Interface To Fib Table | ${dut2_node}
74 | | ... | ${dut2_to_tg} | ${fib_table_1} | ipv6=${TRUE}
75 | | And Vpp Set If IPv6 Addr
76 | | ... | ${dut1_node} | ${dut1_to_dut2} | ${dut1_to_dut2_ip6} | ${prefix6}
77 | | And Vpp Set If IPv6 Addr
78 | | ... | ${dut1_node} | ${dut1_to_tg} | ${dut1_to_tg_ip6} | ${prefix6}
79 | | And Vpp Set If IPv6 Addr
80 | | ... | ${dut2_node} | ${dut2_to_dut1} | ${dut2_to_dut1_ip6} | ${prefix6}
81 | | And Vpp Set If IPv6 Addr
82 | | ... | ${dut2_node} | ${dut2_to_tg} | ${dut2_to_tg_ip6} | ${prefix6}
83 | | And Add IP Neighbors
84 | | And Vpp All RA Suppress Link Layer | ${nodes}
85 | | When Configure LISP GPE topology in 3-node circular topology
86 | | ... | ${dut1_node} | ${dut1_to_dut2} | ${NONE}
87 | | ... | ${dut2_node} | ${dut2_to_dut1} | ${NONE}
88 | | ... | ${duts_locator_set} | ${dut1_ip6_eid} | ${dut2_ip6_eid}
89 | | ... | ${dut1_to_dut2_ip6_static_adjacency}
90 | | ... | ${dut2_to_dut1_ip6_static_adjacency}
91 | | ... | ${dut1_dut2_vni} | ${fib_table_1}
92 | | Then Send packet and verify headers
93 | | ... | ${tg_node} | ${tg1_ip6} | ${tg2_ip6}
94 | | ... | ${tg_to_dut1} | ${tg_to_dut1_mac} | ${dut1_to_tg_mac}
95 | | ... | ${tg_to_dut2} | ${dut2_to_tg_mac} | ${tg_to_dut2_mac}
96 | | And Send packet and verify headers
97 | | ... | ${tg_node} | ${tg2_ip6} | ${tg1_ip6}
98 | | ... | ${tg_to_dut2} | ${tg_to_dut2_mac} | ${dut2_to_tg_mac}
99 | | ... | ${tg_to_dut1} | ${dut1_to_tg_mac} | ${tg_to_dut1_mac}
100
101 *** Keywords ***
102 | Add IP Neighbors
103 | | [Documentation]
104 | | ... | Add IP neighbors to physical interfaces on DUTs.
105 | | ...
106 | | Add IP Neighbor | ${dut1_node} | ${dut1_to_tg} | ${tg1_ip6}
107 | | ... | ${tg_to_dut1_mac}
108 | | Add IP Neighbor | ${dut2_node} | ${dut2_to_tg} | ${tg2_ip6}
109 | | ... | ${tg_to_dut2_mac}
110 | | Add IP Neighbor | ${dut1_node} | ${dut1_to_dut2} | ${dut2_to_dut1_ip6}
111 | | ... | ${dut2_to_dut1_mac}
112 | | Add IP Neighbor | ${dut2_node} | ${dut2_to_dut1} | ${dut1_to_dut2_ip6}
113 | | ... | ${dut1_to_dut2_mac}

©2016 FD.io a Linux Foundation Collaborative Project. All Rights Reserved.
Linux Foundation is a registered trademark of The Linux Foundation. Linux is a registered trademark of Linus Torvalds.
Please see our privacy policy and terms of use.