tests/vpp/perf/crypto/2n1l-10ge2p1x710-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes128gcm-udir-reconf.robot

   1 # Copyright (c) 2024 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 |
  17 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | UDIR | PERFTEST | HW_ENV | RECONF
  18 | ... | IP4FWD | IPSEC | IPSECSW | IPSECINT | NIC_Intel-X710 | SCALE | TNL_40
  19 | ... | AES_128_GCM | AES | 1_ADDED_TUNNEL | DRV_VFIO_PCI
  20 | ... | RXQ_SIZE_0 | TXQ_SIZE_0
  21 | ... | ethip4ipsec40tnlsw-1atnl-ip4base-int-aes128gcm-udir
  22 |
  23 | Suite Setup | Setup suite topology interfaces | performance
  24 | Suite Teardown | Tear down suite | performance
  25 | Test Setup | Setup test | performance
  26 | Test Teardown | Tear down test | performance | ipsec_sa
  27 |
  28 | Test Template | Local Template
  29 |
  30 | Documentation | **RFC2544: Packet loss IPv4 IPsec tunnel mode.**
  31 | ... |
  32 | ... | - **[Top] Network Topologies:** TG-DUT1-TG 2-node circular topology \
  33 | ... | with single links between nodes.
  34 | ... |
  35 | ... | - **[Enc] Packet Encapsulations:** Eth-IPv4 on TG-DUT1, \
  36 | ... | Eth-IPv4-IPSec on DUT1-TG.
  37 | ... |
  38 | ... | - **[Cfg] DUT configuration:** DUT1 is configured with multiple IPsec \
  39 | ... | tunnels between it and TG. DUT gets IPv4 traffic from TG, encrypts it \
  40 | ... | and sends back to TG.
  41 | ... |
  42 | ... | - **[Ver] TG verification:** TG finds throughput NDR (Non Drop Rate) \
  43 | ... | with zero packet loss tolerance, then measures loss at this load \
  44 | ... | while additional tunnels are configured. \
  45 | ... | Test packets are generated by TG on \
  46 | ... | links to DUTs. TG traffic profile contains one L3 flow-groups \
  47 | ... | (flow-group per direction, number of flows per flow-group equals to \
  48 | ... | number of IPSec tunnels) with all packets \
  49 | ... | containing Ethernet header, IPv4 header with IP protocol=61 and \
  50 | ... | static payload. MAC addresses are matching MAC addresses of the TG \
  51 | ... | node interfaces. Incrementing of IP.dst (IPv4 destination address) \
  52 | ... | field is applied to the stream.
  53 | ... |
  54 | ... | - **[Ref] Applicable standard specifications:** RFC4303 and RFC2544.
  55
  56 *** Variables ***
  57 | @{plugins_to_enable}= | dpdk_plugin.so | perfmon_plugin.so
  58 | ... | crypto_native_plugin.so
  59 | ... | crypto_ipsecmb_plugin.so | crypto_openssl_plugin.so
  60 | ${crypto_type}= | ${None}
  61 | ${nic_name}= | Intel-X710
  62 | ${nic_driver}= | vfio-pci
  63 | ${nic_rxq_size}= | 0
  64 | ${nic_txq_size}= | 0
  65 | ${nic_pfs}= | 2
  66 | ${nic_vfs}= | 0
  67 | ${osi_layer}= | L3
  68 | ${overhead}= | ${54}
  69 | ${tg_if1_ip4}= | 192.168.10.2
  70 | ${dut1_if1_ip4}= | 192.168.10.1
  71 | ${tun_if1_ip4}= | 100.0.0.1
  72 | ${tun_if2_ip4}= | 200.0.0.2
  73 | ${raddr_ip4}= | 20.0.0.0
  74 | ${laddr_ip4}= | 10.0.0.0
  75 | ${addr_range}= | ${24}
  76 | ${n_tunnels}= | ${40}
  77 | ${n_added_tunnels}= | ${1}
  78 # Traffic profile:
  79 | ${traffic_profile}= | trex-stl-ethip4-ip4dst${n_tunnels}-udir
  80 | ${traffic_directions}= | ${1}
  81
  82 *** Keywords ***
  83 | Local Template
  84 | | [Documentation]
  85 | | ... | - **[Cfg]** DUT runs IPSec tunneling AES_128_GCM config. \
  86 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  87 | | ... | - **[Ver]** Measure packet loss during reconfig at NDR load.
  88 | |
  89 | | ... | *Arguments:*
  90 | | ... | - frame_size - Framesize in Bytes in integer or string (IMIX_v4_1).
  91 | | ... | Type: integer, string
  92 | | ... | - phy_cores - Number of physical cores. Type: integer
  93 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  94 | |
  95 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  96 | |
  97 | | Set Test Variable | \${frame_size}
  98 | |
  99 | | # These are enums (not strings) so they cannot be in Variables table.
 100 | | ${encr_alg}= | Crypto Alg AES GCM 128
 101 | | ${auth_alg}= | Set Variable | ${NONE}
 102 | | ${ipsec_proto} = | IPsec Proto ESP
 103 | |
 104 | | ${n_total_tunnels} = | Evaluate | ${n_tunnels} + ${n_added_tunnels}
 105 | | Given Set Max Rate And Jumbo
 106 | | And Add worker threads to all DUTs | ${phy_cores} | ${rxq}
 107 | | And Pre-initialize layer driver | ${nic_driver}
 108 | | And Apply startup configuration on all VPP DUTs
 109 | | When Initialize layer driver | ${nic_driver}
 110 | | And Initialize layer interface
 111 | | And Initialize IPSec in 2-node circular topology
 112 | | And VPP IPsec Create Tunnel Interfaces
 113 | | ... | ${nodes} | ${tun_if1_ip4} | ${tun_if2_ip4} | ${DUT1_${int}2}[0]
 114 | | ... | ${TG_pf2}[0] | ${n_tunnels} | ${encr_alg} | ${auth_alg}
 115 | | ... | ${laddr_ip4} | ${raddr_ip4} | ${addr_range}
 116 | | ${unidirectional_throughput} = | Find Throughput Using MLRsearch
 117 | | Start Traffic on Background | ${unidirectional_throughput}
 118 | | And VPP IPsec Create Tunnel Interfaces
 119 | | ... | ${nodes} | ${tun_if1_ip4} | ${tun_if2_ip4} | ${DUT1_${int}2}[0]
 120 | | ... | ${TG_pf2}[0] | ${n_total_tunnels} | ${encr_alg} | ${auth_alg}
 121 | | ... | ${laddr_ip4} | ${raddr_ip4} | ${addr_range} | ${n_tunnels}
 122 | | ${result}= | Stop Running Traffic
 123 | | Display Reconfig Test Message | ${result}
 124
 125 *** Test Cases ***
 126 | 64B-1c-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes128gcm-udir-reconf
 127 | | [Tags] | 64B | 1C
 128 | | frame_size=${64} | phy_cores=${1}
 129
 130 | 64B-2c-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes128gcm-udir-reconf
 131 | | [Tags] | 64B | 2C
 132 | | frame_size=${64} | phy_cores=${2}
 133
 134 | 64B-4c-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes128gcm-udir-reconf
 135 | | [Tags] | 64B | 4C
 136 | | frame_size=${64} | phy_cores=${4}
 137
 138 | 1518B-1c-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes128gcm-udir-reconf
 139 | | [Tags] | 1518B | 1C
 140 | | frame_size=${1518} | phy_cores=${1}
 141
 142 | 1518B-2c-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes128gcm-udir-reconf
 143 | | [Tags] | 1518B | 2C
 144 | | frame_size=${1518} | phy_cores=${2}
 145
 146 | 1518B-4c-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes128gcm-udir-reconf
 147 | | [Tags] | 1518B | 4C
 148 | | frame_size=${1518} | phy_cores=${4}
 149
 150 | 9000B-1c-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes128gcm-udir-reconf
 151 | | [Tags] | 9000B | 1C
 152 | | frame_size=${9000} | phy_cores=${1}
 153
 154 | 9000B-2c-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes128gcm-udir-reconf
 155 | | [Tags] | 9000B | 2C
 156 | | frame_size=${9000} | phy_cores=${2}
 157
 158 | 9000B-4c-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes128gcm-udir-reconf
 159 | | [Tags] | 9000B | 4C
 160 | | frame_size=${9000} | phy_cores=${4}
 161
 162 | IMIX-1c-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes128gcm-udir-reconf
 163 | | [Tags] | IMIX | 1C
 164 | | frame_size=IMIX_v4_1 | phy_cores=${1}
 165
 166 | IMIX-2c-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes128gcm-udir-reconf
 167 | | [Tags] | IMIX | 2C
 168 | | frame_size=IMIX_v4_1 | phy_cores=${2}
 169
 170 | IMIX-4c-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes128gcm-udir-reconf
 171 | | [Tags] | IMIX | 4C
 172 | | frame_size=IMIX_v4_1 | phy_cores=${4}