config/arm/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017 Intel Corporation.
   3 # Copyright(c) 2017 Cavium, Inc
   4
   5 # for checking defines we need to use the correct compiler flags
   6 march_opt = '-march=@0@'.format(machine)
   7
   8 arm_force_native_march = false
   9
  10 machine_args_generic = [
  11         ['default', ['-march=armv8-a']],
  12         ['native', ['-march=native']],
  13         ['0xd03', ['-mcpu=cortex-a53']],
  14         ['0xd04', ['-mcpu=cortex-a35']],
  15         ['0xd07', ['-mcpu=cortex-a57']],
  16         ['0xd08', ['-mcpu=cortex-a72']],
  17         ['0xd09', ['-mcpu=cortex-a73']],
  18         ['0xd0a', ['-mcpu=cortex-a75']],
  19 ]
  20 machine_args_cavium = [
  21         ['default', ['-march=armv8-a+crc+crypto','-mcpu=thunderx']],
  22         ['native', ['-march=native']],
  23         ['0xa1', ['-mcpu=thunderxt88']],
  24         ['0xa2', ['-mcpu=thunderxt81']],
  25         ['0xa3', ['-mcpu=thunderxt83']]]
  26
  27 flags_common_default = [
  28         # Accelarate rte_memcpy. Be sure to run unit test (memcpy_perf_autotest)
  29         # to determine the best threshold in code. Refer to notes in source file
  30         # (lib/librte_eal/common/include/arch/arm/rte_memcpy_64.h) for more info.
  31         ['RTE_ARCH_ARM64_MEMCPY', false],
  32         #       ['RTE_ARM64_MEMCPY_ALIGNED_THRESHOLD', 2048],
  33         #       ['RTE_ARM64_MEMCPY_UNALIGNED_THRESHOLD', 512],
  34         # Leave below RTE_ARM64_MEMCPY_xxx options commented out, unless there're
  35         # strong reasons.
  36         #       ['RTE_ARM64_MEMCPY_SKIP_GCC_VER_CHECK', false],
  37         #       ['RTE_ARM64_MEMCPY_ALIGN_MASK', 0xF],
  38         #       ['RTE_ARM64_MEMCPY_STRICT_ALIGN', false],
  39
  40         ['RTE_LIBRTE_FM10K_PMD', false],
  41         ['RTE_LIBRTE_SFC_EFX_PMD', false],
  42         ['RTE_LIBRTE_AVP_PMD', false],
  43
  44         ['RTE_SCHED_VECTOR', false],
  45 ]
  46
  47 flags_generic = [
  48         ['RTE_MACHINE', '"armv8a"'],
  49         ['RTE_CACHE_LINE_SIZE', 128]]
  50 flags_cavium = [
  51         ['RTE_MACHINE', '"thunderx"'],
  52         ['RTE_CACHE_LINE_SIZE', 128],
  53         ['RTE_MAX_NUMA_NODES', 2],
  54         ['RTE_MAX_LCORE', 96],
  55         ['RTE_MAX_VFIO_GROUPS', 128],
  56         ['RTE_RING_USE_C11_MEM_MODEL', false]]
  57
  58 ## Arm implementer ID (ARM DDI 0487C.a, Section G7.2.106, Page G7-5321)
  59 impl_generic = ['Generic armv8', flags_generic, machine_args_generic]
  60 impl_0x41 = ['Arm', flags_generic, machine_args_generic]
  61 impl_0x42 = ['Broadcom', flags_generic, machine_args_generic]
  62 impl_0x43 = ['Cavium', flags_cavium, machine_args_cavium]
  63 impl_0x44 = ['DEC', flags_generic, machine_args_generic]
  64 impl_0x49 = ['Infineon', flags_generic, machine_args_generic]
  65 impl_0x4d = ['Motorola', flags_generic, machine_args_generic]
  66 impl_0x4e = ['NVIDIA', flags_generic, machine_args_generic]
  67 impl_0x50 = ['AppliedMicro', flags_generic, machine_args_generic]
  68 impl_0x51 = ['Qualcomm', flags_generic, machine_args_generic]
  69 impl_0x53 = ['Samsung', flags_generic, machine_args_generic]
  70 impl_0x56 = ['Marvell', flags_generic, machine_args_generic]
  71 impl_0x69 = ['Intel', flags_generic, machine_args_generic]
  72
  73
  74 if cc.get_define('__clang__') != ''
  75         dpdk_conf.set_quoted('RTE_TOOLCHAIN', 'clang')
  76         dpdk_conf.set('RTE_TOOLCHAIN_CLANG', 1)
  77 else
  78         dpdk_conf.set_quoted('RTE_TOOLCHAIN', 'gcc')
  79         dpdk_conf.set('RTE_TOOLCHAIN_GCC', 1)
  80 endif
  81
  82 dpdk_conf.set('RTE_FORCE_INTRINSICS', 1)
  83
  84 if cc.sizeof('void *') != 8
  85         dpdk_conf.set('RTE_CACHE_LINE_SIZE', 64)
  86         dpdk_conf.set('RTE_ARCH_ARM', 1)
  87         dpdk_conf.set('RTE_ARCH_ARMv7', 1)
  88 else
  89         dpdk_conf.set('RTE_CACHE_LINE_SIZE', 128)
  90         dpdk_conf.set('RTE_ARCH_ARM64', 1)
  91         dpdk_conf.set('RTE_ARCH_64', 1)
  92
  93         machine = []
  94         cmd_generic = ['generic', '', '', 'default', '']
  95         cmd_output = cmd_generic # Set generic by default
  96         machine_args = [] # Clear previous machine args
  97         if not meson.is_cross_build()
  98                 # The script returns ['Implementer', 'Variant', 'Architecture',
  99                 # 'Primary Part number', 'Revision']
 100                 detect_vendor = find_program(join_paths(
 101                                 meson.current_source_dir(), 'armv8_machine.py'))
 102                 cmd = run_command(detect_vendor.path())
 103                 if cmd.returncode() == 0
 104                         cmd_output = cmd.stdout().to_lower().strip().split(' ')
 105                 endif
 106                 # Set to generic if variable is not found
 107                 machine = get_variable('impl_' + cmd_output[0], 'generic')
 108                 if machine == 'generic'
 109                         machine = impl_generic
 110                         cmd_output = cmd_generic
 111                 endif
 112                 impl_pn = cmd_output[3]
 113                 if arm_force_native_march == true
 114                         impl_pn = 'native'
 115                 endif
 116         else
 117                 impl_id = meson.get_cross_property('implementor_id', 'generic')
 118                 impl_pn = meson.get_cross_property('implementor_pn', 'default')
 119                 machine = get_variable('impl_' + impl_id)
 120         endif
 121
 122         # Apply Common Defaults. These settings may be overwritten by machine
 123         # settings later.
 124         foreach flag: flags_common_default
 125                 if flag.length() > 0
 126                         dpdk_conf.set(flag[0], flag[1])
 127                 endif
 128         endforeach
 129
 130         message('Implementer : ' + machine[0])
 131         foreach flag: machine[1]
 132                 if flag.length() > 0
 133                         dpdk_conf.set(flag[0], flag[1])
 134                 endif
 135         endforeach
 136         # Primary part number based mcpu flags are supported
 137         # for gcc versions > 7
 138         if cc.version().version_compare(
 139                         '<7.0') or cmd_output.length() == 0
 140                 if not meson.is_cross_build() and arm_force_native_march == true
 141                         impl_pn = 'native'
 142                 else
 143                         impl_pn = 'default'
 144                 endif
 145         endif
 146         foreach marg: machine[2]
 147                 if marg[0] == impl_pn
 148                         foreach f: marg[1]
 149                                 machine_args += f
 150                         endforeach
 151                 endif
 152         endforeach
 153 endif
 154 message(machine_args)
 155
 156 if cc.get_define('__ARM_NEON', args: machine_args) != ''
 157         dpdk_conf.set('RTE_MACHINE_CPUFLAG_NEON', 1)
 158         compile_time_cpuflags += ['RTE_CPUFLAG_NEON']
 159 endif
 160
 161 if cc.get_define('__ARM_FEATURE_CRC32', args: machine_args) != ''
 162         dpdk_conf.set('RTE_MACHINE_CPUFLAG_CRC32', 1)
 163         compile_time_cpuflags += ['RTE_CPUFLAG_CRC32']
 164 endif
 165
 166 if cc.get_define('__ARM_FEATURE_CRYPTO', args: machine_args) != ''
 167         dpdk_conf.set('RTE_MACHINE_CPUFLAG_AES', 1)
 168         dpdk_conf.set('RTE_MACHINE_CPUFLAG_PMULL', 1)
 169         dpdk_conf.set('RTE_MACHINE_CPUFLAG_SHA1', 1)
 170         dpdk_conf.set('RTE_MACHINE_CPUFLAG_SHA2', 1)
 171         compile_time_cpuflags += ['RTE_CPUFLAG_AES', 'RTE_CPUFLAG_PMULL',
 172         'RTE_CPUFLAG_SHA1', 'RTE_CPUFLAG_SHA2']
 173 endif