src/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 cmake_minimum_required(VERSION 3.5 FATAL_ERROR)
  15
  16 set(CMAKE_C_COMPILER_NAMES clang-10 clang-9 gcc-9 cc)
  17
  18 project(vpp C)
  19
  20 include(CheckCCompilerFlag)
  21 include(cmake/misc.cmake)
  22 include(cmake/cpu.cmake)
  23 include(cmake/ccache.cmake)
  24
  25 ##############################################################################
  26 # VPP Version
  27 ##############################################################################
  28 execute_process(
  29   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  30   COMMAND scripts/version
  31   OUTPUT_VARIABLE VPP_VERSION
  32   OUTPUT_STRIP_TRAILING_WHITESPACE
  33 )
  34 string(REPLACE "-" ";" VPP_LIB_VERSION ${VPP_VERSION})
  35 list(GET VPP_LIB_VERSION 0 VPP_LIB_VERSION)
  36
  37 ##############################################################################
  38 # cross compiling
  39 ##############################################################################
  40 if(CMAKE_CROSSCOMPILING)
  41   set(CMAKE_IGNORE_PATH
  42     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/
  43     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/lib/
  44   )
  45 endif()
  46 set(CMAKE_C_COMPILER_TARGET ${CMAKE_SYSTEM_PROCESSOR}-linux-gnu)
  47
  48 ##############################################################################
  49 # build config
  50 ##############################################################################
  51 check_c_compiler_flag("-Wno-address-of-packed-member"
  52                       compiler_flag_no_address_of_packed_member)
  53
  54 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  55 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  56
  57 if (CMAKE_BUILD_TYPE)
  58   set(CMAKE_C_FLAGS "-g -fPIC -Werror -Wall ${CMAKE_C_FLAGS}")
  59 endif()
  60
  61 if (compiler_flag_no_address_of_packed_member)
  62   set(CMAKE_C_FLAGS "-Wno-address-of-packed-member ${CMAKE_C_FLAGS}")
  63 endif()
  64
  65 # release
  66 list(APPEND BUILD_TYPES "release")
  67 string(CONCAT CMAKE_C_FLAGS_RELEASE
  68   "-O2 "
  69   "-fstack-protector "
  70   "-DFORTIFY_SOURCE=2 "
  71   "-fno-common "
  72 )
  73
  74 string(CONCAT CMAKE_EXE_LINKER_FLAGS_RELEASE "-pie")
  75
  76 # debug
  77 list(APPEND BUILD_TYPES "debug")
  78 string(CONCAT CMAKE_C_FLAGS_DEBUG
  79   "-O0 "
  80   "-DCLIB_DEBUG "
  81   "-fstack-protector "
  82   "-DFORTIFY_SOURCE=2 "
  83   "-fno-common "
  84 )
  85
  86 # coverity
  87 list(APPEND BUILD_TYPES "coverity")
  88 string(CONCAT CMAKE_C_FLAGS_COVERITY "-O2 -D__COVERITY__")
  89
  90 # gcov
  91 list(APPEND BUILD_TYPES "gcov")
  92 string(CONCAT CMAKE_C_FLAGS_GCOV
  93   "-O0 "
  94   "-DCLIB_DEBUG "
  95   "-DCLIB_GCOV "
  96   "-fprofile-arcs "
  97   "-ftest-coverage ")
  98
  99 string(TOUPPER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_UC)
 100
 101
 102 string(REPLACE ";" " " BUILD_TYPES "${BUILD_TYPES}")
 103 set_property(CACHE CMAKE_BUILD_TYPE PROPERTY
 104              HELPSTRING "Build type - valid options are: ${BUILD_TYPES}")
 105
 106 ##############################################################################
 107 # sanitizers
 108 ##############################################################################
 109
 110 option(ENABLE_SANITIZE_ADDR "Enable Address Sanitizer" OFF)
 111 if (ENABLE_SANITIZE_ADDR)
 112   set(CMAKE_C_FLAGS "-fsanitize=address --param asan-stack=0 -DCLIB_SANITIZE_ADDR ${CMAKE_C_FLAGS}")
 113   set(CMAKE_EXE_LINKER_FLAGS "-fsanitize=address ${CMAKE_EXE_LINKER_FLAGS}")
 114   set(CMAKE_SHARED_LINKER_FLAGS "-fsanitize=address ${CMAKE_SHARED_LINKER_FLAGS}")
 115 endif (ENABLE_SANITIZE_ADDR)
 116
 117 ##############################################################################
 118 # install config
 119 ##############################################################################
 120 set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib")
 121 set(CMAKE_INSTALL_MESSAGE NEVER)
 122
 123 include_directories (
 124         ${CMAKE_SOURCE_DIR}
 125         ${CMAKE_BINARY_DIR}
 126         ${CMAKE_BINARY_DIR}/include
 127 )
 128 set(CMAKE_INSTALL_DEFAULT_COMPONENT_NAME "vpp")
 129
 130 set(THREADS_PREFER_PTHREAD_FLAG ON)
 131 find_package(Threads REQUIRED)
 132
 133 include(cmake/syscall.cmake)
 134 include(cmake/api.cmake)
 135 include(cmake/library.cmake)
 136 include(cmake/exec.cmake)
 137 include(cmake/plugin.cmake)
 138
 139 ##############################################################################
 140 # subdirs - order matters
 141 ##############################################################################
 142 if("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
 143   find_package(OpenSSL REQUIRED)
 144   set(SUBDIRS
 145     vppinfra svm vlib vlibmemory vlibapi vnet vpp vat vcl plugins
 146     vpp-api tools/vppapigen tools/g2 tools/elftool tools/perftool cmake pkg
 147     tools/appimage
 148   )
 149 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
 150   set(SUBDIRS vppinfra)
 151 else()
 152   message(FATAL_ERROR "Unsupported system: ${CMAKE_SYSTEM_NAME}")
 153 endif()
 154
 155 foreach(DIR ${SUBDIRS})
 156   add_subdirectory(${DIR})
 157 endforeach()
 158
 159 ##############################################################################
 160 # detect if we are inside git repo and add configure dependency
 161 ##############################################################################
 162 execute_process(
 163   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 164   COMMAND git rev-parse --show-toplevel
 165   OUTPUT_VARIABLE VPP_GIT_TOPLEVEL_DIR
 166   OUTPUT_STRIP_TRAILING_WHITESPACE
 167   ERROR_QUIET
 168 )
 169
 170 if (VPP_GIT_TOPLEVEL_DIR)
 171   set_property(
 172     DIRECTORY APPEND PROPERTY
 173     CMAKE_CONFIGURE_DEPENDS ${VPP_GIT_TOPLEVEL_DIR}/.git/index
 174   )
 175 endif()
 176
 177 ##############################################################################
 178 # print configuration
 179 ##############################################################################
 180 message(STATUS "Configuration:")
 181 pr("VPP version" "${VPP_VERSION}")
 182 pr("VPP library version" "${VPP_LIB_VERSION}")
 183 pr("GIT toplevel dir" "${VPP_GIT_TOPLEVEL_DIR}")
 184 pr("Build type" "${CMAKE_BUILD_TYPE}")
 185 pr("C flags" "${CMAKE_C_FLAGS}${CMAKE_C_FLAGS_${CMAKE_BUILD_TYPE_UC}}")
 186 pr("Linker flags (apps)" "${CMAKE_EXE_LINKER_FLAGS}${CMAKE_EXE_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}}")
 187 pr("Linker flags (libs)" "${CMAKE_SHARED_LINKER_FLAGS}${CMAKE_SHARED_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}}")
 188 pr("Host processor" "${CMAKE_HOST_SYSTEM_PROCESSOR}")
 189 pr("Target processor" "${CMAKE_SYSTEM_PROCESSOR}")
 190 pr("Prefix path" "${CMAKE_PREFIX_PATH}")
 191 pr("Install prefix" "${CMAKE_INSTALL_PREFIX}")