tests/vpp/perf/hoststack/2n1l-10ge2p1x710-eth-ip4tcphttp-wrk8u8c50con-cps.robot

   1 # Copyright (c) 2020 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15
  16 | Library  | resources.tools.wrk.wrk
  17 | Resource | resources/libraries/robot/wrk/wrk_utils.robot
  18 | Resource | resources/libraries/robot/shared/default.robot
  19 | Resource | resources/libraries/robot/hoststack/tcp_setup.robot
  20 |
  21 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV
  22 | ... | HTTP | TCP | TCP_CPS | NIC_Intel-X710 | DRV_VFIO_PCI
  23 | ... | RXQ_SIZE_0 | TXQ_SIZE_0 | IMIX
  24 | ... | eth-ip4tcphttp-wrk8u8c50con
  25 |
  26 | Suite Setup | Setup suite single link | wrk
  27 | Suite Teardown | Tear down suite | wrk
  28 | Test Setup | Setup test
  29 | Test Teardown | Tear down test
  30 |
  31 | Test Template | Local template
  32 |
  33 | Documentation | *HTTP connections per seconds.*
  34 |
  35 | ... | *[Top] Network Topologies:* TG-DUT-TG 2-node topology
  36 | ... | with single link between nodes.
  37 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4-TCP-HTTP for TCP Host Stack
  38 | ... | *[Cfg] DUT configuration:*
  39 | ... | *[Ver] TG verification:*
  40 | ... | *[Ref] Applicable standard specifications:*
  41
  42 *** Variables ***
  43 | @{plugins_to_enable}= | dpdk_plugin.so | http_static_plugin.so
  44 | ... | hs_apps_plugin.so
  45 | ${crypto_type}= | ${None}
  46 | ${nic_name}= | Intel-X710
  47 | ${nic_driver}= | vfio-pci
  48 | ${nic_rxq_size}= | 0
  49 | ${nic_txq_size}= | 0
  50 | ${overhead}= | ${0}
  51 | ${frame_size}= | IMIX_v4_1
  52 | ${traffic_profile}= | wrk-sf-2n-ethip4tcphttp-8u8c50con-cps
  53 | ${http_static_plugin}= | ${false}
  54
  55 *** Keywords ***
  56 | Local template
  57 | | [Arguments] | ${phy_cores} | ${rxq}=${None}
  58 | |
  59 | | Given Set Max Rate And Jumbo
  60 | | And Add worker threads to all DUTs | ${phy_cores} | ${rxq}
  61 | | And Pre-initialize layer driver | ${nic_driver}
  62 | | FOR | ${dut} | IN | @{duts}
  63 | | | Import Library | resources.libraries.python.VppConfigGenerator
  64 | | | ... | WITH NAME | ${dut}
  65 | | | Run keyword | ${dut}.Add api segment global size | 2G
  66 | | | Run keyword | ${dut}.Add api segment api size | 1G
  67 | | | Run keyword | ${dut}.Add TCP preallocated connections | 1000000
  68 | | | Run keyword | ${dut}.Add TCP preallocated half open connections | 1000000
  69 | | | Run keyword | ${dut}.Add session event queue length | 1000000
  70 | | | Run keyword | ${dut}.Add session preallocated sessions | 1000000
  71 | | | Run keyword | ${dut}.Add session v4 session table buckets | 500000
  72 | | | Run keyword | ${dut}.Add session v4 session table memory | 1g
  73 | | | Run keyword | ${dut}.Add session v4 halfopen table buckets | 2500000
  74 | | | Run keyword | ${dut}.Add session v4 halfopen table memory | 3g
  75 | | | Run keyword | ${dut}.Add session local endpoints table buckets | 2500000
  76 | | | Run keyword | ${dut}.Add session local endpoints table memory | 3g
  77 | | END
  78 | | And Apply startup configuration on all VPP DUTs
  79 | | When Initialize layer driver | ${nic_driver}
  80 | | And Initialize layer interface
  81 | | And Set up HTTP server with parameters on the VPP node
  82 | | ... | ${http_static_plugin} | 31000 | 64 | 4000m
  83 | | Then Measure connections per second | ${traffic_profile}
  84
  85 *** Test Cases ***
  86 | tc01-IMIX-1c-eth-ip4tcphttp-wrk8u8c50con-cps
  87 | | [Tags] | 1C
  88 | | phy_cores=${1}
  89
  90 | tc02-IMIX-2c-eth-ip4tcphttp-wrk8u8c50con-cps
  91 | | [Tags] | 2C
  92 | | phy_cores=${2}
  93
  94 | tc03-IMIX-4c-eth-ip4tcphttp-wrk8u8c50con-cps
  95 | | [Tags] | 4C
  96 | | phy_cores=${4}