tests/vpp/perf/l2/10ge2p1x710-dot1ad-l2xcbase-ndrpdr.robot

   1 # Copyright (c) 2021 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 | Resource | resources/libraries/robot/l2/tagging.robot
  17 |
  18 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  19 | ... | NIC_Intel-X710 | L2XCFWD | BASE | DOT1AD | DRV_VFIO_PCI
  20 | ... | RXQ_SIZE_0 | TXQ_SIZE_0
  21 | ... | dot1ad-l2xcbase
  22 |
  23 | Suite Setup | Setup suite topology interfaces | performance
  24 | Suite Teardown | Tear down suite | performance
  25 | Test Setup | Setup test | performance
  26 | Test Teardown | Tear down test | performance
  27 |
  28 | Test Template | Local Template
  29 |
  30 | Documentation | **RFC2544: Pkt throughput L2XC with 802.1ad test cases**
  31 | ... |
  32 | ... | - **[Top] Network Topologies:** TG-DUT1-DUT2-TG 3-node circular \
  33 | ... | topology with single links between nodes.
  34 | ... |
  35 | ... | - **[Enc] Packet Encapsulations:** Eth-IPv4 for L2 xconnect. \
  36 | ... | 802.1ad tagging is applied on link between DUT1 and DUT2 with inner 4B \
  37 | ... | vlan tag (id=100) and outer 4B vlan tag (id=200).
  38 | ... |
  39 | ... | - **[Cfg] DUT configuration:** DUT1 and DUT2 are configured with L2 \
  40 | ... | cross-connect. DUT1 and DUT2 are tested with ${nic_name}.
  41 | ... |
  42 | ... | - **[Ver] TG verification:** TG finds and reports throughput NDR (Non \
  43 | ... | Drop Rate) with zero packet loss tolerance and throughput PDR \
  44 | ... | (Partial Drop Rate) with non-zero packet loss tolerance (LT) \
  45 | ... | expressed in percentage of packets transmitted. NDR and PDR are \
  46 | ... | discovered for different Ethernet L2 frame sizes using MLRsearch \
  47 | ... | library.
  48 | ... | Test packets are generated by TG on \
  49 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups \
  50 | ... | (flow-group per direction, 253 flows per flow-group) with all packets \
  51 | ... | containing Ethernet header, IPv4 header with IP protocol=61 and \
  52 | ... | static payload. MAC addresses are matching MAC addresses of the TG. \
  53 | ... | node interfaces.
  54 | ... |
  55 | ... | - **[Ref] Applicable standard specifications:** RFC2544.
  56
  57 *** Variables ***
  58 | @{plugins_to_enable}= | dpdk_plugin.so | perfmon_plugin.so
  59 | ${crypto_type}= | ${None}
  60 | ${nic_name}= | Intel-X710
  61 | ${nic_driver}= | vfio-pci
  62 | ${nic_rxq_size}= | 0
  63 | ${nic_txq_size}= | 0
  64 | ${nic_pfs}= | 2
  65 | ${nic_vfs}= | 0
  66 | ${osi_layer}= | L2
  67 | ${overhead}= | ${8}
  68 | ${subid}= | 10
  69 | ${outer_vlan_id}= |
  70 | ${inner_vlan_id}= |
  71 | ${type_subif}= | two_tags
  72 | ${tag_rewrite}= | pop-2
  73 # Traffic profile:
  74 | ${traffic_profile}= | trex-stl-3n-ethip4-ip4src254
  75
  76 *** Keywords ***
  77 | Local Template
  78 | | [Documentation]
  79 | | ... | - **[Cfg]** DUT runs L2XC forwarding config. \
  80 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  81 | | ... | - **[Ver]** Measure NDR and PDR values using MLRsearch algorithm.
  82 | |
  83 | | ... | *Arguments:*
  84 | | ... | - frame_size - Framesize in Bytes in integer or string (IMIX_v4_1).
  85 | | ... | Type: integer, string
  86 | | ... | - phy_cores - Number of physical cores. Type: integer
  87 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  88 | |
  89 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  90 | |
  91 | | Set Test Variable | \${frame_size}
  92 | |
  93 | | Given Set Max Rate And Jumbo
  94 | | And Add worker threads to all DUTs | ${phy_cores} | ${rxq}
  95 | | And Pre-initialize layer driver | ${nic_driver}
  96 | | And Apply Startup configuration on all VPP DUTs
  97 | | When Initialize layer driver | ${nic_driver}
  98 | | And Initialize layer interface
  99 | | When Initialize VLAN sub-interfaces in 3-node circular topology
 100 | | ... | ${dut1} | ${DUT1_${int}2}[0] | ${dut2} | ${DUT2_${int}1}[0] | ${subid}
 101 | | ... | ${outer_vlan_id} | ${inner_vlan_id} | ${type_subif}
 102 | | And Configure L2 tag rewrite method on interfaces
 103 | | ... | ${dut1} | ${subif_index_1} | ${dut2} | ${subif_index_2}
 104 | | ... | ${tag_rewrite}
 105 | | And Configure L2XC
 106 | | ... | ${dut1} | ${DUT1_${int}1}[0] | ${subif_index_1}
 107 | | And Configure L2XC
 108 | | ... | ${dut2} | ${DUT2_${int}2}[0] | ${subif_index_2}
 109 | | Then Find NDR and PDR intervals using optimized search
 110
 111 *** Test Cases ***
 112 | 64B-1c-dot1ad-l2xcbase-ndrpdr
 113 | | [Tags] | 64B | 1C
 114 | | frame_size=${64} | phy_cores=${1}
 115
 116 | 64B-2c-dot1ad-l2xcbase-ndrpdr
 117 | | [Tags] | 64B | 2C
 118 | | frame_size=${64} | phy_cores=${2}
 119
 120 | 64B-4c-dot1ad-l2xcbase-ndrpdr
 121 | | [Tags] | 64B | 4C
 122 | | frame_size=${64} | phy_cores=${4}
 123
 124 | 1518B-1c-dot1ad-l2xcbase-ndrpdr
 125 | | [Tags] | 1518B | 1C
 126 | | frame_size=${1518} | phy_cores=${1}
 127
 128 | 1518B-2c-dot1ad-l2xcbase-ndrpdr
 129 | | [Tags] | 1518B | 2C
 130 | | frame_size=${1518} | phy_cores=${2}
 131
 132 | 1518B-4c-dot1ad-l2xcbase-ndrpdr
 133 | | [Tags] | 1518B | 4C
 134 | | frame_size=${1518} | phy_cores=${4}
 135
 136 | 9000B-1c-dot1ad-l2xcbase-ndrpdr
 137 | | [Tags] | 9000B | 1C
 138 | | frame_size=${9000} | phy_cores=${1}
 139
 140 | 9000B-2c-dot1ad-l2xcbase-ndrpdr
 141 | | [Tags] | 9000B | 2C
 142 | | frame_size=${9000} | phy_cores=${2}
 143
 144 | 9000B-4c-dot1ad-l2xcbase-ndrpdr
 145 | | [Tags] | 9000B | 4C
 146 | | frame_size=${9000} | phy_cores=${4}
 147
 148 | IMIX-1c-dot1ad-l2xcbase-ndrpdr
 149 | | [Tags] | IMIX | 1C
 150 | | frame_size=IMIX_v4_1 | phy_cores=${1}
 151
 152 | IMIX-2c-dot1ad-l2xcbase-ndrpdr
 153 | | [Tags] | IMIX | 2C
 154 | | frame_size=IMIX_v4_1 | phy_cores=${2}
 155
 156 | IMIX-4c-dot1ad-l2xcbase-ndrpdr
 157 | | [Tags] | IMIX | 4C
 158 | | frame_size=IMIX_v4_1 | phy_cores=${4}