config/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017 Intel Corporation
   3
   4 # set the machine type and cflags for it
   5 if meson.is_cross_build()
   6         machine = host_machine.cpu()
   7 else
   8         machine = get_option('machine')
   9 endif
  10 dpdk_conf.set('RTE_MACHINE', machine)
  11 machine_args = []
  12 # ppc64 does not support -march=native
  13 if host_machine.cpu_family().startswith('ppc') and machine == 'native'
  14         machine_args += '-mcpu=' + machine
  15         machine_args += '-mtune=' + machine
  16 else
  17         machine_args += '-march=' + machine
  18 endif
  19
  20 toolchain = cc.get_id()
  21 dpdk_conf.set_quoted('RTE_TOOLCHAIN', toolchain)
  22 dpdk_conf.set('RTE_TOOLCHAIN_' + toolchain.to_upper(), 1)
  23
  24 add_project_link_arguments('-Wl,--no-as-needed', language: 'c')
  25 dpdk_extra_ldflags += '-Wl,--no-as-needed'
  26
  27 # use pthreads
  28 add_project_link_arguments('-pthread', language: 'c')
  29 dpdk_extra_ldflags += '-pthread'
  30
  31 # some libs depend on maths lib
  32 add_project_link_arguments('-lm', language: 'c')
  33 dpdk_extra_ldflags += '-lm'
  34
  35 # for linux link against dl, for bsd execinfo
  36 if host_machine.system() == 'linux'
  37         link_lib = 'dl'
  38 else
  39         link_lib = 'execinfo'
  40 endif
  41 add_project_link_arguments('-l' + link_lib, language: 'c')
  42 dpdk_extra_ldflags += '-l' + link_lib
  43
  44 # check for libraries used in multiple places in DPDK
  45 has_libnuma = 0
  46 numa_dep = cc.find_library('numa', required: false)
  47 if numa_dep.found() and cc.has_header('numaif.h')
  48         dpdk_conf.set10('RTE_HAS_LIBNUMA', true)
  49         has_libnuma = 1
  50         add_project_link_arguments('-lnuma', language: 'c')
  51         dpdk_extra_ldflags += '-lnuma'
  52 endif
  53
  54 # check for strlcpy
  55 if host_machine.system() == 'linux' and cc.find_library('bsd',
  56                 required: false).found() and cc.has_header('bsd/string.h')
  57         dpdk_conf.set('RTE_USE_LIBBSD', 1)
  58         add_project_link_arguments('-lbsd', language: 'c')
  59         dpdk_extra_ldflags += '-lbsd'
  60 endif
  61
  62 # add -include rte_config to cflags
  63 add_project_arguments('-include', 'rte_config.h', language: 'c')
  64
  65 # enable extra warnings and disable any unwanted warnings
  66 warning_flags = [
  67         '-Wsign-compare',
  68         '-Wcast-qual',
  69         '-Wno-address-of-packed-member'
  70 ]
  71 if cc.sizeof('void *') == 4
  72 # for 32-bit, don't warn about casting a 32-bit pointer to 64-bit int - it's fine!!
  73         warning_flags += '-Wno-pointer-to-int-cast'
  74 endif
  75 foreach arg: warning_flags
  76         if cc.has_argument(arg)
  77                 add_project_arguments(arg, language: 'c')
  78         endif
  79 endforeach
  80
  81 # set other values pulled from the build options
  82 dpdk_conf.set('RTE_MAX_LCORE', get_option('max_lcores'))
  83 dpdk_conf.set('RTE_MAX_NUMA_NODES', get_option('max_numa_nodes'))
  84 dpdk_conf.set('RTE_LIBEAL_USE_HPET', get_option('use_hpet'))
  85 dpdk_conf.set('RTE_EAL_ALLOW_INV_SOCKET_ID', get_option('allow_invalid_socket_id'))
  86 # values which have defaults which may be overridden
  87 dpdk_conf.set('RTE_MAX_VFIO_GROUPS', 64)
  88 dpdk_conf.set('RTE_DRIVER_MEMPOOL_BUCKET_SIZE_KB', 64)
  89 dpdk_conf.set('RTE_LIBRTE_DPAA2_USE_PHYS_IOVA', true)
  90
  91 compile_time_cpuflags = []
  92 if host_machine.cpu_family().startswith('x86')
  93         arch_subdir = 'x86'
  94 elif host_machine.cpu_family().startswith('arm') or host_machine.cpu_family().startswith('aarch')
  95         arch_subdir = 'arm'
  96 elif host_machine.cpu_family().startswith('ppc')
  97         arch_subdir = 'ppc_64'
  98 endif
  99 subdir(arch_subdir)
 100 dpdk_conf.set('RTE_COMPILE_TIME_CPUFLAGS', ','.join(compile_time_cpuflags))
 101
 102 # set the install path for the drivers
 103 dpdk_conf.set_quoted('RTE_EAL_PMD_PATH', eal_pmd_path)
 104
 105 install_headers('rte_config.h', subdir: get_option('include_subdir_arch'))
 106
 107 # enable VFIO only if it is linux OS
 108 dpdk_conf.set('RTE_EAL_VFIO', host_machine.system() == 'linux')