tests/vpp/perf/container_memif/40ge2p1xl710-eth-l2bdbasemaclrn-eth-2memif-1lxc-mrr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | ...
  17 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | MRR
  18 | ... | NIC_Intel-XL710 | ETH | L2BDMACLRN | BASE | MEMIF | LXC
  19 | ...
  20 | Suite Setup | Run Keywords
  21 | ... | Set up 3-node performance topology with DUT's NIC model | L2
  22 | ... | Intel-XL710
  23 | ... | AND | Set up performance test suite with MEMIF
  24 | ... | AND | Set up performance topology with containers
  25 | ...
  26 | Suite Teardown | Tear down 3-node performance topology with container
  27 | ...
  28 | Test Setup | Run Keywords
  29 | ... | Set up performance test
  30 | ... | AND | Restart VPP in all 'VNF' containers
  31 | ...
  32 | Test Teardown | Tear down performance mrr test
  33 | ...
  34 | Test Template | Local template
  35 | ...
  36 | Documentation | *Raw results L2BD test cases*
  37 | ...
  38 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  39 | ... | with single links between nodes.
  40 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 bridge domain.
  41 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with two L2
  42 | ... | bridge domains and MAC learning enabled. LXC is connected to VPP via
  43 | ... | Memif interface. LXC is running same VPP version as running on DUT. LXC
  44 | ... | is limited via cgroup to use 3 cores allocated from pool of isolated
  45 | ... | CPUs. There are no memory constraints. DUT1 and DUT2 tested with
  46 | ... | 2p40GE NIC XL710 by Intel.
  47 | ... | *[Ver] TG verification:* In MaxReceivedRate test TG sends traffic
  48 | ... | at line rate and reports total received/sent packets over trial period.
  49 | ... | Test packets are generated by TG on links to DUTs. TG traffic profile
  50 | ... | contains two L3 flow-groups (flow-group per direction, 254 flows per
  51 | ... | flow-group) with all packets containing Ethernet header, IPv4 header
  52 | ... | with IP protocol=61 and static payload. MAC addresses are matching MAC
  53 | ... | addresses of the TG node interfaces.
  54
  55 *** Variables ***
  56 # XL710-DA2 bandwidth limit ~49Gbps/2=24.5Gbps
  57 | ${s_24.5G} | ${24500000000}
  58 # XL710-DA2 Mpps limit 37.5Mpps/2=18.75Mpps
  59 | ${s_18.75Mpps} | ${18750000}
  60 # Traffic profile:
  61 | ${traffic_profile} | trex-sl-3n-ethip4-ip4src254
  62 # LXC container
  63 | ${container_count}= | ${1}
  64 | ${container_engine}= | LXC
  65 | ${container_image}= | ${EMPTY}
  66 | ${container_install_dkms}= | ${FALSE}
  67 | ${container_chain_topology}= | chain
  68 # CPU settings
  69 | ${system_cpus}= | ${1}
  70 | ${vpp_cpus}= | ${5}
  71 | ${container_cpus}= | ${5}
  72
  73 *** Keywords ***
  74 | Local template
  75 | | [Documentation]
  76 | | ... | [Cfg] DUT runs L2BD switching config.
  77 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  78 | | ... | [Ver] Measure MaxReceivedRate for ${framesize}B frames using single\
  79 | | ... | trial throughput test.
  80 | | ...
  81 | | ... | *Arguments:*
  82 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  83 | | ... | Type: integer, string
  84 | | ... | - phy_cores - Number of physical cores. Type: integer
  85 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  86 | | ...
  87 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  88 | | ...
  89 | | Set Test Variable | ${framesize}
  90 | | ${get_framesize}= | Get Frame Size | ${framesize}
  91 | | ${max_rate}= | Calculate pps | ${s_24.5G} | ${get_framesize}
  92 | | ${max_rate}= | Set Variable If
  93 | | ... | ${max_rate} > ${s_18.75Mpps} | ${s_18.75Mpps} | ${max_rate}
  94 | | ...
  95 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  96 | | And Add PCI devices to all DUTs
  97 | | And Run Keyword If | ${get_framesize} < ${1522}
  98 | | ... | Add no multi seg to all DUTs
  99 | | And Apply startup configuration on all VPP DUTs
 100 | | And Initialize L2 Bridge Domain for '1' memif pairs in 3-node circular topology
 101 | | Then Traffic should pass with maximum rate
 102 | | ... | ${max_rate}pps | ${framesize} | ${traffic_profile}
 103
 104 *** Test Cases ***
 105 | tc01-64B-1t1c-eth-l2bdbasemaclrn-eth-2memif-1lxc-mrr
 106 | | [Tags] | 64B | 1C
 107 | | framesize=${64} | phy_cores=${1}
 108
 109 | tc02-1518B-1t1c-eth-l2bdbasemaclrn-eth-2memif-1lxc-mrr
 110 | | [Tags] | 1518B | 1C
 111 | | framesize=${1518} | phy_cores=${1}
 112
 113 | tc03-9000B-1t1c-eth-l2bdbasemaclrn-eth-2memif-1lxc-mrr
 114 | | [Tags] | 9000B | 1C
 115 | | framesize=${9000} | phy_cores=${1}
 116
 117 | tc04-IMIX-1t1c-eth-l2bdbasemaclrn-eth-2memif-1lxc-mrr
 118 | | [Tags] | IMIX | 1C
 119 | | framesize=IMIX_v4_1 | phy_cores=${1}
 120
 121 | tc05-64B-2t2c-eth-l2bdbasemaclrn-eth-2memif-1lxc-mrr
 122 | | [Tags] | 64B | 2C
 123 | | framesize=${64} | phy_cores=${2}
 124
 125 | tc06-1518B-2t2c-eth-l2bdbasemaclrn-eth-2memif-1lxc-mrr
 126 | | [Tags] | 1518B | 2C
 127 | | framesize=${1518} | phy_cores=${2}
 128
 129 | tc07-9000B-2t2c-eth-l2bdbasemaclrn-eth-2memif-1lxc-mrr
 130 | | [Tags] | 9000B | 2C
 131 | | framesize=${9000} | phy_cores=${2}
 132
 133 | tc08-IMIX-2t2c-eth-l2bdbasemaclrn-eth-2memif-1lxc-mrr
 134 | | [Tags] | IMIX | 2C
 135 | | framesize=IMIX_v4_1 | phy_cores=${2}
 136
 137 | tc09-64B-4t4c-eth-l2bdbasemaclrn-eth-2memif-1lxc-mrr
 138 | | [Tags] | 64B | 4C
 139 | | framesize=${64} | phy_cores=${4}
 140
 141 | tc10-1518B-4t4c-eth-l2bdbasemaclrn-eth-2memif-1lxc-mrr
 142 | | [Tags] | 1518B | 4C
 143 | | framesize=${1518} | phy_cores=${4}
 144
 145 | tc11-9000B-4t4c-eth-l2bdbasemaclrn-eth-2memif-1lxc-mrr
 146 | | [Tags] | 9000B | 4C
 147 | | framesize=${9000} | phy_cores=${4}
 148
 149 | tc12-IMIX-4t4c-eth-l2bdbasemaclrn-eth-2memif-1lxc-mrr
 150 | | [Tags] | IMIX | 4C
 151 | | framesize=IMIX_v4_1 | phy_cores=${4}