tests/vpp/perf/ip6/2n1l-10ge2p1x710-dot1q-ip6base-ndrpdr.robot

   1 # Copyright (c) 2021 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 |
  17 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  18 | ... | NIC_Intel-X710 | ETH | IP6FWD | BASE | DOT1Q | IP6BASE | DRV_VFIO_PCI
  19 | ... | RXQ_SIZE_0 | TXQ_SIZE_0
  20 | ... | dot1q-ip6base
  21 |
  22 | Suite Setup | Setup suite topology interfaces | performance
  23 | Suite Teardown | Tear down suite | performance
  24 | Test Setup | Setup test | performance
  25 | Test Teardown | Tear down test | performance
  26 |
  27 | Test Template | Local Template
  28 |
  29 | Documentation | **RFC2544: Pkt throughput IPv6 routing with IEEE 802.1Q test \
  30 | ... | cases**
  31 | ... |
  32 | ... | - **[Top] Network Topologies:** TG-DUT1-TG 2-node circular topology \
  33 | ... | with single links between nodes.
  34 | ... |
  35 | ... | - **[Enc] Packet Encapsulations:** Eth-IPv6 for IPv6 routing. \
  36 | ... | IEEE 802.1Q tagging is applied on link between DUT1-if2 and TG-if2.
  37 | ... |
  38 | ... | - **[Cfg] DUT configuration:** DUT1 is configured with IPv6 routing \
  39 | ... | two static IPv6 /64 route entries. DUT1 is tested with ${nic_name}.
  40 | ... |
  41 | ... | - **[Ver] TG verification:** TG finds and reports throughput NDR (Non \
  42 | ... | Drop Rate) with zero packet loss tolerance and throughput PDR \
  43 | ... | (Partial Drop Rate) with non-zero packet loss tolerance (LT) \
  44 | ... | expressed in percentage of packets transmitted. NDR and PDR are \
  45 | ... | discovered for different Ethernet L2 frame sizes using MLRsearch \
  46 | ... | library.
  47 | ... | Test packets are \
  48 | ... | generated by TG on links to DUT1. TG traffic profile contains two L3 \
  49 | ... | flow-groups (flow-group per direction, 253 flows per flow-group) with \
  50 | ... | all packets containing Ethernet header, IPv6 header with IP \
  51 | ... | protocol=61 and static payload. MAC addresses are matching MAC \
  52 | ... | addresses of the TG node interfaces.
  53 | ... |
  54 | ... | - **[Ref] Applicable standard specifications:** RFC2544.
  55
  56 *** Variables ***
  57 | @{plugins_to_enable}= | dpdk_plugin.so | perfmon_plugin.so
  58 | ${crypto_type}= | ${None}
  59 | ${nic_name}= | Intel-X710
  60 | ${nic_driver}= | vfio-pci
  61 | ${nic_rxq_size}= | 0
  62 | ${nic_txq_size}= | 0
  63 | ${nic_pfs}= | 2
  64 | ${nic_vfs}= | 0
  65 | ${osi_layer}= | L3
  66 | ${overhead}= | ${4}
  67 | ${subid}= | 10
  68 | ${tag_rewrite}= | pop-1
  69 # TG subnets used by T-Rex
  70 | ${tg_if1_net}= | 2001:1::0
  71 | ${tg_if2_net}= | 2001:2::0
  72 # Traffic profile:
  73 | ${traffic_profile}= | trex-stl-2n-dot1qip6asym-ip6src253
  74
  75 *** Keywords ***
  76 | Local Template
  77 | | [Documentation]
  78 | | ... | - **[Cfg]** Each DUT runs IPv6 routing with VLAN and uses \
  79 | | ... | ${phy_cores} physical core(s) for worker threads.
  80 | | ... | - **[Ver]** Measure NDR and PDR values using MLRsearch algorithm.
  81 | |
  82 | | ... | *Arguments:*
  83 | | ... | - frame_size - Framesize in Bytes in integer or string (IMIX_v4_1).
  84 | | ... | Type: integer, string
  85 | | ... | - phy_cores - Number of physical cores. Type: integer
  86 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  87 | |
  88 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  89 | |
  90 | | Set Test Variable | \${frame_size}
  91 | |
  92 | | Given Set Max Rate And Jumbo
  93 | | And Add worker threads to all DUTs | ${phy_cores} | ${rxq}
  94 | | And Pre-initialize layer driver | ${nic_driver}
  95 | | And Apply startup configuration on all VPP DUTs
  96 | | When Initialize layer driver | ${nic_driver}
  97 | | And Initialize layer interface
  98 | | When Initialize IPv6 forwarding with VLAN dot1q sub-interfaces in circular topology
  99 | | ... | ${tg_if1_net} | ${tg_if2_net} | ${subid} | ${tag_rewrite}
 100 | | Then Find NDR and PDR intervals using optimized search
 101
 102 *** Test Cases ***
 103 | 78B-1c-dot1q-ip6base-ndrpdr
 104 | | [Tags] | 78B | 1C
 105 | | frame_size=${78} | phy_cores=${1}
 106
 107 | 78B-2c-dot1q-ip6base-ndrpdr
 108 | | [Tags] | 78B | 2C
 109 | | frame_size=${78} | phy_cores=${2}
 110
 111 | 78B-4c-dot1q-ip6base-ndrpdr
 112 | | [Tags] | 78B | 4C
 113 | | frame_size=${78} | phy_cores=${4}
 114
 115 | 1518B-1c-dot1q-ip6base-ndrpdr
 116 | | [Tags] | 1518B | 1C
 117 | | frame_size=${1518} | phy_cores=${1}
 118
 119 | 1518B-2c-dot1q-ip6base-ndrpdr
 120 | | [Tags] | 1518B | 2C
 121 | | frame_size=${1518} | phy_cores=${2}
 122
 123 | 1518B-4c-dot1q-ip6base-ndrpdr
 124 | | [Tags] | 1518B | 4C
 125 | | frame_size=${1518} | phy_cores=${4}
 126
 127 | 9000B-1c-dot1q-ip6base-ndrpdr
 128 | | [Tags] | 9000B | 1C
 129 | | frame_size=${9000} | phy_cores=${1}
 130
 131 | 9000B-2c-dot1q-ip6base-ndrpdr
 132 | | [Tags] | 9000B | 2C
 133 | | frame_size=${9000} | phy_cores=${2}
 134
 135 | 9000B-4c-dot1q-ip6base-ndrpdr
 136 | | [Tags] | 9000B | 4C
 137 | | frame_size=${9000} | phy_cores=${4}
 138
 139 | IMIX-1c-dot1q-ip6base-ndrpdr
 140 | | [Tags] | IMIX | 1C
 141 | | frame_size=IMIX_v4_1 | phy_cores=${1}
 142
 143 | IMIX-2c-dot1q-ip6base-ndrpdr
 144 | | [Tags] | IMIX | 2C
 145 | | frame_size=IMIX_v4_1 | phy_cores=${2}
 146
 147 | IMIX-4c-dot1q-ip6base-ndrpdr
 148 | | [Tags] | IMIX | 4C
 149 | | frame_size=IMIX_v4_1 | phy_cores=${4}