src/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 cmake_minimum_required(VERSION 3.5 FATAL_ERROR)
  15
  16 project(vpp C)
  17
  18 include(CheckCCompilerFlag)
  19 include(cmake/message.cmake)
  20 include(cmake/cpu.cmake)
  21 include(cmake/ccache.cmake)
  22
  23 ##############################################################################
  24 # VPP Version
  25 ##############################################################################
  26 execute_process(
  27   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  28   COMMAND scripts/version
  29   OUTPUT_VARIABLE VPP_VERSION
  30   OUTPUT_STRIP_TRAILING_WHITESPACE
  31 )
  32 string(REPLACE "-" ";" VPP_LIB_VERSION ${VPP_VERSION})
  33 list(GET VPP_LIB_VERSION 0 VPP_LIB_VERSION)
  34
  35 ##############################################################################
  36 # build config
  37 ##############################################################################
  38 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  39 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  40 set(CMAKE_C_FLAGS_COMMON "-DFORTIFY_SOURCE=2 -fstack-protector-all -Werror")
  41 set(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} ${CMAKE_C_FLAGS_COMMON} -DCLIB_DEBUG")
  42 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${CMAKE_C_FLAGS_COMMON}")
  43
  44 check_c_compiler_flag("-Wno-address-of-packed-member" compiler_flag_no_address_of_packed_member)
  45 if (compiler_flag_no_address_of_packed_member)
  46   add_definitions(-Wno-address-of-packed-member)
  47 endif()
  48
  49 ##############################################################################
  50 # install config
  51 ##############################################################################
  52 set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${VPP_LIB_DIR_NAME}")
  53 set(CMAKE_INSTALL_MESSAGE NEVER)
  54
  55 include_directories (
  56         ${CMAKE_SOURCE_DIR}
  57         ${CMAKE_BINARY_DIR}
  58         ${CMAKE_BINARY_DIR}/include
  59 )
  60 set(CMAKE_INSTALL_DEFAULT_COMPONENT_NAME "vpp")
  61
  62 set(THREADS_PREFER_PTHREAD_FLAG ON)
  63 find_package(Threads REQUIRED)
  64 find_package(OpenSSL REQUIRED)
  65
  66 include(cmake/memfd.cmake)
  67 include(cmake/api.cmake)
  68 include(cmake/library.cmake)
  69 include(cmake/exec.cmake)
  70 include(cmake/plugin.cmake)
  71
  72 ##############################################################################
  73 # subdirs - order matters
  74 ##############################################################################
  75 foreach(
  76   DIR
  77   vppinfra svm vlib vlibmemory vlibapi vnet vpp vat vcl plugins
  78   vpp-api tools/vppapigen tools/g2 tools/elftool tools/perftool
  79 )
  80   add_subdirectory(${DIR})
  81 endforeach()
  82
  83 include(cmake/pack.cmake)
  84 ##############################################################################
  85 # detect if we are inside git repo and add configure dependency
  86 ##############################################################################
  87 execute_process(
  88   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  89   COMMAND git rev-parse --show-toplevel
  90   OUTPUT_VARIABLE VPP_GIT_TOPLEVEL_DIR
  91   OUTPUT_STRIP_TRAILING_WHITESPACE
  92 )
  93
  94 if (VPP_GIT_TOPLEVEL_DIR)
  95   set_property(
  96     DIRECTORY APPEND PROPERTY
  97     CMAKE_CONFIGURE_DEPENDS ${VPP_GIT_TOPLEVEL_DIR}/.git/index
  98   )
  99 endif()
 100
 101 ##############################################################################
 102 # print configuration
 103 ##############################################################################
 104 message(STATUS "Configuration:")
 105 pr("VPP version" "${VPP_VERSION}")
 106 pr("VPP library version" "${VPP_LIB_VERSION}")
 107 pr("GIT toplevel dir" "${VPP_GIT_TOPLEVEL_DIR}")
 108 pr("C flags" "${CMAKE_C_FLAGS}")
 109 pr("Linker flags" "${CMAKE_LINKER_FLAGS}")
 110 pr("Target processor" "${CMAKE_SYSTEM_PROCESSOR}")
 111 pr("Build type" "${CMAKE_BUILD_TYPE}")
 112 pr("Install prefix" "${CMAKE_INSTALL_PREFIX}")