config/x86/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017 Intel Corporation
   3
   4 # get binutils version for the workaround of Bug 97
   5 ldver = run_command('ld', '-v').stdout().strip()
   6 if ldver.contains('2.30')
   7         if cc.has_argument('-mno-avx512f')
   8                 machine_args += '-mno-avx512f'
   9                 message('Binutils 2.30 detected, disabling AVX512 support as workaround for bug #97')
  10         endif
  11         if ldver.contains('2.31') and cc.has_argument('-mno-avx512f')
  12                 machine_args += '-mno-avx512f'
  13                 message('Binutils 2.31 detected, disabling AVX512 support as workaround for bug #249')
  14         endif
  15 endif
  16
  17 # we require SSE4.2 for DPDK
  18 sse_errormsg = '''SSE4.2 instruction set is required for DPDK.
  19 Please set the machine type to "nehalem" or "corei7" or higher value'''
  20
  21 if cc.get_define('__SSE4_2__', args: machine_args) == ''
  22         error(sse_errormsg)
  23 endif
  24
  25 base_flags = ['SSE', 'SSE2', 'SSE3','SSSE3', 'SSE4_1', 'SSE4_2']
  26 foreach f:base_flags
  27         dpdk_conf.set('RTE_MACHINE_CPUFLAG_' + f, 1)
  28         compile_time_cpuflags += ['RTE_CPUFLAG_' + f]
  29 endforeach
  30
  31 dpdk_conf.set('RTE_ARCH_X86', 1)
  32 if (host_machine.cpu_family() == 'x86_64')
  33         dpdk_conf.set('RTE_ARCH_X86_64', 1)
  34         dpdk_conf.set('RTE_ARCH', 'x86_64')
  35         dpdk_conf.set('RTE_ARCH_64', 1)
  36 else
  37         dpdk_conf.set('RTE_ARCH_I686', 1)
  38         dpdk_conf.set('RTE_ARCH', 'i686')
  39 endif
  40
  41 if cc.get_define('__AES__', args: machine_args) != ''
  42         dpdk_conf.set('RTE_MACHINE_CPUFLAG_AES', 1)
  43         compile_time_cpuflags += ['RTE_CPUFLAG_AES']
  44 endif
  45 if cc.get_define('__PCLMUL__', args: machine_args) != ''
  46         dpdk_conf.set('RTE_MACHINE_CPUFLAG_PCLMULQDQ', 1)
  47         compile_time_cpuflags += ['RTE_CPUFLAG_PCLMULQDQ']
  48 endif
  49 if cc.get_define('__AVX__', args: machine_args) != ''
  50         dpdk_conf.set('RTE_MACHINE_CPUFLAG_AVX', 1)
  51         compile_time_cpuflags += ['RTE_CPUFLAG_AVX']
  52 endif
  53 if cc.get_define('__AVX2__', args: machine_args) != ''
  54         dpdk_conf.set('RTE_MACHINE_CPUFLAG_AVX2', 1)
  55         compile_time_cpuflags += ['RTE_CPUFLAG_AVX2']
  56 endif
  57 if cc.get_define('__AVX512F__', args: machine_args) != ''
  58         dpdk_conf.set('RTE_MACHINE_CPUFLAG_AVX512F', 1)
  59         compile_time_cpuflags += ['RTE_CPUFLAG_AVX512F']
  60 endif
  61
  62 dpdk_conf.set('RTE_CACHE_LINE_SIZE', 64)