config/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017 Intel Corporation
   3
   4 # set the machine type and cflags for it
   5 if meson.is_cross_build()
   6         machine = host_machine.cpu()
   7 else
   8         machine = get_option('machine')
   9 endif
  10 dpdk_conf.set('RTE_MACHINE', machine)
  11 machine_args = []
  12 machine_args += '-march=' + machine
  13
  14 toolchain = cc.get_id()
  15 dpdk_conf.set_quoted('RTE_TOOLCHAIN', toolchain)
  16 dpdk_conf.set('RTE_TOOLCHAIN_' + toolchain.to_upper(), 1)
  17
  18 # use pthreads
  19 add_project_link_arguments('-pthread', language: 'c')
  20 dpdk_extra_ldflags += '-pthread'
  21
  22 # some libs depend on maths lib
  23 add_project_link_arguments('-lm', language: 'c')
  24 dpdk_extra_ldflags += '-lm'
  25
  26 # for linux link against dl, for bsd execinfo
  27 if host_machine.system() == 'linux'
  28         link_lib = 'dl'
  29 else
  30         link_lib = 'execinfo'
  31 endif
  32 add_project_link_arguments('-l' + link_lib, language: 'c')
  33 dpdk_extra_ldflags += '-l' + link_lib
  34
  35 # check for libraries used in multiple places in DPDK
  36 has_libnuma = 0
  37 numa_dep = cc.find_library('numa', required: false)
  38 if numa_dep.found() and cc.has_header('numaif.h')
  39         dpdk_conf.set10('RTE_HAS_LIBNUMA', true)
  40         has_libnuma = 1
  41         add_project_link_arguments('-lnuma', language: 'c')
  42         dpdk_extra_ldflags += '-lnuma'
  43 endif
  44
  45 # check for strlcpy
  46 if host_machine.system() == 'linux' and cc.find_library('bsd',
  47                 required: false).found() and cc.has_header('bsd/string.h')
  48         dpdk_conf.set('RTE_USE_LIBBSD', 1)
  49         add_project_link_arguments('-lbsd', language: 'c')
  50         dpdk_extra_ldflags += '-lbsd'
  51 endif
  52
  53 # add -include rte_config to cflags
  54 add_project_arguments('-include', 'rte_config.h', language: 'c')
  55
  56 # enable extra warnings and disable any unwanted warnings
  57 warning_flags = [
  58         '-Wsign-compare',
  59         '-Wcast-qual',
  60         '-Wno-address-of-packed-member'
  61 ]
  62 if cc.sizeof('void *') == 4
  63 # for 32-bit, don't warn about casting a 32-bit pointer to 64-bit int - it's fine!!
  64         warning_flags += '-Wno-pointer-to-int-cast'
  65 endif
  66 foreach arg: warning_flags
  67         if cc.has_argument(arg)
  68                 add_project_arguments(arg, language: 'c')
  69         endif
  70 endforeach
  71
  72 # set other values pulled from the build options
  73 dpdk_conf.set('RTE_MAX_LCORE', get_option('max_lcores'))
  74 dpdk_conf.set('RTE_MAX_NUMA_NODES', get_option('max_numa_nodes'))
  75 dpdk_conf.set('RTE_LIBEAL_USE_HPET', get_option('use_hpet'))
  76 dpdk_conf.set('RTE_EAL_ALLOW_INV_SOCKET_ID', get_option('allow_invalid_socket_id'))
  77 # values which have defaults which may be overridden
  78 dpdk_conf.set('RTE_MAX_VFIO_GROUPS', 64)
  79 dpdk_conf.set('RTE_DRIVER_MEMPOOL_BUCKET_SIZE_KB', 64)
  80 dpdk_conf.set('RTE_LIBRTE_DPAA2_USE_PHYS_IOVA', true)
  81
  82 compile_time_cpuflags = []
  83 if host_machine.cpu_family().startswith('x86')
  84         arch_subdir = 'x86'
  85 elif host_machine.cpu_family().startswith('arm') or host_machine.cpu_family().startswith('aarch')
  86         arch_subdir = 'arm'
  87 endif
  88 subdir(arch_subdir)
  89 dpdk_conf.set('RTE_COMPILE_TIME_CPUFLAGS', ','.join(compile_time_cpuflags))
  90
  91 # set the install path for the drivers
  92 dpdk_conf.set_quoted('RTE_EAL_PMD_PATH', eal_pmd_path)
  93
  94 install_headers('rte_config.h', subdir: get_option('include_subdir_arch'))