drivers/net/mlx5/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright 2018 6WIND S.A.
   3 # Copyright 2018 Mellanox Technologies, Ltd
   4
   5 pmd_dlopen = get_option('enable_driver_mlx_glue')
   6 LIB_GLUE_BASE = 'librte_pmd_mlx5_glue.so'
   7 LIB_GLUE_VERSION = '18.11.0'
   8 LIB_GLUE = LIB_GLUE_BASE + '.' + LIB_GLUE_VERSION
   9 if pmd_dlopen
  10         dpdk_conf.set('RTE_LIBRTE_MLX5_DLOPEN_DEPS', 1)
  11         cflags += [
  12                 '-DMLX5_GLUE="@0@"'.format(LIB_GLUE),
  13                 '-DMLX5_GLUE_VERSION="@0@"'.format(LIB_GLUE_VERSION),
  14         ]
  15 endif
  16 libs = [
  17         cc.find_library('mnl', required:false),
  18         cc.find_library('mlx5', required:false),
  19         cc.find_library('ibverbs', required:false),
  20 ]
  21 build = true
  22 foreach lib:libs
  23         if not lib.found()
  24                 build = false
  25         endif
  26 endforeach
  27 if build
  28         allow_experimental_apis = true
  29         ext_deps += libs
  30         sources = files(
  31                 'mlx5.c',
  32                 'mlx5_ethdev.c',
  33                 'mlx5_flow.c',
  34                 'mlx5_flow_dv.c',
  35                 'mlx5_flow_tcf.c',
  36                 'mlx5_flow_verbs.c',
  37                 'mlx5_mac.c',
  38                 'mlx5_mr.c',
  39                 'mlx5_nl.c',
  40                 'mlx5_rss.c',
  41                 'mlx5_rxmode.c',
  42                 'mlx5_rxq.c',
  43                 'mlx5_rxtx.c',
  44                 'mlx5_socket.c',
  45                 'mlx5_stats.c',
  46                 'mlx5_trigger.c',
  47                 'mlx5_txq.c',
  48                 'mlx5_vlan.c',
  49         )
  50         if dpdk_conf.has('RTE_ARCH_X86_64') or dpdk_conf.has('RTE_ARCH_ARM64')
  51                 sources += files('mlx5_rxtx_vec.c')
  52         endif
  53         if not pmd_dlopen
  54                 sources += files('mlx5_glue.c')
  55         endif
  56         cflags_options = [
  57                 '-Wextra',
  58                 '-std=c11',
  59                 '-Wno-strict-prototypes',
  60                 '-D_BSD_SOURCE',
  61                 '-D_DEFAULT_SOURCE',
  62                 '-D_XOPEN_SOURCE=600'
  63         ]
  64         foreach option:cflags_options
  65                 if cc.has_argument(option)
  66                         cflags += option
  67                 endif
  68         endforeach
  69         if get_option('buildtype').contains('debug')
  70                 cflags += [ '-pedantic', '-UNDEBUG', '-DPEDANTIC' ]
  71         else
  72                 cflags += [ '-DNDEBUG', '-UPEDANTIC' ]
  73         endif
  74         # To maintain the compatibility with the make build system
  75         # mlx5_autoconf.h file is still generated.
  76         # input array for meson member search:
  77         # [ "MACRO to define if found", "header for the search",
  78         #   "symbol to search", "struct member to search" ]
  79         has_member_args = [
  80                 [ 'HAVE_IBV_MLX5_MOD_SWP', 'infiniband/mlx5dv.h',
  81                 'struct mlx5dv_sw_parsing_caps', 'sw_parsing_offloads' ],
  82                 [ 'HAVE_IBV_DEVICE_COUNTERS_SET_V42', 'infiniband/verbs.h',
  83                 'struct ibv_counter_set_init_attr', 'counter_set_id' ],
  84                 [ 'HAVE_IBV_DEVICE_COUNTERS_SET_V45', 'infiniband/verbs.h',
  85                 'struct ibv_counters_init_attr', 'comp_mask' ],
  86         ]
  87         # input array for meson symbol search:
  88         # [ "MACRO to define if found", "header for the search",
  89         #   "symbol to search" ]
  90         has_sym_args = [
  91                 [ 'HAVE_IBV_DEVICE_STRIDING_RQ_SUPPORT', 'infiniband/mlx5dv.h',
  92                 'MLX5DV_CQE_RES_FORMAT_CSUM_STRIDX' ],
  93                 [ 'HAVE_IBV_DEVICE_TUNNEL_SUPPORT', 'infiniband/mlx5dv.h',
  94                 'MLX5DV_CONTEXT_MASK_TUNNEL_OFFLOADS' ],
  95                 [ 'HAVE_IBV_MLX5_MOD_MPW', 'infiniband/mlx5dv.h',
  96                 'MLX5DV_CONTEXT_FLAGS_MPW_ALLOWED' ],
  97                 [ 'HAVE_IBV_MLX5_MOD_CQE_128B_COMP', 'infiniband/mlx5dv.h',
  98                 'MLX5DV_CONTEXT_FLAGS_CQE_128B_COMP' ],
  99                 [ 'HAVE_IBV_FLOW_DV_SUPPORT', 'infiniband/mlx5dv.h',
 100                 'MLX5DV_FLOW_ACTION_TAG' ],
 101                 [ 'HAVE_IBV_DEVICE_MPLS_SUPPORT', 'infiniband/verbs.h',
 102                 'IBV_FLOW_SPEC_MPLS' ],
 103                 [ 'HAVE_IBV_WQ_FLAG_RX_END_PADDING', 'infiniband/verbs.h',
 104                 'IBV_WQ_FLAG_RX_END_PADDING' ],
 105                 [ 'HAVE_SUPPORTED_40000baseKR4_Full', 'linux/ethtool.h',
 106                 'SUPPORTED_40000baseKR4_Full' ],
 107                 [ 'HAVE_SUPPORTED_40000baseCR4_Full', 'linux/ethtool.h',
 108                 'SUPPORTED_40000baseCR4_Full' ],
 109                 [ 'HAVE_SUPPORTED_40000baseSR4_Full', 'linux/ethtool.h',
 110                 'SUPPORTED_40000baseSR4_Full' ],
 111                 [ 'HAVE_SUPPORTED_40000baseLR4_Full', 'linux/ethtool.h',
 112                 'SUPPORTED_40000baseLR4_Full' ],
 113                 [ 'HAVE_SUPPORTED_56000baseKR4_Full', 'linux/ethtool.h',
 114                 'SUPPORTED_56000baseKR4_Full' ],
 115                 [ 'HAVE_SUPPORTED_56000baseCR4_Full', 'linux/ethtool.h',
 116                 'SUPPORTED_56000baseCR4_Full' ],
 117                 [ 'HAVE_SUPPORTED_56000baseSR4_Full', 'linux/ethtool.h',
 118                 'SUPPORTED_56000baseSR4_Full' ],
 119                 [ 'HAVE_SUPPORTED_56000baseLR4_Full', 'linux/ethtool.h',
 120                 'SUPPORTED_56000baseLR4_Full' ],
 121                 [ 'HAVE_ETHTOOL_LINK_MODE_25G', 'linux/ethtool.h',
 122                 'ETHTOOL_LINK_MODE_25000baseCR_Full_BIT' ],
 123                 [ 'HAVE_ETHTOOL_LINK_MODE_50G', 'linux/ethtool.h',
 124                 'ETHTOOL_LINK_MODE_50000baseCR2_Full_BIT' ],
 125                 [ 'HAVE_ETHTOOL_LINK_MODE_100G', 'linux/ethtool.h',
 126                 'ETHTOOL_LINK_MODE_100000baseKR4_Full_BIT' ],
 127                 [ 'HAVE_IFLA_PHYS_SWITCH_ID', 'linux/if_link.h',
 128                 'IFLA_PHYS_SWITCH_ID' ],
 129                 [ 'HAVE_IFLA_PHYS_PORT_NAME', 'linux/if_link.h',
 130                 'IFLA_PHYS_PORT_NAME' ],
 131                 [ 'HAVE_TCA_CHAIN', 'linux/rtnetlink.h',
 132                 'TCA_CHAIN' ],
 133                 [ 'HAVE_TCA_FLOWER_ACT', 'linux/pkt_cls.h',
 134                 'TCA_FLOWER_ACT' ],
 135                 [ 'HAVE_TCA_FLOWER_FLAGS', 'linux/pkt_cls.h',
 136                 'TCA_FLOWER_FLAGS' ],
 137                 [ 'HAVE_TCA_FLOWER_KEY_ETH_TYPE', 'linux/pkt_cls.h',
 138                 'TCA_FLOWER_KEY_ETH_TYPE' ],
 139                 [ 'HAVE_TCA_FLOWER_KEY_ETH_DST', 'linux/pkt_cls.h',
 140                 'TCA_FLOWER_KEY_ETH_DST' ],
 141                 [ 'HAVE_TCA_FLOWER_KEY_ETH_DST_MASK', 'linux/pkt_cls.h',
 142                 'TCA_FLOWER_KEY_ETH_DST_MASK' ],
 143                 [ 'HAVE_TCA_FLOWER_KEY_ETH_SRC', 'linux/pkt_cls.h',
 144                 'TCA_FLOWER_KEY_ETH_SRC' ],
 145                 [ 'HAVE_TCA_FLOWER_KEY_ETH_SRC_MASK', 'linux/pkt_cls.h',
 146                 'TCA_FLOWER_KEY_ETH_SRC_MASK' ],
 147                 [ 'HAVE_TCA_FLOWER_KEY_IP_PROTO', 'linux/pkt_cls.h',
 148                 'TCA_FLOWER_KEY_IP_PROTO' ],
 149                 [ 'HAVE_TCA_FLOWER_KEY_IPV4_SRC', 'linux/pkt_cls.h',
 150                 'TCA_FLOWER_KEY_IPV4_SRC' ],
 151                 [ 'HAVE_TCA_FLOWER_KEY_IPV4_SRC_MASK', 'linux/pkt_cls.h',
 152                 'TCA_FLOWER_KEY_IPV4_SRC_MASK' ],
 153                 [ 'HAVE_TCA_FLOWER_KEY_IPV4_DST', 'linux/pkt_cls.h',
 154                 'TCA_FLOWER_KEY_IPV4_DST' ],
 155                 [ 'HAVE_TCA_FLOWER_KEY_IPV4_DST_MASK', 'linux/pkt_cls.h',
 156                 'TCA_FLOWER_KEY_IPV4_DST_MASK' ],
 157                 [ 'HAVE_TCA_FLOWER_KEY_IPV6_SRC', 'linux/pkt_cls.h',
 158                 'TCA_FLOWER_KEY_IPV6_SRC' ],
 159                 [ 'HAVE_TCA_FLOWER_KEY_IPV6_SRC_MASK', 'linux/pkt_cls.h',
 160                 'TCA_FLOWER_KEY_IPV6_SRC_MASK' ],
 161                 [ 'HAVE_TCA_FLOWER_KEY_IPV6_DST', 'linux/pkt_cls.h',
 162                 'TCA_FLOWER_KEY_IPV6_DST' ],
 163                 [ 'HAVE_TCA_FLOWER_KEY_IPV6_DST_MASK', 'linux/pkt_cls.h',
 164                 'TCA_FLOWER_KEY_IPV6_DST_MASK' ],
 165                 [ 'HAVE_TCA_FLOWER_KEY_TCP_SRC', 'linux/pkt_cls.h',
 166                 'TCA_FLOWER_KEY_TCP_SRC' ],
 167                 [ 'HAVE_TCA_FLOWER_KEY_TCP_SRC_MASK', 'linux/pkt_cls.h',
 168                 'TCA_FLOWER_KEY_TCP_SRC_MASK' ],
 169                 [ 'HAVE_TCA_FLOWER_KEY_TCP_DST', 'linux/pkt_cls.h',
 170                 'TCA_FLOWER_KEY_TCP_DST' ],
 171                 [ 'HAVE_TCA_FLOWER_KEY_TCP_DST_MASK', 'linux/pkt_cls.h',
 172                 'TCA_FLOWER_KEY_TCP_DST_MASK' ],
 173                 [ 'HAVE_TCA_FLOWER_KEY_UDP_SRC', 'linux/pkt_cls.h',
 174                 'TCA_FLOWER_KEY_UDP_SRC' ],
 175                 [ 'HAVE_TCA_FLOWER_KEY_UDP_SRC_MASK', 'linux/pkt_cls.h',
 176                 'TCA_FLOWER_KEY_UDP_SRC_MASK' ],
 177                 [ 'HAVE_TCA_FLOWER_KEY_UDP_DST', 'linux/pkt_cls.h',
 178                 'TCA_FLOWER_KEY_UDP_DST' ],
 179                 [ 'HAVE_TCA_FLOWER_KEY_UDP_DST_MASK', 'linux/pkt_cls.h',
 180                 'TCA_FLOWER_KEY_UDP_DST_MASK' ],
 181                 [ 'HAVE_TCA_FLOWER_KEY_VLAN_ID', 'linux/pkt_cls.h',
 182                 'TCA_FLOWER_KEY_VLAN_ID' ],
 183                 [ 'HAVE_TCA_FLOWER_KEY_VLAN_PRIO', 'linux/pkt_cls.h',
 184                 'TCA_FLOWER_KEY_VLAN_PRIO' ],
 185                 [ 'HAVE_TCA_FLOWER_KEY_VLAN_ETH_TYPE', 'linux/pkt_cls.h',
 186                 'TCA_FLOWER_KEY_VLAN_ETH_TYPE' ],
 187                 [ 'HAVE_TCA_FLOWER_KEY_TCP_FLAGS', 'linux/pkt_cls.h',
 188                 'TCA_FLOWER_KEY_TCP_FLAGS' ],
 189                 [ 'HAVE_TCA_FLOWER_KEY_TCP_FLAGS_MASK', 'linux/pkt_cls.h',
 190                 'TCA_FLOWER_KEY_TCP_FLAGS_MASK' ],
 191                 [ 'HAVE_TC_ACT_GOTO_CHAIN', 'linux/pkt_cls.h',
 192                 'TC_ACT_GOTO_CHAIN' ],
 193                 [ 'HAVE_TC_ACT_VLAN', 'linux/tc_act/tc_vlan.h',
 194                 'TCA_VLAN_PUSH_VLAN_PRIORITY' ],
 195                 [ 'HAVE_TC_ACT_PEDIT', 'linux/tc_act/tc_pedit.h',
 196                 'TCA_PEDIT_KEY_EX_HDR_TYPE_UDP' ],
 197                 [ 'HAVE_RDMA_NL_NLDEV', 'rdma/rdma_netlink.h',
 198                 'RDMA_NL_NLDEV' ],
 199                 [ 'HAVE_RDMA_NLDEV_CMD_GET', 'rdma/rdma_netlink.h',
 200                 'RDMA_NLDEV_CMD_GET' ],
 201                 [ 'HAVE_RDMA_NLDEV_CMD_PORT_GET', 'rdma/rdma_netlink.h',
 202                 'RDMA_NLDEV_CMD_PORT_GET' ],
 203                 [ 'HAVE_RDMA_NLDEV_ATTR_DEV_INDEX', 'rdma/rdma_netlink.h',
 204                 'RDMA_NLDEV_ATTR_DEV_INDEX' ],
 205                 [ 'HAVE_RDMA_NLDEV_ATTR_DEV_NAME', 'rdma/rdma_netlink.h',
 206                 'RDMA_NLDEV_ATTR_DEV_NAME' ],
 207                 [ 'HAVE_RDMA_NLDEV_ATTR_PORT_INDEX', 'rdma/rdma_netlink.h',
 208                 'RDMA_NLDEV_ATTR_PORT_INDEX' ],
 209                 [ 'HAVE_RDMA_NLDEV_ATTR_NDEV_INDEX', 'rdma/rdma_netlink.h',
 210                 'RDMA_NLDEV_ATTR_NDEV_INDEX' ],
 211         ]
 212         config = configuration_data()
 213         foreach arg:has_sym_args
 214                 config.set(arg[0], cc.has_header_symbol(arg[1], arg[2]))
 215         endforeach
 216         foreach arg:has_member_args
 217                 file_prefix = '#include<' + arg[1] + '>'
 218                 config.set(arg[0], cc.has_member(arg[2], arg[3],
 219                         prefix : file_prefix))
 220         endforeach
 221         configure_file(output : 'mlx5_autoconf.h', configuration : config)
 222 endif
 223 # Build Glue Library
 224 if pmd_dlopen and build
 225         dlopen_name = 'mlx5_glue'
 226         dlopen_lib_name = driver_name_fmt.format(dlopen_name)
 227         dlopen_so_version = LIB_GLUE_VERSION
 228         dlopen_sources = files('mlx5_glue.c')
 229         dlopen_install_dir = [ eal_pmd_path + '-glue' ]
 230         shared_lib = shared_library(
 231                 dlopen_lib_name,
 232                 dlopen_sources,
 233                 include_directories: global_inc,
 234                 c_args: cflags,
 235                 dependencies: libs,
 236                 link_args: [
 237                 '-Wl,-export-dynamic',
 238                 '-Wl,-h,@0@'.format(LIB_GLUE),
 239                 ],
 240                 soversion: dlopen_so_version,
 241                 install: true,
 242                 install_dir: dlopen_install_dir,
 243         )
 244 endif