tests/vpp/perf/l2/2n1l-25ge2p1xxv710-dot1q-l2xcbase-mrr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Resource | resources/libraries/robot/l2/tagging.robot
  17 | ...
  18 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | MRR
  19 | ... | NIC_Intel-XXV710 | L2XCFWD | BASE | DOT1Q
  20 | ...
  21 | Suite Setup | Set up 2-node performance topology with DUT's NIC model
  22 | ... | L2 | Intel-XXV710
  23 | ...
  24 | Suite Teardown | Tear down 2-node performance topology
  25 | ...
  26 | Test Setup | Set up performance test
  27 | ...
  28 | Test Teardown | Tear down performance mrr test
  29 | ...
  30 | Test Template | Local Template
  31 | ...
  32 | Documentation | *Raw results L2XC with IEEE 802.1Q test cases*
  33 | ...
  34 | ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology with\
  35 | ... | single links between nodes.
  36 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 cross connect. IEEE\
  37 | ... | 802.1Q tagging is applied on link between DUT1-if2 and TG-if2.
  38 | ... | *[Cfg] DUT configuration:* DUT1 is configured with L2 cross- connect.\
  39 | ... | DUT1 is tested with 2p25GE NIC XXV710 by Intel.
  40 | ... | *[Ver] TG verification:* In MaxReceivedRate tests TG sends traffic\
  41 | ... | at line rate and reports total received/sent packets over trial period.\
  42 | ... | Test packets are generated by TG on links to DUTs. TG traffic profile\
  43 | ... | contains two L3 flow-groups (flow-group per direction, 254 flows per\
  44 | ... | flow-group) with all packets containing Ethernet header, IPv4 header\
  45 | ... | with IP protocol=61 and static payload. MAC addresses are matching MAC\
  46 | ... | addresses of the TG node interfaces.
  47 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  48
  49 *** Variables ***
  50 | ${subid}= | 10
  51 | ${tag_rewrite}= | pop-1
  52 | ${overhead}= | ${4}
  53 # XXV710-DA2 bandwidth limit ~49Gbps/2=24.5Gbps
  54 | ${s_24.5G}= | ${24500000000}
  55 # XXV710-DA2 Mpps limit 37.5Mpps/2=18.75Mpps
  56 | ${s_18.75Mpps}= | ${18750000}
  57 # Traffic profile:
  58 | ${traffic_profile}= | trex-sl-2n-dot1qip4asym-ip4src254
  59
  60 *** Keywords ***
  61 | Local Template
  62 | | [Documentation]
  63 | | ... | [Cfg] Each DUT runs L2XC config with VLAN and uses ${phy_cores}\
  64 | | ... | physical core(s) for worker threads.
  65 | | ... | [Ver] Measure MaxReceivedRate for ${framesize}B frames using single\
  66 | | ... | trial throughput test.
  67 | | ...
  68 | | ... | *Arguments:*
  69 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  70 | | ... | Type: integer, string
  71 | | ... | - phy_cores - Number of physical cores. Type: integer
  72 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  73 | | ...
  74 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  75 | | ...
  76 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  77 | | And Add PCI devices to all DUTs
  78 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
  79 | | ... | ${s_24.5G} | ${framesize} | pps_limit=${s_18.75Mpps}
  80 | | ... | overhead=${overhead}
  81 | | And Apply startup configuration on all VPP DUTs
  82 | | And Set interfaces in path up
  83 | | When Initialize VLAN dot1q sub-interfaces in circular topology
  84 | | ... | ${dut1} | ${dut1_if2} | SUB_ID=${subid}
  85 | | And Configure L2 tag rewrite method on interfaces
  86 | | ... | ${dut1} | ${subif_index_1} | TAG_REWRITE_METHOD=${tag_rewrite}
  87 | | And Connect interfaces and VLAN sub-interfaces using L2XC
  88 | | ... | ${dut1} | ${dut1_if1} | ${subif_index_1}
  89 | | Then Traffic should pass with maximum rate
  90 | | ... | ${max_rate}pps | ${framesize} | ${traffic_profile}
  91
  92 *** Test Cases ***
  93 | tc01-64B-1c-dot1q-l2xcbase-mrr
  94 | | [Tags] | 64B | 1C
  95 | | framesize=${64} | phy_cores=${1}
  96
  97 | tc02-64B-2c-dot1q-l2xcbase-mrr
  98 | | [Tags] | 64B | 2C
  99 | | framesize=${64} | phy_cores=${2}
 100
 101 | tc03-64B-4c-dot1q-l2xcbase-mrr
 102 | | [Tags] | 64B | 4C
 103 | | framesize=${64} | phy_cores=${4}
 104
 105 | tc04-1518B-1c-dot1q-l2xcbase-mrr
 106 | | [Tags] | 1518B | 1C
 107 | | framesize=${1518} | phy_cores=${1}
 108
 109 | tc05-1518B-2c-dot1q-l2xcbase-mrr
 110 | | [Tags] | 1518B | 2C
 111 | | framesize=${1518} | phy_cores=${2}
 112
 113 | tc06-1518B-4c-dot1q-l2xcbase-mrr
 114 | | [Tags] | 1518B | 4C
 115 | | framesize=${1518} | phy_cores=${4}
 116
 117 | tc07-9000B-1c-dot1q-l2xcbase-mrr
 118 | | [Tags] | 9000B | 1C
 119 | | framesize=${9000} | phy_cores=${1}
 120
 121 | tc08-9000B-2c-dot1q-l2xcbase-mrr
 122 | | [Tags] | 9000B | 2C
 123 | | framesize=${9000} | phy_cores=${2}
 124
 125 | tc09-9000B-4c-dot1q-l2xcbase-mrr
 126 | | [Tags] | 9000B | 4C
 127 | | framesize=${9000} | phy_cores=${4}
 128
 129 | tc10-IMIX-1c-dot1q-l2xcbase-mrr
 130 | | [Tags] | IMIX | 1C
 131 | | framesize=IMIX_v4_1 | phy_cores=${1}
 132
 133 | tc11-IMIX-2c-dot1q-l2xcbase-mrr
 134 | | [Tags] | IMIX | 2C
 135 | | framesize=IMIX_v4_1 | phy_cores=${2}
 136
 137 | tc12-IMIX-4c-dot1q-l2xcbase-mrr
 138 | | [Tags] | IMIX | 4C
 139 | | framesize=IMIX_v4_1 | phy_cores=${4}