tests/vpp/perf/l2/10ge2p1x710-dot1ad-l2xcbase-ndrpdr.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 | Resource | resources/libraries/robot/l2/tagging.robot
  17 | ...
  18 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  19 | ... | NIC_Intel-X710 | L2XCFWD | BASE | DOT1AD
  20 | ...
  21 | Suite Setup | Setup suite single link | performance
  22 | Suite Teardown | Tear down suite | performance
  23 | Test Setup | Setup test
  24 | Test Teardown | Tear down test | performance
  25 | ...
  26 | Test Template | Local Template
  27 | ...
  28 | Documentation | *RFC2544: Pkt throughput L2XC with 802.1ad test cases*
  29 | ...
  30 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  31 | ... | with single links between nodes.
  32 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 xconnect.
  33 | ... | 802.1ad tagging is applied on link between DUT1 and DUT2 with inner 4B
  34 | ... | vlan tag (id=100) and outer 4B vlan tag (id=200).
  35 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2 cross-
  36 | ... | connect. DUT1 and DUT2 tested with ${nic_name}.\
  37 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop\
  38 | ... | Rate) with zero packet loss tolerance and throughput PDR (Partial Drop\
  39 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage\
  40 | ... | of packets transmitted. NDR and PDR are discovered for different\
  41 | ... | Ethernet L2 frame sizes using MLRsearch library.\
  42 | ... | Test packets are generated by TG on
  43 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups
  44 | ... | (flow-group per direction, 253 flows per flow-group) with all packets
  45 | ... | containing Ethernet header, IPv4 header with IP protocol=61 and
  46 | ... | static payload. MAC addresses are matching MAC addresses of the TG
  47 | ... | node interfaces.
  48 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  49
  50 *** Variables ***
  51 | @{plugins_to_enable}= | dpdk_plugin.so
  52 | ${osi_layer}= | L2
  53 | ${nic_name}= | Intel-X710
  54 | ${nic_driver}= | vfio-pci
  55 | ${overhead}= | ${8}
  56 | ${subid}= | 10
  57 | ${outer_vlan_id}= | 100
  58 | ${inner_vlan_id}= | 200
  59 | ${type_subif}= | two_tags
  60 | ${tag_rewrite}= | pop-2
  61 # Traffic profile:
  62 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4src254
  63
  64 *** Keywords ***
  65 | Local Template
  66 | | [Documentation]
  67 | | ... | [Cfg] DUT runs L2XC forwarding config.
  68 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  69 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  70 | | ...
  71 | | ... | *Arguments:*
  72 | | ... | - frame_size - Framesize in Bytes in integer or string (IMIX_v4_1).
  73 | | ... | Type: integer, string
  74 | | ... | - phy_cores - Number of physical cores. Type: integer
  75 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  76 | | ...
  77 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  78 | | ...
  79 | | Set Test Variable | \${frame_size}
  80 | | ...
  81 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  82 | | And Add PCI devices to all DUTs
  83 | | And Set Max Rate And Jumbo And Handle Multi Seg
  84 | | And Apply startup configuration on all VPP DUTs
  85 | | When Initialize layer driver | ${nic_driver}
  86 | | And Set interfaces in path up
  87 | | When Initialize VLAN sub-interfaces in 3-node circular topology
  88 | | ... | ${dut1} | ${dut1_if2} | ${dut2} | ${dut2_if1} | ${subid}
  89 | | ... | ${outer_vlan_id} | ${inner_vlan_id} | ${type_subif}
  90 | | And Configure L2 tag rewrite method on interfaces
  91 | | ... | ${dut1} | ${subif_index_1} | ${dut2} | ${subif_index_2}
  92 | | ... | ${tag_rewrite}
  93 | | And Configure L2XC
  94 | | ... | ${dut1} | ${dut1_if1} | ${subif_index_1}
  95 | | And Configure L2XC
  96 | | ... | ${dut2} | ${dut2_if2} | ${subif_index_2}
  97 | | Then Find NDR and PDR intervals using optimized search
  98
  99 *** Test Cases ***
 100 | tc01-64B-1c-dot1ad-l2xcbase-ndrpdr
 101 | | [Tags] | 64B | 1C
 102 | | frame_size=${64} | phy_cores=${1}
 103
 104 | tc02-64B-2c-dot1ad-l2xcbase-ndrpdr
 105 | | [Tags] | 64B | 2C
 106 | | frame_size=${64} | phy_cores=${2}
 107
 108 | tc03-64B-4c-dot1ad-l2xcbase-ndrpdr
 109 | | [Tags] | 64B | 4C
 110 | | frame_size=${64} | phy_cores=${4}
 111
 112 | tc04-1518B-1c-dot1ad-l2xcbase-ndrpdr
 113 | | [Tags] | 1518B | 1C
 114 | | frame_size=${1518} | phy_cores=${1}
 115
 116 | tc05-1518B-2c-dot1ad-l2xcbase-ndrpdr
 117 | | [Tags] | 1518B | 2C
 118 | | frame_size=${1518} | phy_cores=${2}
 119
 120 | tc06-1518B-4c-dot1ad-l2xcbase-ndrpdr
 121 | | [Tags] | 1518B | 4C
 122 | | frame_size=${1518} | phy_cores=${4}
 123
 124 | tc07-9000B-1c-dot1ad-l2xcbase-ndrpdr
 125 | | [Tags] | 9000B | 1C
 126 | | frame_size=${9000} | phy_cores=${1}
 127
 128 | tc08-9000B-2c-dot1ad-l2xcbase-ndrpdr
 129 | | [Tags] | 9000B | 2C
 130 | | frame_size=${9000} | phy_cores=${2}
 131
 132 | tc09-9000B-4c-dot1ad-l2xcbase-ndrpdr
 133 | | [Tags] | 9000B | 4C
 134 | | frame_size=${9000} | phy_cores=${4}
 135
 136 | tc10-IMIX-1c-dot1ad-l2xcbase-ndrpdr
 137 | | [Tags] | IMIX | 1C
 138 | | frame_size=IMIX_v4_1 | phy_cores=${1}
 139
 140 | tc11-IMIX-2c-dot1ad-l2xcbase-ndrpdr
 141 | | [Tags] | IMIX | 2C
 142 | | frame_size=IMIX_v4_1 | phy_cores=${2}
 143
 144 | tc12-IMIX-4c-dot1ad-l2xcbase-ndrpdr
 145 | | [Tags] | IMIX | 4C
 146 | | frame_size=IMIX_v4_1 | phy_cores=${4}