src/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 cmake_minimum_required(VERSION 3.5 FATAL_ERROR)
  15
  16 project(vpp C)
  17
  18 include(CheckCCompilerFlag)
  19 include(cmake/misc.cmake)
  20 include(cmake/cpu.cmake)
  21 include(cmake/ccache.cmake)
  22
  23 ##############################################################################
  24 # VPP Version
  25 ##############################################################################
  26 execute_process(
  27   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  28   COMMAND scripts/version
  29   OUTPUT_VARIABLE VPP_VERSION
  30   OUTPUT_STRIP_TRAILING_WHITESPACE
  31 )
  32 string(REPLACE "-" ";" VPP_LIB_VERSION ${VPP_VERSION})
  33 list(GET VPP_LIB_VERSION 0 VPP_LIB_VERSION)
  34
  35 ##############################################################################
  36 # cross compiling
  37 ##############################################################################
  38 if(CMAKE_CROSSCOMPILING)
  39   set(CMAKE_IGNORE_PATH
  40     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/
  41     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/lib/
  42   )
  43 endif()
  44 set(CMAKE_C_COMPILER_TARGET ${CMAKE_SYSTEM_PROCESSOR}-linux-gnu)
  45
  46 ##############################################################################
  47 # build config
  48 ##############################################################################
  49 check_c_compiler_flag("-Wno-address-of-packed-member"
  50                       compiler_flag_no_address_of_packed_member)
  51
  52 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  53 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  54
  55 if (CMAKE_BUILD_TYPE)
  56   set(CMAKE_C_FLAGS "-g -fPIC -Werror -Wall ${CMAKE_C_FLAGS}")
  57 endif()
  58
  59 if (compiler_flag_no_address_of_packed_member)
  60   set(CMAKE_C_FLAGS "-Wno-address-of-packed-member ${CMAKE_C_FLAGS}")
  61 endif()
  62
  63 # release
  64 list(APPEND BUILD_TYPES "release")
  65 string(CONCAT CMAKE_C_FLAGS_RELEASE
  66   "-O2 "
  67   "-fstack-protector "
  68   "-DFORTIFY_SOURCE=2 "
  69   "-fno-common "
  70 )
  71
  72 string(CONCAT CMAKE_EXE_LINKER_FLAGS_RELEASE "-pie")
  73
  74 # debug
  75 list(APPEND BUILD_TYPES "debug")
  76 string(CONCAT CMAKE_C_FLAGS_DEBUG
  77   "-O0 "
  78   "-DCLIB_DEBUG "
  79   "-fstack-protector "
  80   "-DFORTIFY_SOURCE=2 "
  81   "-fno-common "
  82 )
  83
  84 # coverity
  85 list(APPEND BUILD_TYPES "coverity")
  86 string(CONCAT CMAKE_C_FLAGS_COVERITY "-O2 -D__COVERITY__")
  87
  88 # gcov
  89 list(APPEND BUILD_TYPES "gcov")
  90 string(CONCAT CMAKE_C_FLAGS_GCOV
  91   "-O0 "
  92   "-DCLIB_DEBUG "
  93   "-DCLIB_GCOV "
  94   "-fprofile-arcs "
  95   "-ftest-coverage ")
  96
  97 string(TOUPPER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_UC)
  98
  99
 100 string(REPLACE ";" " " BUILD_TYPES "${BUILD_TYPES}")
 101 set_property(CACHE CMAKE_BUILD_TYPE PROPERTY
 102              HELPSTRING "Build type - valid options are: ${BUILD_TYPES}")
 103
 104 ##############################################################################
 105 # install config
 106 ##############################################################################
 107 set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib")
 108 set(CMAKE_INSTALL_MESSAGE NEVER)
 109
 110 include_directories (
 111         ${CMAKE_SOURCE_DIR}
 112         ${CMAKE_BINARY_DIR}
 113         ${CMAKE_BINARY_DIR}/include
 114 )
 115 set(CMAKE_INSTALL_DEFAULT_COMPONENT_NAME "vpp")
 116
 117 set(THREADS_PREFER_PTHREAD_FLAG ON)
 118 find_package(Threads REQUIRED)
 119
 120 include(cmake/syscall.cmake)
 121 include(cmake/api.cmake)
 122 include(cmake/library.cmake)
 123 include(cmake/exec.cmake)
 124 include(cmake/plugin.cmake)
 125
 126 ##############################################################################
 127 # subdirs - order matters
 128 ##############################################################################
 129 if("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
 130   find_package(OpenSSL REQUIRED)
 131   set(SUBDIRS
 132     vppinfra svm vlib vlibmemory vlibapi vnet vpp vat vcl plugins
 133     vpp-api tools/vppapigen tools/g2 tools/elftool tools/perftool cmake pkg
 134     tools/appimage
 135   )
 136 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
 137   set(SUBDIRS vppinfra)
 138 else()
 139   message(FATAL_ERROR "Unsupported system: ${CMAKE_SYSTEM_NAME}")
 140 endif()
 141
 142 foreach(DIR ${SUBDIRS})
 143   add_subdirectory(${DIR})
 144 endforeach()
 145
 146 ##############################################################################
 147 # detect if we are inside git repo and add configure dependency
 148 ##############################################################################
 149 execute_process(
 150   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 151   COMMAND git rev-parse --show-toplevel
 152   OUTPUT_VARIABLE VPP_GIT_TOPLEVEL_DIR
 153   OUTPUT_STRIP_TRAILING_WHITESPACE
 154   ERROR_QUIET
 155 )
 156
 157 if (VPP_GIT_TOPLEVEL_DIR)
 158   set_property(
 159     DIRECTORY APPEND PROPERTY
 160     CMAKE_CONFIGURE_DEPENDS ${VPP_GIT_TOPLEVEL_DIR}/.git/index
 161   )
 162 endif()
 163
 164 ##############################################################################
 165 # print configuration
 166 ##############################################################################
 167 message(STATUS "Configuration:")
 168 pr("VPP version" "${VPP_VERSION}")
 169 pr("VPP library version" "${VPP_LIB_VERSION}")
 170 pr("GIT toplevel dir" "${VPP_GIT_TOPLEVEL_DIR}")
 171 pr("Build type" "${CMAKE_BUILD_TYPE}")
 172 pr("C flags" "${CMAKE_C_FLAGS}${CMAKE_C_FLAGS_${CMAKE_BUILD_TYPE_UC}}")
 173 pr("Linker flags (apps)" "${CMAKE_EXE_LINKER_FLAGS}${CMAKE_EXE_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}}")
 174 pr("Linker flags (libs)" "${CMAKE_SHARED_LINKER_FLAGS}${CMAKE_SHARED_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}}")
 175 pr("Host processor" "${CMAKE_HOST_SYSTEM_PROCESSOR}")
 176 pr("Target processor" "${CMAKE_SYSTEM_PROCESSOR}")
 177 pr("Prefix path" "${CMAKE_PREFIX_PATH}")
 178 pr("Install prefix" "${CMAKE_INSTALL_PREFIX}")