src/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 cmake_minimum_required(VERSION 3.5 FATAL_ERROR)
  15
  16 project(vpp C)
  17
  18 include(CheckCCompilerFlag)
  19
  20 ##############################################################################
  21 # CPU optimizations and multiarch support
  22 ##############################################################################
  23 if(CMAKE_SYSTEM_PROCESSOR MATCHES "amd64.*|x86_64.*|AMD64.*")
  24   set(CMAKE_C_FLAGS "-march=corei7 -mtune=corei7-avx ${CMAKE_C_FLAGS}")
  25   check_c_compiler_flag("-march=core-avx2" AVX2)
  26   if(AVX2)
  27     list(APPEND MARCH_VARIANTS "avx2\;-march=core-avx2 -mtune=core-avx2")
  28   endif()
  29   check_c_compiler_flag("-march=skylake-avx512" AVX512)
  30   if(AVX512)
  31     list(APPEND MARCH_VARIANTS "avx512\;-march=skylake-avx512 -mtune=skylake-avx512")
  32   endif()
  33 elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "^(aarch64.*|AARCH64.*)")
  34   set(CMAKE_C_FLAGS "-march=armv8-a+crc ${CMAKE_C_FLAGS}")
  35 endif()
  36
  37 macro(vpp_library_set_multiarch_sources lib)
  38   foreach(V ${MARCH_VARIANTS})
  39     list(GET V 0 VARIANT)
  40     list(GET V 1 VARIANT_FLAGS)
  41     set(l ${lib}_${VARIANT})
  42     add_library(${l} OBJECT ${ARGN})
  43     set_target_properties(${l} PROPERTIES POSITION_INDEPENDENT_CODE ON)
  44     target_compile_options(${l} PUBLIC "-DCLIB_MARCH_VARIANT=${VARIANT}")
  45     separate_arguments(VARIANT_FLAGS)
  46     target_compile_options(${l} PUBLIC ${VARIANT_FLAGS})
  47     target_sources(${lib} PRIVATE $<TARGET_OBJECTS:${l}>)
  48   endforeach()
  49 endmacro()
  50
  51 ##############################################################################
  52 # build config
  53 ##############################################################################
  54 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  55 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  56 set(CMAKE_C_FLAGS_COMMON "-DFORTIFY_SOURCE=2 -fstack-protector-all -Werror")
  57 set(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} ${CMAKE_C_FLAGS_COMMON} -DCLIB_DEBUG")
  58 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${CMAKE_C_FLAGS_COMMON}")
  59
  60 ##############################################################################
  61 # ccache
  62 ##############################################################################
  63 option(VPP_USE_CCACHE "Use ccache compiler cache." ON)
  64 if(VPP_USE_CCACHE)
  65   find_program(CCACHE_FOUND ccache)
  66   message(STATUS "Looking for ccache")
  67   if(CCACHE_FOUND)
  68     message(STATUS "Looking for ccache - found")
  69     set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ccache)
  70     set_property(GLOBAL PROPERTY RULE_LAUNCH_LINK ccache)
  71   else(CCACHE_FOUND)
  72     message(STATUS "Looking for ccache - not found")
  73   endif(CCACHE_FOUND)
  74 endif(VPP_USE_CCACHE)
  75
  76 ##############################################################################
  77 # install config
  78 ##############################################################################
  79 set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib")
  80 set(CMAKE_INSTALL_MESSAGE NEVER)
  81
  82 message(STATUS "CMAKE_C_FLAGS: ${CMAKE_C_FLAGS}")
  83 message(STATUS "We are on a ${CMAKE_SYSTEM_NAME} system")
  84 message(STATUS "The host processor is ${CMAKE_HOST_SYSTEM_PROCESSOR}")
  85
  86 include_directories (
  87         ${CMAKE_SOURCE_DIR}
  88         ${CMAKE_BINARY_DIR}
  89         ${CMAKE_BINARY_DIR}/include
  90 )
  91 set(CMAKE_INSTALL_DEFAULT_COMPONENT_NAME "vpp")
  92
  93 set(THREADS_PREFER_PTHREAD_FLAG ON)
  94 find_package(Threads REQUIRED)
  95 find_package(OpenSSL REQUIRED)
  96 include_directories(${OPENSSL_INCLUDE_DIR})
  97
  98 add_definitions(-DHAVE_MEMFD_CREATE -DVPP_API_TEST_BUILTIN=1)
  99
 100 ##############################################################################
 101 # API
 102 ##############################################################################
 103 function(vpp_generate_api_header file)
 104   set (output_name ${CMAKE_CURRENT_BINARY_DIR}/${file}.h)
 105   get_filename_component(output_dir ${output_name} DIRECTORY)
 106   add_custom_command (OUTPUT ${output_name}
 107     COMMAND mkdir -p ${output_dir}
 108     COMMAND ${CMAKE_SOURCE_DIR}/tools/vppapigen/vppapigen
 109     ARGS --includedir ${CMAKE_SOURCE_DIR} --input ${CMAKE_CURRENT_SOURCE_DIR}/${file} --output ${output_name}
 110     DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/${file}
 111     COMMENT "Generating API header ${file}.h"
 112   )
 113 endfunction()
 114
 115 function(vpp_add_api_files target)
 116   unset(header_files)
 117   foreach(file ${ARGN})
 118     vpp_generate_api_header (${file})
 119     list (APPEND header_files ${file}.h)
 120   endforeach()
 121   add_custom_target(${target} DEPENDS ${header_files})
 122 endfunction()
 123
 124 add_custom_target(api_headers
 125   DEPENDS vlibmemory_api_headers vnet_api_headers vpp_api_headers
 126 )
 127
 128 ##############################################################################
 129 # header files
 130 ##############################################################################
 131 function (vpp_add_header_files path)
 132   foreach(file ${ARGN})
 133     get_filename_component(dir ${file} DIRECTORY)
 134     install(FILES ${file} DESTINATION include/${path}/${dir})
 135   endforeach()
 136 endfunction()
 137
 138 ##############################################################################
 139 # subdirs
 140 ##############################################################################
 141 foreach (DIR vppinfra svm vlib vlibmemory vnet vpp vcl plugins)
 142   add_subdirectory(${DIR})
 143 endforeach ()
 144
 145 ##############################################################################
 146 # DEB Packaging
 147 ##############################################################################
 148 set(CPACK_GENERATOR "DEB")
 149 set(CPACK_DEBIAN_PACKAGE_MAINTAINER "VPP Team")
 150 set(CPACK_PACKAGE_NAME "vpp")
 151 set(CPACK_PACKAGE_VENDOR "fd.io")
 152 set(CPACK_PACKAGE_VERSION "18.08")
 153 set(CPACK_DEB_COMPONENT_INSTALL ON)
 154 set(CPACK_COMPONENTS_IGNORE_GROUPS 1)
 155 set(CPACK_DEBIAN_VPP_PACKAGE_NAME "vpp")
 156 set(CPACK_DEBIAN_VPP_FILE_NAME "vpp.deb")
 157 set(CPACK_DEBIAN_DEV_PACKAGE_NAME "vpp-dev")
 158 set(CPACK_DEBIAN_DEV_FILE_NAME "vpp-dev.deb")
 159 set(CPACK_DEBIAN_PLUGINS_PACKAGE_NAME "vpp-plugins")
 160 set(CPACK_DEBIAN_PLUGINS_FILE_NAME "vpp-plugins.deb")
 161 include(CPack)