src/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 cmake_minimum_required(VERSION 3.10)
  15
  16 set(CMAKE_C_COMPILER_NAMES
  17   clang-12
  18   clang-11
  19   clang-10
  20   clang-9
  21   gcc-10
  22   gcc-9
  23   cc
  24 )
  25
  26 project(vpp C)
  27
  28 if(CMAKE_VERSION VERSION_LESS 3.12)
  29   macro(add_compile_definitions defs)
  30     foreach(d ${defs})
  31       add_compile_options(-D${d})
  32     endforeach()
  33   endmacro()
  34 endif()
  35
  36 include(CheckCCompilerFlag)
  37 include(CheckIPOSupported)
  38 include(GNUInstallDirs)
  39 include(cmake/misc.cmake)
  40 include(cmake/cpu.cmake)
  41 include(cmake/ccache.cmake)
  42
  43 ##############################################################################
  44 # VPP Version
  45 ##############################################################################
  46 execute_process(
  47   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  48   COMMAND scripts/version
  49   OUTPUT_VARIABLE VPP_VERSION
  50   OUTPUT_STRIP_TRAILING_WHITESPACE
  51 )
  52 string(REPLACE "-" ";" VPP_LIB_VERSION ${VPP_VERSION})
  53 list(GET VPP_LIB_VERSION 0 VPP_LIB_VERSION)
  54
  55 ##############################################################################
  56 # cross compiling
  57 ##############################################################################
  58 if(CMAKE_CROSSCOMPILING)
  59   set(CMAKE_IGNORE_PATH
  60     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/
  61     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/lib/
  62   )
  63 endif()
  64 set(CMAKE_C_COMPILER_TARGET ${CMAKE_SYSTEM_PROCESSOR}-linux-gnu)
  65
  66 ##############################################################################
  67 # build config
  68 ##############################################################################
  69 check_c_compiler_flag("-Wno-address-of-packed-member"
  70                       compiler_flag_no_address_of_packed_member)
  71 set(VPP_RUNTIME_DIR ${CMAKE_INSTALL_BINDIR} CACHE STRING "Relative runtime directory path")
  72 set(VPP_LIBRARY_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING "Relative library directory path")
  73
  74 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_RUNTIME_DIR})
  75 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_LIBRARY_DIR})
  76 set(VPP_BINARY_DIR ${CMAKE_BINARY_DIR}/CMakeFiles)
  77 set(PYENV PYTHONPYCACHEPREFIX=${CMAKE_BINARY_DIR}/CMakeFile/__pycache__)
  78
  79 if (CMAKE_BUILD_TYPE)
  80   add_compile_options(-g -fPIC -Werror -Wall)
  81 endif()
  82
  83 if (compiler_flag_no_address_of_packed_member)
  84   add_compile_options(-Wno-address-of-packed-member)
  85 endif()
  86
  87 string(TOLOWER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_LC)
  88 string(TOUPPER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_UC)
  89
  90 set(CMAKE_C_FLAGS_RELEASE "")
  91 set(CMAKE_C_FLAGS_DEBUG "")
  92
  93 if (${CMAKE_BUILD_TYPE_LC} MATCHES "release")
  94   add_compile_options(-O3 -fstack-protector -fno-common)
  95   add_compile_definitions(_FORTIFY_SOURCE=2)
  96   set(CMAKE_EXE_LINKER_FLAGS_RELEASE "-pie")
  97 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "debug")
  98   add_compile_options(-O0 -fstack-protector -fno-common)
  99   add_compile_definitions(CLIB_DEBUG)
 100 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "coverity")
 101   add_compile_options(-O0)
 102   add_compile_definitions(__COVERITY__)
 103 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "gcov")
 104   add_compile_options(-O0 -fprofile-arcs -ftest-coverage)
 105   add_compile_definitions(CLIB_DEBUG CLIB_GCOV)
 106 endif()
 107
 108 set(BUILD_TYPES release debug coverity gcov)
 109 string(REPLACE ";" " " BUILD_TYPES_STR "${BUILD_TYPES}")
 110 set_property(CACHE CMAKE_BUILD_TYPE PROPERTY
 111              HELPSTRING "Build type - valid options are: ${BUILD_TYPES_STR}")
 112
 113 ##############################################################################
 114 # link time optimizations
 115 ##############################################################################
 116 if (CMAKE_BUILD_TYPE_UC STREQUAL "RELEASE")
 117   check_ipo_supported(RESULT _result)
 118   if (_result)
 119     option(VPP_USE_LTO "Link time optimization of release binaries" ON)
 120   endif()
 121 endif()
 122
 123 ##############################################################################
 124 # sanitizers
 125 ##############################################################################
 126
 127 option(VPP_ENABLE_SANITIZE_ADDR "Enable Address Sanitizer" OFF)
 128 set(VPP_SANITIZE_ADDR_OPTIONS
 129   "unmap_shadow_on_exit=1:disable_coredump=0:abort_on_error=1:detect_leaks=0"
 130   CACHE
 131   STRING "Address sanitizer arguments"
 132 )
 133
 134 if (VPP_ENABLE_SANITIZE_ADDR)
 135   add_compile_options(-fsanitize=address)
 136   add_compile_definitions(CLIB_SANITIZE_ADDR)
 137   set(CMAKE_EXE_LINKER_FLAGS "-fsanitize=address ${CMAKE_EXE_LINKER_FLAGS}")
 138   set(CMAKE_SHARED_LINKER_FLAGS "-fsanitize=address ${CMAKE_SHARED_LINKER_FLAGS}")
 139 endif (VPP_ENABLE_SANITIZE_ADDR)
 140
 141 ##############################################################################
 142 # trajectory trace
 143 ##############################################################################
 144
 145 option(VPP_ENABLE_TRAJECTORY_TRACE "Build vpp with trajectory tracing enabled" OFF)
 146 if(VPP_ENABLE_TRAJECTORY_TRACE)
 147   add_compile_definitions(VLIB_BUFFER_TRACE_TRAJECTORY=1)
 148 endif()
 149
 150 ##############################################################################
 151 # install config
 152 ##############################################################################
 153 option(VPP_SET_RPATH "Set rpath for resulting binaries and libraries." ON)
 154 if(VPP_SET_RPATH)
 155   set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib")
 156 endif()
 157 set(CMAKE_INSTALL_MESSAGE NEVER)
 158
 159 include_directories (
 160         ${CMAKE_SOURCE_DIR}
 161         ${VPP_BINARY_DIR}
 162 )
 163 set(CMAKE_INSTALL_DEFAULT_COMPONENT_NAME "vpp")
 164
 165 set(THREADS_PREFER_PTHREAD_FLAG ON)
 166 find_package(Threads REQUIRED)
 167
 168 include(cmake/syscall.cmake)
 169 include(cmake/api.cmake)
 170 include(cmake/library.cmake)
 171 include(cmake/exec.cmake)
 172 include(cmake/plugin.cmake)
 173
 174 ##############################################################################
 175 # subdirs - order matters
 176 ##############################################################################
 177 option(VPP_HOST_TOOLS_ONLY "Build only host tools" OFF)
 178 if(VPP_HOST_TOOLS_ONLY)
 179   set(SUBDIRS tools/vppapigen cmake)
 180 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
 181   find_package(OpenSSL)
 182   set(SUBDIRS
 183     vppinfra svm vlib vlibmemory vlibapi vnet vpp vat vat2 vcl plugins
 184     vpp-api tools/vppapigen tools/g2 tools/perftool cmake pkg
 185     tools/appimage
 186   )
 187 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
 188   set(SUBDIRS vppinfra)
 189 else()
 190   message(FATAL_ERROR "Unsupported system: ${CMAKE_SYSTEM_NAME}")
 191 endif()
 192
 193 foreach(DIR ${SUBDIRS})
 194   add_subdirectory(${DIR} ${VPP_BINARY_DIR}/${DIR})
 195 endforeach()
 196
 197 ##############################################################################
 198 # detect if we are inside git repo and add configure dependency
 199 ##############################################################################
 200 execute_process(
 201   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 202   COMMAND git rev-parse --show-toplevel
 203   OUTPUT_VARIABLE VPP_GIT_TOPLEVEL_DIR
 204   OUTPUT_STRIP_TRAILING_WHITESPACE
 205   ERROR_QUIET
 206 )
 207
 208 if (VPP_GIT_TOPLEVEL_DIR)
 209   set_property(
 210     DIRECTORY APPEND PROPERTY
 211     CMAKE_CONFIGURE_DEPENDS ${VPP_GIT_TOPLEVEL_DIR}/.git/index
 212   )
 213 endif()
 214
 215 ##############################################################################
 216 # custom targets
 217 ##############################################################################
 218
 219 add_custom_target(run
 220   COMMAND ./${VPP_RUNTIME_DIR}/vpp -c startup.conf
 221   COMMENT "Starting VPP..."
 222   USES_TERMINAL
 223 )
 224
 225 add_custom_target(debug
 226   COMMAND gdb --args ./${VPP_RUNTIME_DIR}/vpp -c startup.conf
 227   COMMENT "Starting VPP in the debugger..."
 228   USES_TERMINAL
 229 )
 230
 231 add_custom_target(config
 232   COMMAND ccmake ${CMAKE_BINARY_DIR}
 233   COMMENT "Starting Configuration TUI..."
 234   USES_TERMINAL
 235 )
 236
 237 foreach(bt ${BUILD_TYPES})
 238   add_custom_target(set-build-type-${bt}
 239     COMMAND cmake -DCMAKE_BUILD_TYPE:STRING=${bt} .
 240     COMMENT "Changing build type to ${bt}"
 241     USES_TERMINAL
 242   )
 243 endforeach()
 244
 245 mark_as_advanced(CLEAR
 246   CMAKE_C_FLAGS
 247   CMAKE_C_COMPILER
 248   CMAKE_EXPORT_COMPILE_COMMANDS
 249   CMAKE_INSTALL_PREFIX
 250   CMAKE_LINKER
 251   CMAKE_SHARED_LINKER_FLAGS
 252   CMAKE_VERBOSE_MAKEFILE
 253 )
 254
 255 ##############################################################################
 256 # print configuration
 257 ##############################################################################
 258 message(STATUS "Configuration:")
 259 pr("VPP version" ${VPP_VERSION})
 260 pr("VPP library version" ${VPP_LIB_VERSION})
 261 pr("GIT toplevel dir" ${VPP_GIT_TOPLEVEL_DIR})
 262 pr("Build type" ${CMAKE_BUILD_TYPE})
 263 pr("C flags" ${CMAKE_C_FLAGS}${CMAKE_C_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 264 pr("Linker flags (apps)" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 265 pr("Linker flags (libs)" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 266 pr("Host processor" ${CMAKE_HOST_SYSTEM_PROCESSOR})
 267 pr("Target processor" ${CMAKE_SYSTEM_PROCESSOR})
 268 pr("Prefix path" ${CMAKE_PREFIX_PATH})
 269 pr("Install prefix" ${CMAKE_INSTALL_PREFIX})