config/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017 Intel Corporation
   3
   4 # set the machine type and cflags for it
   5 if meson.is_cross_build()
   6         machine = host_machine.cpu()
   7 else
   8         machine = get_option('machine')
   9 endif
  10
  11 # machine type 'default' is special, it defaults to the per arch agreed common
  12 # minimal baseline needed for DPDK.
  13 # That might not be the most optimized, but the most portable version while
  14 # still being able to support the CPU features required for DPDK.
  15 # This can be bumped up by the DPDK project, but it can never be an
  16 # invariant like 'native'
  17 if machine == 'default'
  18         if host_machine.cpu_family().startswith('x86')
  19                 # matches the old pre-meson build systems default
  20                 machine = 'corei7'
  21         elif host_machine.cpu_family().startswith('arm')
  22                 machine = 'armv7-a'
  23         elif host_machine.cpu_family().startswith('aarch')
  24                 # arm64 manages defaults in config/arm/meson.build
  25                 machine = 'default'
  26         elif host_machine.cpu_family().startswith('ppc')
  27                 machine = 'power8'
  28         endif
  29 endif
  30
  31 dpdk_conf.set('RTE_MACHINE', machine)
  32 machine_args = []
  33
  34 # ppc64 does not support -march= at all, use -mcpu and -mtune for that
  35 if host_machine.cpu_family().startswith('ppc')
  36         machine_args += '-mcpu=' + machine
  37         machine_args += '-mtune=' + machine
  38 else
  39         machine_args += '-march=' + machine
  40 endif
  41
  42 toolchain = cc.get_id()
  43 dpdk_conf.set_quoted('RTE_TOOLCHAIN', toolchain)
  44 dpdk_conf.set('RTE_TOOLCHAIN_' + toolchain.to_upper(), 1)
  45
  46 add_project_link_arguments('-Wl,--no-as-needed', language: 'c')
  47 dpdk_extra_ldflags += '-Wl,--no-as-needed'
  48
  49 # use pthreads
  50 add_project_link_arguments('-pthread', language: 'c')
  51 dpdk_extra_ldflags += '-pthread'
  52
  53 # some libs depend on maths lib
  54 add_project_link_arguments('-lm', language: 'c')
  55 dpdk_extra_ldflags += '-lm'
  56
  57 # for linux link against dl, for bsd execinfo
  58 if host_machine.system() == 'linux'
  59         link_lib = 'dl'
  60 else
  61         link_lib = 'execinfo'
  62 endif
  63 add_project_link_arguments('-l' + link_lib, language: 'c')
  64 dpdk_extra_ldflags += '-l' + link_lib
  65
  66 # check for libraries used in multiple places in DPDK
  67 has_libnuma = 0
  68 numa_dep = cc.find_library('numa', required: false)
  69 if numa_dep.found() and cc.has_header('numaif.h')
  70         dpdk_conf.set10('RTE_HAS_LIBNUMA', true)
  71         has_libnuma = 1
  72         add_project_link_arguments('-lnuma', language: 'c')
  73         dpdk_extra_ldflags += '-lnuma'
  74 endif
  75
  76 # check for strlcpy
  77 if host_machine.system() == 'linux' and cc.find_library('bsd',
  78                 required: false).found() and cc.has_header('bsd/string.h')
  79         dpdk_conf.set('RTE_USE_LIBBSD', 1)
  80         add_project_link_arguments('-lbsd', language: 'c')
  81         dpdk_extra_ldflags += '-lbsd'
  82 endif
  83
  84 # add -include rte_config to cflags
  85 add_project_arguments('-include', 'rte_config.h', language: 'c')
  86
  87 # enable extra warnings and disable any unwanted warnings
  88 warning_flags = [
  89         '-Wsign-compare',
  90         '-Wcast-qual',
  91         '-Wno-address-of-packed-member'
  92 ]
  93 if cc.sizeof('void *') == 4
  94 # for 32-bit, don't warn about casting a 32-bit pointer to 64-bit int - it's fine!!
  95         warning_flags += '-Wno-pointer-to-int-cast'
  96 endif
  97 foreach arg: warning_flags
  98         if cc.has_argument(arg)
  99                 add_project_arguments(arg, language: 'c')
 100         endif
 101 endforeach
 102
 103 # set other values pulled from the build options
 104 dpdk_conf.set('RTE_MAX_LCORE', get_option('max_lcores'))
 105 dpdk_conf.set('RTE_MAX_NUMA_NODES', get_option('max_numa_nodes'))
 106 dpdk_conf.set('RTE_LIBEAL_USE_HPET', get_option('use_hpet'))
 107 dpdk_conf.set('RTE_EAL_ALLOW_INV_SOCKET_ID', get_option('allow_invalid_socket_id'))
 108 # values which have defaults which may be overridden
 109 dpdk_conf.set('RTE_MAX_VFIO_GROUPS', 64)
 110 dpdk_conf.set('RTE_DRIVER_MEMPOOL_BUCKET_SIZE_KB', 64)
 111 dpdk_conf.set('RTE_LIBRTE_DPAA2_USE_PHYS_IOVA', true)
 112
 113 compile_time_cpuflags = []
 114 if host_machine.cpu_family().startswith('x86')
 115         arch_subdir = 'x86'
 116 elif host_machine.cpu_family().startswith('arm') or host_machine.cpu_family().startswith('aarch')
 117         arch_subdir = 'arm'
 118 elif host_machine.cpu_family().startswith('ppc')
 119         arch_subdir = 'ppc_64'
 120 endif
 121 subdir(arch_subdir)
 122 dpdk_conf.set('RTE_COMPILE_TIME_CPUFLAGS', ','.join(compile_time_cpuflags))
 123
 124 # set the install path for the drivers
 125 dpdk_conf.set_quoted('RTE_EAL_PMD_PATH', eal_pmd_path)
 126
 127 install_headers('rte_config.h', subdir: get_option('include_subdir_arch'))
 128
 129 # enable VFIO only if it is linux OS
 130 dpdk_conf.set('RTE_EAL_VFIO', host_machine.system() == 'linux')