src/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 cmake_minimum_required(VERSION 3.10)
  15
  16 set(CMAKE_C_COMPILER_NAMES clang-11 clang-10 clang-9 gcc-10 gcc-9 cc)
  17
  18 project(vpp C)
  19
  20 include(CheckCCompilerFlag)
  21 include(CheckIPOSupported)
  22 include(cmake/misc.cmake)
  23 include(cmake/cpu.cmake)
  24 include(cmake/ccache.cmake)
  25
  26 ##############################################################################
  27 # VPP Version
  28 ##############################################################################
  29 execute_process(
  30   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  31   COMMAND scripts/version
  32   OUTPUT_VARIABLE VPP_VERSION
  33   OUTPUT_STRIP_TRAILING_WHITESPACE
  34 )
  35 string(REPLACE "-" ";" VPP_LIB_VERSION ${VPP_VERSION})
  36 list(GET VPP_LIB_VERSION 0 VPP_LIB_VERSION)
  37
  38 ##############################################################################
  39 # cross compiling
  40 ##############################################################################
  41 if(CMAKE_CROSSCOMPILING)
  42   set(CMAKE_IGNORE_PATH
  43     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/
  44     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/lib/
  45   )
  46 endif()
  47 set(CMAKE_C_COMPILER_TARGET ${CMAKE_SYSTEM_PROCESSOR}-linux-gnu)
  48
  49 ##############################################################################
  50 # build config
  51 ##############################################################################
  52 check_c_compiler_flag("-Wno-address-of-packed-member"
  53                       compiler_flag_no_address_of_packed_member)
  54 set(VPP_RUNTIME_DIR "bin" CACHE STRING "Relative runtime directory path")
  55 set(VPP_LIBRARY_DIR "lib" CACHE STRING "Relative library directory path")
  56
  57 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_RUNTIME_DIR})
  58 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_LIBRARY_DIR})
  59
  60 if (CMAKE_BUILD_TYPE)
  61   set(CMAKE_C_FLAGS "-g -fPIC -Werror -Wall ${CMAKE_C_FLAGS}")
  62 endif()
  63
  64 if (compiler_flag_no_address_of_packed_member)
  65   set(CMAKE_C_FLAGS "-Wno-address-of-packed-member ${CMAKE_C_FLAGS}")
  66 endif()
  67
  68 # release
  69 list(APPEND BUILD_TYPES "release")
  70 string(CONCAT CMAKE_C_FLAGS_RELEASE
  71   "-O2 "
  72   "-fstack-protector "
  73   "-DFORTIFY_SOURCE=2 "
  74   "-fno-common "
  75 )
  76
  77 string(CONCAT CMAKE_EXE_LINKER_FLAGS_RELEASE "-pie")
  78
  79 # debug
  80 list(APPEND BUILD_TYPES "debug")
  81 string(CONCAT CMAKE_C_FLAGS_DEBUG
  82   "-O0 "
  83   "-DCLIB_DEBUG "
  84   "-fstack-protector "
  85   "-DFORTIFY_SOURCE=2 "
  86   "-fno-common "
  87 )
  88
  89 # coverity
  90 list(APPEND BUILD_TYPES "coverity")
  91 string(CONCAT CMAKE_C_FLAGS_COVERITY "-O2 -D__COVERITY__")
  92
  93 # gcov
  94 list(APPEND BUILD_TYPES "gcov")
  95 string(CONCAT CMAKE_C_FLAGS_GCOV
  96   "-O0 "
  97   "-DCLIB_DEBUG "
  98   "-DCLIB_GCOV "
  99   "-fprofile-arcs "
 100   "-ftest-coverage ")
 101
 102 string(TOUPPER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_UC)
 103
 104
 105 string(REPLACE ";" " " BUILD_TYPES "${BUILD_TYPES}")
 106 set_property(CACHE CMAKE_BUILD_TYPE PROPERTY
 107              HELPSTRING "Build type - valid options are: ${BUILD_TYPES}")
 108
 109 ##############################################################################
 110 # link time optimizations
 111 ##############################################################################
 112 if (CMAKE_BUILD_TYPE_UC STREQUAL "RELEASE")
 113   check_ipo_supported(RESULT _result)
 114   if (_result)
 115     option(VPP_USE_LTO "Link time optimization of release binaries" ON)
 116   endif()
 117 endif()
 118
 119 ##############################################################################
 120 # sanitizers
 121 ##############################################################################
 122
 123 option(VPP_ENABLE_SANITIZE_ADDR "Enable Address Sanitizer" OFF)
 124 set(VPP_SANITIZE_ADDR_OPTIONS
 125   "unmap_shadow_on_exit=1:disable_coredump=0:abort_on_error=1:detect_leaks=0"
 126   CACHE
 127   STRING "Address sanitizer arguments"
 128 )
 129
 130 if (VPP_ENABLE_SANITIZE_ADDR)
 131   set(CMAKE_C_FLAGS "-fsanitize=address -DCLIB_SANITIZE_ADDR ${CMAKE_C_FLAGS}")
 132   set(CMAKE_EXE_LINKER_FLAGS "-fsanitize=address ${CMAKE_EXE_LINKER_FLAGS}")
 133   set(CMAKE_SHARED_LINKER_FLAGS "-fsanitize=address ${CMAKE_SHARED_LINKER_FLAGS}")
 134 endif (VPP_ENABLE_SANITIZE_ADDR)
 135
 136 ##############################################################################
 137 # install config
 138 ##############################################################################
 139 set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib")
 140 set(CMAKE_INSTALL_MESSAGE NEVER)
 141
 142 include_directories (
 143         ${CMAKE_SOURCE_DIR}
 144         ${CMAKE_BINARY_DIR}
 145         ${CMAKE_BINARY_DIR}/include
 146 )
 147 set(CMAKE_INSTALL_DEFAULT_COMPONENT_NAME "vpp")
 148
 149 set(THREADS_PREFER_PTHREAD_FLAG ON)
 150 find_package(Threads REQUIRED)
 151
 152 include(cmake/syscall.cmake)
 153 include(cmake/api.cmake)
 154 include(cmake/library.cmake)
 155 include(cmake/exec.cmake)
 156 include(cmake/plugin.cmake)
 157
 158 ##############################################################################
 159 # subdirs - order matters
 160 ##############################################################################
 161 option(VPP_HOST_TOOLS_ONLY "Build only host tools" OFF)
 162 if(VPP_HOST_TOOLS_ONLY)
 163   set(SUBDIRS tools/vppapigen cmake)
 164 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
 165   find_package(OpenSSL REQUIRED)
 166   set(SUBDIRS
 167     vppinfra svm vlib vlibmemory vlibapi vnet vpp vat vat2 vcl plugins
 168     vpp-api tools/vppapigen tools/g2 tools/perftool cmake pkg
 169     tools/appimage
 170   )
 171 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
 172   set(SUBDIRS vppinfra)
 173 else()
 174   message(FATAL_ERROR "Unsupported system: ${CMAKE_SYSTEM_NAME}")
 175 endif()
 176
 177 foreach(DIR ${SUBDIRS})
 178   add_subdirectory(${DIR})
 179 endforeach()
 180
 181 ##############################################################################
 182 # detect if we are inside git repo and add configure dependency
 183 ##############################################################################
 184 execute_process(
 185   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 186   COMMAND git rev-parse --show-toplevel
 187   OUTPUT_VARIABLE VPP_GIT_TOPLEVEL_DIR
 188   OUTPUT_STRIP_TRAILING_WHITESPACE
 189   ERROR_QUIET
 190 )
 191
 192 if (VPP_GIT_TOPLEVEL_DIR)
 193   set_property(
 194     DIRECTORY APPEND PROPERTY
 195     CMAKE_CONFIGURE_DEPENDS ${VPP_GIT_TOPLEVEL_DIR}/.git/index
 196   )
 197 endif()
 198
 199 ##############################################################################
 200 # print configuration
 201 ##############################################################################
 202 message(STATUS "Configuration:")
 203 pr("VPP version" "${VPP_VERSION}")
 204 pr("VPP library version" "${VPP_LIB_VERSION}")
 205 pr("GIT toplevel dir" "${VPP_GIT_TOPLEVEL_DIR}")
 206 pr("Build type" "${CMAKE_BUILD_TYPE}")
 207 pr("C flags" "${CMAKE_C_FLAGS}${CMAKE_C_FLAGS_${CMAKE_BUILD_TYPE_UC}}")
 208 pr("Linker flags (apps)" "${CMAKE_EXE_LINKER_FLAGS}${CMAKE_EXE_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}}")
 209 pr("Linker flags (libs)" "${CMAKE_SHARED_LINKER_FLAGS}${CMAKE_SHARED_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}}")
 210 pr("Host processor" "${CMAKE_HOST_SYSTEM_PROCESSOR}")
 211 pr("Target processor" "${CMAKE_SYSTEM_PROCESSOR}")
 212 pr("Prefix path" "${CMAKE_PREFIX_PATH}")
 213 pr("Install prefix" "${CMAKE_INSTALL_PREFIX}")