src/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 cmake_minimum_required(VERSION 3.5 FATAL_ERROR)
  15
  16 project(vpp C)
  17
  18 include(CheckCCompilerFlag)
  19 include(cmake/message.cmake)
  20 include(cmake/cpu.cmake)
  21 include(cmake/ccache.cmake)
  22
  23 ##############################################################################
  24 # VPP Version
  25 ##############################################################################
  26 execute_process(
  27   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  28   COMMAND scripts/version
  29   OUTPUT_VARIABLE VPP_VERSION
  30   OUTPUT_STRIP_TRAILING_WHITESPACE
  31 )
  32 string(REPLACE "-" ";" VPP_LIB_VERSION ${VPP_VERSION})
  33 list(GET VPP_LIB_VERSION 0 VPP_LIB_VERSION)
  34
  35 ##############################################################################
  36 # build config
  37 ##############################################################################
  38 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  39 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  40 set(CMAKE_C_FLAGS_COMMON "-DFORTIFY_SOURCE=2 -fstack-protector-all -Werror")
  41 set(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} ${CMAKE_C_FLAGS_COMMON} -DCLIB_DEBUG")
  42 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${CMAKE_C_FLAGS_COMMON}")
  43
  44 check_c_compiler_flag("-Wno-address-of-packed-member" compiler_flag_no_address_of_packed_member)
  45 if (compiler_flag_no_address_of_packed_member)
  46   add_definitions(-Wno-address-of-packed-member)
  47 endif()
  48
  49 ##############################################################################
  50 # install config
  51 ##############################################################################
  52 set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib")
  53 set(CMAKE_INSTALL_MESSAGE NEVER)
  54
  55 include_directories (
  56         ${CMAKE_SOURCE_DIR}
  57         ${CMAKE_BINARY_DIR}
  58         ${CMAKE_BINARY_DIR}/include
  59 )
  60 set(CMAKE_INSTALL_DEFAULT_COMPONENT_NAME "vpp")
  61
  62 set(THREADS_PREFER_PTHREAD_FLAG ON)
  63 find_package(Threads REQUIRED)
  64
  65 include(cmake/memfd.cmake)
  66 include(cmake/api.cmake)
  67 include(cmake/library.cmake)
  68 include(cmake/exec.cmake)
  69 include(cmake/plugin.cmake)
  70
  71 ##############################################################################
  72 # subdirs - order matters
  73 ##############################################################################
  74 if("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
  75   find_package(OpenSSL REQUIRED)
  76   set(SUBDIRS
  77     vppinfra svm vlib vlibmemory vlibapi vnet vpp vat vcl plugins
  78     vpp-api tools/vppapigen tools/g2 tools/elftool tools/perftool cmake
  79   )
  80 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
  81   set(SUBDIRS vppinfra)
  82 else()
  83   message(FATAL_ERROR "Unsupported system: ${CMAKE_SYSTEM_NAME}")
  84 endif()
  85
  86 foreach(DIR ${SUBDIRS})
  87   add_subdirectory(${DIR})
  88 endforeach()
  89
  90 ##############################################################################
  91 # packaging
  92 ##############################################################################
  93 include(cmake/pack.cmake)
  94 add_vpp_packaging(
  95   NAME "vpp"
  96   VENDOR "fd.io"
  97   DESCRIPTION "Vector Packet Processor"
  98 )
  99
 100 ##############################################################################
 101 # detect if we are inside git repo and add configure dependency
 102 ##############################################################################
 103 execute_process(
 104   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 105   COMMAND git rev-parse --show-toplevel
 106   OUTPUT_VARIABLE VPP_GIT_TOPLEVEL_DIR
 107   OUTPUT_STRIP_TRAILING_WHITESPACE
 108 )
 109
 110 if (VPP_GIT_TOPLEVEL_DIR)
 111   set_property(
 112     DIRECTORY APPEND PROPERTY
 113     CMAKE_CONFIGURE_DEPENDS ${VPP_GIT_TOPLEVEL_DIR}/.git/index
 114   )
 115 endif()
 116
 117 ##############################################################################
 118 # print configuration
 119 ##############################################################################
 120 message(STATUS "Configuration:")
 121 pr("VPP version" "${VPP_VERSION}")
 122 pr("VPP library version" "${VPP_LIB_VERSION}")
 123 pr("GIT toplevel dir" "${VPP_GIT_TOPLEVEL_DIR}")
 124 pr("C flags" "${CMAKE_C_FLAGS}")
 125 pr("Linker flags" "${CMAKE_LINKER_FLAGS}")
 126 pr("Target processor" "${CMAKE_SYSTEM_PROCESSOR}")
 127 pr("Build type" "${CMAKE_BUILD_TYPE}")
 128 pr("Prefix path" "${CMAKE_PREFIX_PATH}")
 129 pr("Install prefix" "${CMAKE_INSTALL_PREFIX}")
 130