src/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 cmake_minimum_required(VERSION 3.5 FATAL_ERROR)
  15
  16 project(vpp C)
  17
  18 include(CheckCCompilerFlag)
  19 include(cmake/misc.cmake)
  20 include(cmake/cpu.cmake)
  21 include(cmake/ccache.cmake)
  22
  23 ##############################################################################
  24 # VPP Version
  25 ##############################################################################
  26 execute_process(
  27   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  28   COMMAND scripts/version
  29   OUTPUT_VARIABLE VPP_VERSION
  30   OUTPUT_STRIP_TRAILING_WHITESPACE
  31 )
  32 string(REPLACE "-" ";" VPP_LIB_VERSION ${VPP_VERSION})
  33 list(GET VPP_LIB_VERSION 0 VPP_LIB_VERSION)
  34
  35 ##############################################################################
  36 # cross compiling
  37 ##############################################################################
  38 if(CMAKE_CROSSCOMPILING)
  39   set(CMAKE_IGNORE_PATH
  40     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/
  41     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/lib/
  42   )
  43 endif()
  44 set(CMAKE_C_COMPILER_TARGET ${CMAKE_SYSTEM_PROCESSOR}-linux-gnu)
  45
  46 ##############################################################################
  47 # build config
  48 ##############################################################################
  49 check_c_compiler_flag("-Wno-address-of-packed-member"
  50                       compiler_flag_no_address_of_packed_member)
  51
  52 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  53 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  54
  55 if (CMAKE_BUILD_TYPE)
  56   set(CMAKE_C_FLAGS "-g -fPIC -Werror -Wall ${CMAKE_C_FLAGS}")
  57 endif()
  58
  59 if (compiler_flag_no_address_of_packed_member)
  60   set(CMAKE_C_FLAGS "-Wno-address-of-packed-member ${CMAKE_C_FLAGS}")
  61 endif()
  62
  63 # release
  64 string(CONCAT CMAKE_C_FLAGS_RELEASE
  65   "-O2 "
  66   "-fstack-protector "
  67   "-DFORTIFY_SOURCE=2 "
  68   "-fno-common "
  69 )
  70
  71 string(CONCAT CMAKE_EXE_LINKER_FLAGS_RELEASE "-pie")
  72
  73 # debug
  74 string(CONCAT CMAKE_C_FLAGS_DEBUG
  75   "-O0 "
  76   "-DCLIB_DEBUG "
  77   "-fstack-protector "
  78   "-DFORTIFY_SOURCE=2 "
  79   "-fno-common "
  80 )
  81
  82 # coverity
  83 string(CONCAT CMAKE_C_FLAGS_COVERITY "-O2 -D__COVERITY__")
  84
  85 # gcov
  86 string(CONCAT CMAKE_C_FLAGS_GCOV
  87   "-O0 "
  88   "-DCLIB_DEBUG "
  89   "-DCLIB_GCOV "
  90   "-fprofile-arcs "
  91   "-ftest-coverage ")
  92
  93 string(TOUPPER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_UC)
  94
  95 ##############################################################################
  96 # install config
  97 ##############################################################################
  98 set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib")
  99 set(CMAKE_INSTALL_MESSAGE NEVER)
 100
 101 include_directories (
 102         ${CMAKE_SOURCE_DIR}
 103         ${CMAKE_BINARY_DIR}
 104         ${CMAKE_BINARY_DIR}/include
 105 )
 106 set(CMAKE_INSTALL_DEFAULT_COMPONENT_NAME "vpp")
 107
 108 set(THREADS_PREFER_PTHREAD_FLAG ON)
 109 find_package(Threads REQUIRED)
 110
 111 include(cmake/syscall.cmake)
 112 include(cmake/api.cmake)
 113 include(cmake/library.cmake)
 114 include(cmake/exec.cmake)
 115 include(cmake/plugin.cmake)
 116
 117 ##############################################################################
 118 # subdirs - order matters
 119 ##############################################################################
 120 if("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
 121   find_package(OpenSSL REQUIRED)
 122   set(SUBDIRS
 123     vppinfra svm vlib vlibmemory vlibapi vnet vpp vat vcl plugins
 124     vpp-api tools/vppapigen tools/g2 tools/elftool tools/perftool cmake pkg
 125     tools/appimage
 126   )
 127 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
 128   set(SUBDIRS vppinfra)
 129 else()
 130   message(FATAL_ERROR "Unsupported system: ${CMAKE_SYSTEM_NAME}")
 131 endif()
 132
 133 foreach(DIR ${SUBDIRS})
 134   add_subdirectory(${DIR})
 135 endforeach()
 136
 137 ##############################################################################
 138 # detect if we are inside git repo and add configure dependency
 139 ##############################################################################
 140 execute_process(
 141   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 142   COMMAND git rev-parse --show-toplevel
 143   OUTPUT_VARIABLE VPP_GIT_TOPLEVEL_DIR
 144   OUTPUT_STRIP_TRAILING_WHITESPACE
 145   ERROR_QUIET
 146 )
 147
 148 if (VPP_GIT_TOPLEVEL_DIR)
 149   set_property(
 150     DIRECTORY APPEND PROPERTY
 151     CMAKE_CONFIGURE_DEPENDS ${VPP_GIT_TOPLEVEL_DIR}/.git/index
 152   )
 153 endif()
 154
 155 ##############################################################################
 156 # print configuration
 157 ##############################################################################
 158 message(STATUS "Configuration:")
 159 pr("VPP version" "${VPP_VERSION}")
 160 pr("VPP library version" "${VPP_LIB_VERSION}")
 161 pr("GIT toplevel dir" "${VPP_GIT_TOPLEVEL_DIR}")
 162 pr("Build type" "${CMAKE_BUILD_TYPE}")
 163 pr("C flags" "${CMAKE_C_FLAGS}${CMAKE_C_FLAGS_${CMAKE_BUILD_TYPE_UC}}")
 164 pr("Linker flags (apps)" "${CMAKE_EXE_LINKER_FLAGS}${CMAKE_EXE_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}}")
 165 pr("Linker flags (libs)" "${CMAKE_SHARED_LINKER_FLAGS}${CMAKE_SHARED_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}}")
 166 pr("Host processor" "${CMAKE_HOST_SYSTEM_PROCESSOR}")
 167 pr("Target processor" "${CMAKE_SYSTEM_PROCESSOR}")
 168 pr("Prefix path" "${CMAKE_PREFIX_PATH}")
 169 pr("Install prefix" "${CMAKE_INSTALL_PREFIX}")