tests/vpp/perf/ip4/10ge2p1x710-ethip4-ip4base-iacldstbase-ndrpdr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | ...
  17 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  18 | ... | NIC_Intel-X710 | ETH | IP4FWD | FEATURE | IACLDST
  19 | ...
  20 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  21 | ... | L3 | Intel-X710
  22 | Suite Teardown | Tear down 3-node performance topology
  23 | ...
  24 | Test Setup | Set up performance test
  25 | ...
  26 | Test Teardown | Tear down performance discovery test | ${min_rate}pps
  27 | ... | ${framesize} | ${traffic_profile}
  28 | ...
  29 | Test Template | Local Template
  30 | ...
  31 | Documentation | *RFC2544: Pkt throughput IPv4 iAcl whitelist test cases*
  32 | ...
  33 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  34 | ... | with single links between nodes.
  35 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for IPv4 routing.
  36 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with IPv4
  37 | ... | routing, two static IPv4 /24 routes and IPv4 iAcl security whitelist
  38 | ... | ingress /24 filter entries applied on links TG - DUT1 and DUT2 - TG.
  39 | ... | DUT1 and DUT2 tested with 2p10GE NIC X710 by Intel.
  40 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop
  41 | ... | Rate) with zero packet loss tolerance or throughput PDR (Partial Drop
  42 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage
  43 | ... | of packets transmitted. NDR and PDR are discovered for different
  44 | ... | Ethernet L2 frame sizes using MLRsearch library.
  45 | ... | Test packets are generated by TG on links to DUTs. TG traffic profile
  46 | ... | contains two L3 flow-groups (flow-group per direction, 253 flows per
  47 | ... | flow-group) with all packets containing Ethernet header, IPv6 header
  48 | ... | and generated payload. MAC addresses are matching MAC addresses
  49 | ... | of the TG node interfaces.
  50 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  51
  52 *** Variables ***
  53 # X710 bandwidth limit
  54 | ${s_limit}= | ${10000000000}
  55 # Traffic profile:
  56 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4src253
  57
  58 *** Keywords ***
  59 | Local Template
  60 | | ...
  61 | | [Documentation]
  62 | | ... | [Cfg] DUT runs IPv4 routing config.
  63 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  64 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  65 | | ...
  66 | | ... | *Arguments:*
  67 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  68 | | ... | Type: integer, string
  69 | | ... | - phy_cores - Number of physical cores. Type: integer
  70 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  71 | | ...
  72 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  73 | | ...
  74 | | Set Test Variable | ${framesize}
  75 | | Set Test Variable | ${min_rate} | ${10000}
  76 | | ...
  77 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  78 | | And Add PCI devices to all DUTs
  79 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
  80 | | ... | ${s_limit} | ${framesize}
  81 | | And Apply startup configuration on all VPP DUTs
  82 | | When Initialize IPv4 forwarding in 3-node circular topology
  83 | | ${table_idx} | ${skip_n} | ${match_n}= | And Vpp Creates Classify Table L3
  84 | | ... | ${dut1} | ip4 | dst
  85 | | And Vpp Configures Classify Session L3
  86 | | ... | ${dut1} | permit | ${table_idx} | ${skip_n} | ${match_n}
  87 | | ... | ip4 | dst | 20.20.20.2
  88 | | And Vpp Enable Input Acl Interface
  89 | | ... | ${dut1} | ${dut1_if1} | ip4 | ${table_idx}
  90 | | ${table_idx} | ${skip_n} | ${match_n}= | And Vpp Creates Classify Table L3
  91 | | ... | ${dut2} | ip4 | dst
  92 | | And Vpp Configures Classify Session L3
  93 | | ... | ${dut2} | permit | ${table_idx} | ${skip_n} | ${match_n}
  94 | | ... | ip4 | dst | 10.10.10.2
  95 | | And Vpp Enable Input Acl Interface
  96 | | ... | ${dut2} | ${dut2_if2} | ip4 | ${table_idx}
  97 | | Then Find NDR and PDR intervals using optimized search
  98 | | ... | ${framesize} | ${traffic_profile} | ${min_rate} | ${max_rate}
  99
 100 *** Test Cases ***
 101 | tc01-64B-1c-ethip4-ip4base-iacldstbase-ndrpdr
 102 | | [Tags] | 64B | 1C
 103 | | framesize=${64} | phy_cores=${1}
 104
 105 | tc02-64B-2c-ethip4-ip4base-iacldstbase-ndrpdr
 106 | | [Tags] | 64B | 2C
 107 | | framesize=${64} | phy_cores=${2}
 108
 109 | tc03-64B-4c-ethip4-ip4base-iacldstbase-ndrpdr
 110 | | [Tags] | 64B | 4C
 111 | | framesize=${64} | phy_cores=${4}
 112
 113 | tc04-1518B-1c-ethip4-ip4base-iacldstbase-ndrpdr
 114 | | [Tags] | 1518B | 1C
 115 | | framesize=${1518} | phy_cores=${1}
 116
 117 | tc05-1518B-2c-ethip4-ip4base-iacldstbase-ndrpdr
 118 | | [Tags] | 1518B | 2C
 119 | | framesize=${1518} | phy_cores=${2}
 120
 121 | tc06-1518B-4c-ethip4-ip4base-iacldstbase-ndrpdr
 122 | | [Tags] | 1518B | 4C
 123 | | framesize=${1518} | phy_cores=${4}
 124
 125 | tc07-9000B-1c-ethip4-ip4base-iacldstbase-ndrpdr
 126 | | [Tags] | 9000B | 1C
 127 | | framesize=${9000} | phy_cores=${1}
 128
 129 | tc08-9000B-2c-ethip4-ip4base-iacldstbase-ndrpdr
 130 | | [Tags] | 9000B | 2C
 131 | | framesize=${9000} | phy_cores=${2}
 132
 133 | tc09-9000B-4c-ethip4-ip4base-iacldstbase-ndrpdr
 134 | | [Tags] | 9000B | 4C
 135 | | framesize=${9000} | phy_cores=${4}
 136
 137 | tc10-IMIX-1c-ethip4-ip4base-iacldstbase-ndrpdr
 138 | | [Tags] | IMIX | 1C
 139 | | framesize=IMIX_v4_1 | phy_cores=${1}
 140
 141 | tc11-IMIX-2c-ethip4-ip4base-iacldstbase-ndrpdr
 142 | | [Tags] | IMIX | 2C
 143 | | framesize=IMIX_v4_1 | phy_cores=${2}
 144
 145 | tc12-IMIX-4c-ethip4-ip4base-iacldstbase-ndrpdr
 146 | | [Tags] | IMIX | 4C
 147 | | framesize=IMIX_v4_1 | phy_cores=${4}