tests/vpp/perf/vm_vhost/10ge2p1x520-ethip4-ip4base-eth-2vhostvr256-1vm-cfsrr1-ndrpdr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Library | resources.libraries.python.QemuUtils
  17 | ...
  18 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  19 | ... | NIC_Intel-X520-DA2 | ETH | IP4FWD | BASE | VHOST | VM | VHOST_256
  20 | ... | CFS_OPT
  21 | ...
  22 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  23 | ... | L3 | Intel-X520-DA2
  24 | Suite Teardown | Tear down 3-node performance topology
  25 | ...
  26 | Test Setup | Set up performance test
  27 | Test Teardown | Tear down performance test with vhost and VM with dpdk-testpmd
  28 | ... | ${min_rate}pps | ${framesize} | ${traffic_profile}
  29 | ... | dut1_node=${dut1} | dut1_vm_refs=${dut1_vm_refs}
  30 | ... | dut2_node=${dut2} | dut2_vm_refs=${dut2_vm_refs}
  31 | ...
  32 | Test Template | Local Template
  33 | ...
  34 | Documentation | *RFC2544: Packet throughput IP4 test cases with vhost*
  35 | ...
  36 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  37 | ... | with single links between nodes.
  38 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for IPv4 routing.
  39 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with IPv4
  40 | ... | routing and two static IPv4 /24 route entries. Qemu Guest is connected
  41 | ... | to VPP via vhost-user interfaces. Guest is running DPDK testpmd
  42 | ... | interconnecting vhost-user interfaces using 5 cores pinned to cpus 5-9
  43 | ... | and 2048M memory. Testpmd is using socket-mem=1024M (512x2M hugepages),
  44 | ... | 5 cores (1 main core and 4 cores dedicated for io), forwarding mode is
  45 | ... | set to mac, rxd/txd=256, burst=64. Scheduler policy is set to SCHED_RR
  46 | ... | with priority 1 for all Qemu CPUs. DUT1, DUT2 are tested with 2p10GE
  47 | ... | NIC X520 Niantic by Intel.
  48 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop
  49 | ... | Rate) with zero packet loss tolerance or throughput PDR (Partial Drop
  50 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage
  51 | ... | of packets transmitted. NDR and PDR are discovered for different
  52 | ... | Ethernet L2 frame sizes using MLRsearch library.
  53 | ... | Test packets are generated by TG on
  54 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups
  55 | ... | (flow-group per direction, 253 flows per flow-group) with all packets
  56 | ... | containing Ethernet header, IPv4 header with IP protocol=61 and static
  57 | ... | payload. MAC addresses are matching MAC addresses of the TG node
  58 | ... | interfaces.
  59 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  60
  61 *** Variables ***
  62 | ${perf_qemu_qsz}= | 256
  63 # X520-DA2 bandwidth limit
  64 | ${s_limit} | ${10000000000}
  65 # Socket names
  66 | ${sock1}= | /tmp/sock-1-1
  67 | ${sock2}= | /tmp/sock-1-2
  68 # FIB tables
  69 | ${fib_table_1}= | 100
  70 | ${fib_table_2}= | 101
  71 # Traffic profile:
  72 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4src253
  73
  74 *** Keywords ***
  75 | Local Template
  76 | | [Documentation]
  77 | | ... | [Cfg] DUT runs IP4 routing config with required number of threads,\
  78 | | ... | phy cores and receive queues per NIC port.
  79 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  80 | | ...
  81 | | ... | *Arguments:*
  82 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  83 | | ... | Type: integer, string
  84 | | ... | - phy_cores - Number of physical cores. Type: integer
  85 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  86 | | ...
  87 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  88 | | ...
  89 | | Set Test Variable | ${use_tuned_cfs} | ${True}
  90 | | Set Test Variable | ${framesize}
  91 | | Set Test Variable | ${min_rate} | ${10000}
  92 | | ${dut1_vm_refs}= | Create Dictionary
  93 | | ${dut2_vm_refs}= | Create Dictionary
  94 | | Set Test Variable | ${dut1_vm_refs}
  95 | | Set Test Variable | ${dut2_vm_refs}
  96 | | ...
  97 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  98 | | And Add PCI devices to all DUTs
  99 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
 100 | | ... | ${s_limit} | ${framesize}
 101 | | And Apply startup configuration on all VPP DUTs
 102 | | When Initialize IPv4 forwarding with vhost in 3-node circular topology
 103 | | ... | ${sock1} | ${sock2}
 104 | | ${vm1}= | And Configure guest VM with dpdk-testpmd-mac connected via vhost-user
 105 | | ... | ${dut1} | ${sock1} | ${sock2} | DUT1_VM1 | ${dut1_vif1_mac}
 106 | | ... | ${dut1_vif2_mac} | jumbo_frames=${jumbo}
 107 | | Set To Dictionary | ${dut1_vm_refs} | DUT1_VM1 | ${vm1}
 108 | | ${vm2}= | And Configure guest VM with dpdk-testpmd-mac connected via vhost-user
 109 | | ... | ${dut2} | ${sock1} | ${sock2} | DUT2_VM1 | ${dut2_vif1_mac}
 110 | | ... | ${dut2_vif2_mac} | jumbo_frames=${jumbo}
 111 | | Set To Dictionary | ${dut2_vm_refs} | DUT2_VM1 | ${vm2}
 112 | | Setup Scheduler Policy for Vpp On All DUTs
 113 | | Then Find NDR and PDR intervals using optimized search
 114 | | ... | ${framesize} | ${traffic_profile} | ${min_rate} | ${max_rate}
 115
 116 *** Test Cases ***
 117 | tc01-64B-1c-ethip4-ip4base-eth-2vhostvr256-1vm-cfsrr1-ndrpdr
 118 | | [Tags] | 64B | 1C
 119 | | framesize=${64} | phy_cores=${1}
 120
 121 | tc02-64B-2c-ethip4-ip4base-eth-2vhostvr256-1vm-cfsrr1-ndrpdr
 122 | | [Tags] | 64B | 2C
 123 | | framesize=${64} | phy_cores=${2}
 124
 125 | tc03-64B-4c-ethip4-ip4base-eth-2vhostvr256-1vm-cfsrr1-ndrpdr
 126 | | [Tags] | 64B | 4C
 127 | | framesize=${64} | phy_cores=${4}
 128
 129 | tc04-1518B-1c-ethip4-ip4base-eth-2vhostvr256-1vm-cfsrr1-ndrpdr
 130 | | [Tags] | 1518B | 1C
 131 | | framesize=${1518} | phy_cores=${1}
 132
 133 | tc05-1518B-2c-ethip4-ip4base-eth-2vhostvr256-1vm-cfsrr1-ndrpdr
 134 | | [Tags] | 1518B | 2C
 135 | | framesize=${1518} | phy_cores=${2}
 136
 137 | tc06-1518B-4c-ethip4-ip4base-eth-2vhostvr256-1vm-cfsrr1-ndrpdr
 138 | | [Tags] | 1518B | 4C
 139 | | framesize=${1518} | phy_cores=${4}
 140
 141 | tc07-9000B-1c-ethip4-ip4base-eth-2vhostvr256-1vm-cfsrr1-ndrpdr
 142 | | [Tags] | 9000B | 1C
 143 | | framesize=${9000} | phy_cores=${1}
 144
 145 | tc08-9000B-2c-ethip4-ip4base-eth-2vhostvr256-1vm-cfsrr1-ndrpdr
 146 | | [Tags] | 9000B | 2C
 147 | | framesize=${9000} | phy_cores=${2}
 148
 149 | tc09-9000B-4c-ethip4-ip4base-eth-2vhostvr256-1vm-cfsrr1-ndrpdr
 150 | | [Tags] | 9000B | 4C
 151 | | framesize=${9000} | phy_cores=${4}
 152
 153 | tc10-IMIX-1c-ethip4-ip4base-eth-2vhostvr256-1vm-cfsrr1-ndrpdr
 154 | | [Tags] | IMIX | 1C
 155 | | framesize=IMIX_v4_1 | phy_cores=${1}
 156
 157 | tc11-IMIX-2c-ethip4-ip4base-eth-2vhostvr256-1vm-cfsrr1-ndrpdr
 158 | | [Tags] | IMIX | 2C
 159 | | framesize=IMIX_v4_1 | phy_cores=${2}
 160
 161 | tc12-IMIX-4c-ethip4-ip4base-eth-2vhostvr256-1vm-cfsrr1-ndrpdr
 162 | | [Tags] | IMIX | 4C
 163 | | framesize=IMIX_v4_1 | phy_cores=${4}