tests/vpp/perf/container_memif/10ge2p1x520-eth-l2xcbase-eth-2memif-1lxc-ndrpdrdisc.robot

   1 # Copyright (c) 2017 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | ...
  17 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDRDISC
  18 | ... | NIC_Intel-X520-DA2 | ETH | L2XCFWD | BASE | MEMIF | LXC
  19 | ...
  20 | Suite Setup | Run Keywords
  21 | ... | Set up 3-node performance topology with DUT's NIC model | L2
  22 | ... | Intel-X520-DA2
  23 | ... | AND | Set up performance test suite with MEMIF
  24 | ... | AND | Set up performance topology with containers
  25 | ...
  26 | Suite Teardown | Tear down 3-node performance topology with container
  27 | ...
  28 | Test Setup | Run Keywords
  29 | ... | Set up performance test
  30 | ... | AND | Restart VPP in all 'VNF' containers
  31 | ...
  32 | Test Teardown | Tear down performance discovery test | ${min_rate}pps
  33 | ... | ${framesize} | ${traffic_profile}
  34 | ...
  35 | Test Template | Local template
  36 | ...
  37 | Documentation | *RFC2544: Pkt throughput L2XC test cases*
  38 | ...
  39 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  40 | ... | with single links between nodes.
  41 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 cross connect.
  42 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2 cross-
  43 | ... | connect. DUT1 and DUT2 tested with 2p10GE NIC X520 Niantic by Intel.
  44 | ... | LXC is connected to VPP via Memif interface. LXC is running same VPP
  45 | ... | version as running on DUT. LXC is limited via cgroup to use 3 cores
  46 | ... | allocated from pool of isolated CPUs. There are no memory contraints.
  47 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop
  48 | ... | Rate) with zero packet loss tolerance or throughput PDR (Partial Drop
  49 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage
  50 | ... | of packets transmitted. NDR and PDR are discovered for different
  51 | ... | Ethernet L2 frame sizes using either binary search or linear search
  52 | ... | algorithms with configured starting rate and final step that determines
  53 | ... | throughput measurement resolution. Test packets are generated by TG on
  54 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups
  55 | ... | (flow-group per direction, 253 flows per flow-group) with all packets
  56 | ... | containing Ethernet header, IPv4 header with IP protocol=61 and static
  57 | ... | payload. MAC addresses are matching MAC addresses of the TG node
  58 | ... | interfaces.
  59 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  60
  61 *** Variables ***
  62 | ${avg_imix_framesize}= | ${357.833}
  63 # X520-DA2 bandwidth limit
  64 | ${s_limit} | ${10000000000}
  65 # Traffic profile:
  66 | ${traffic_profile} | trex-sl-3n-ethip4-ip4src254
  67 # LXC container
  68 | ${container_count}= | ${1}
  69 | ${container_engine}= | LXC
  70 | ${container_image}= | ${EMPTY}
  71 | ${container_install_dkms}= | ${FALSE}
  72 | ${container_chain_topology}= | chain
  73 # CPU settings
  74 | ${system_cpus}= | ${1}
  75 | ${vpp_cpus}= | ${5}
  76 | ${container_cpus}= | ${5}
  77
  78 *** Keywords ***
  79 | L2 Cross Connect over Memif Binary Search
  80 | | [Documentation]
  81 | | ... | [Cfg] DUT runs L2XC switching config.
  82 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  83 | | ... | [Ver] Find ${search_type} for ${framesize}B frames using binary search\
  84 | | ... | start at linerate, step ${min_rate}pps.
  85 | | ...
  86 | | ... | *Arguments:*
  87 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  88 | | ... | Type: integer, string
  89 | | ... | - phy_cores - Number of physical cores. Type: integer
  90 | | ... | - search_type - NDR or PDR. Type: string
  91 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  92 | | ... | - min_rate - Min rate for binary search, default value: ${50000}.
  93 | | ... | Type: integer
  94 | | ...
  95 | | [Arguments] | ${framesize} | ${phy_cores} | ${search_type}
  96 | | ... | ${rxq}=${None} | ${min_rate}=${50000}
  97 | | ...
  98 | | Set Test Variable | ${framesize}
  99 | | Set Test Variable | ${min_rate}
 100 | | ${get_framesize}= | Set Variable If
 101 | | ... | "${framesize}" == "IMIX_v4_1" | ${avg_imix_framesize} | ${framesize}
 102 | | ${max_rate}= | Calculate pps | ${s_limit} | ${get_framesize}
 103 | | ${binary_min}= | Set Variable | ${min_rate}
 104 | | ${binary_max}= | Set Variable | ${max_rate}
 105 | | ${threshold}= | Set Variable | ${min_rate}
 106 | | Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
 107 | | Add PCI devices to all DUTs
 108 | | Run Keyword If | ${get_framesize} < ${1522} | Add No Multi Seg to all DUTs
 109 | | Apply startup configuration on all VPP DUTs
 110 | | Initialize L2 xconnect for '1' memif pairs in 3-node circular topology
 111 | | Run Keyword If | '${search_type}' == 'NDR'
 112 | | ... | Find NDR using binary search and pps
 113 | | ... | ${framesize} | ${binary_min} | ${binary_max} | ${traffic_profile}
 114 | | ... | ${min_rate} | ${max_rate} | ${threshold}
 115 | | ... | ELSE IF | '${search_type}' == 'PDR'
 116 | | ... | Find PDR using binary search and pps
 117 | | ... | ${framesize} | ${binary_min} | ${binary_max} | ${traffic_profile}
 118 | | ... | ${min_rate} | ${max_rate} | ${threshold}
 119 | | ... | ${perf_pdr_loss_acceptance} | ${perf_pdr_loss_acceptance_type}
 120
 121 *** Test Cases ***
 122 | tc01-64B-1t1c-eth-l2xcbase-eth-2memif-1lxc-ndrdisc
 123 | | [Tags] | 64B | 1C | NDRDISC
 124 | | framesize=${64} | phy_cores=${1} | search_type=NDR
 125
 126 | tc02-64B-1t1c-eth-l2xcbase-eth-2memif-1lxc-pdrdisc
 127 | | [Tags] | 64B | 1C | PDRDISC
 128 | | framesize=${64} | phy_cores=${1} | search_type=PDR
 129
 130 | tc03-IMIX-1t1c-eth-l2xcbase-eth-2memif-1lxc-ndrdisc
 131 | | [Tags] | IMIX | 1C | NDRDISC
 132 | | framesize=IMIX_v4_1 | phy_cores=${1} | search_type=NDR
 133
 134 | tc04-IMIX-1t1c-eth-l2xcbase-eth-2memif-1lxc-pdrdisc
 135 | | [Tags] | IMIX | 1C | PDRDISC
 136 | | framesize=IMIX_v4_1 | phy_cores=${1} | search_type=PDR
 137
 138 | tc05-1518B-1t1c-eth-l2xcbase-eth-2memif-1lxc-ndrdisc
 139 | | [Tags] | 1518B | 1C | NDRDISC
 140 | | framesize=${1518} | phy_cores=${1} | search_type=NDR
 141
 142 | tc06-1518B-1t1c-eth-l2xcbase-eth-2memif-1lxc-pdrdisc
 143 | | [Tags] | 1518B | 1C | PDRDISC
 144 | | framesize=${1518} | phy_cores=${1} | search_type=PDR
 145
 146 | tc07-64B-2t2c-eth-l2xcbase-eth-2memif-1lxc-ndrdisc
 147 | | [Tags] | 64B | 2C | NDRDISC
 148 | | framesize=${64} | phy_cores=${2} | search_type=NDR
 149
 150 | tc08-64B-2t2c-eth-l2xcbase-eth-2memif-1lxc-pdrdisc
 151 | | [Tags] | 64B | 2C | PDRDISC
 152 | | framesize=${64} | phy_cores=${2} | search_type=PDR
 153
 154 | tc09-IMIX-2t2c-eth-l2xcbase-eth-2memif-1lxc-ndrdisc
 155 | | [Tags] | IMIX | 2C | NDRDISC
 156 | | framesize=IMIX_v4_1 | phy_cores=${2} | search_type=NDR
 157
 158 | tc10-IMIX-2t2c-eth-l2xcbase-eth-2memif-1lxc-pdrdisc
 159 | | [Tags] | IMIX | 2C | PDRDISC
 160 | | framesize=IMIX_v4_1 | phy_cores=${2} | search_type=PDR
 161
 162 | tc11-1518B-2t2c-eth-l2xcbase-eth-2memif-1lxc-ndrdisc
 163 | | [Tags] | 1518B | 2C | NDRDISC
 164 | | framesize=${1518} | phy_cores=${2} | search_type=NDR
 165
 166 | tc12-1518B-2t2c-eth-l2xcbase-eth-2memif-1lxc-pdrdisc
 167 | | [Tags] | 1518B | 2C | PDRDISC
 168 | | framesize=${1518} | phy_cores=${2} | search_type=PDR