src/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 cmake_minimum_required(VERSION 3.5 FATAL_ERROR)
  15
  16 set(CMAKE_C_COMPILER_NAMES clang-10 clang-9 gcc-9 cc)
  17
  18 project(vpp C)
  19
  20 include(CheckCCompilerFlag)
  21 include(cmake/misc.cmake)
  22 include(cmake/cpu.cmake)
  23 include(cmake/ccache.cmake)
  24
  25 ##############################################################################
  26 # VPP Version
  27 ##############################################################################
  28 execute_process(
  29   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  30   COMMAND scripts/version
  31   OUTPUT_VARIABLE VPP_VERSION
  32   OUTPUT_STRIP_TRAILING_WHITESPACE
  33 )
  34 string(REPLACE "-" ";" VPP_LIB_VERSION ${VPP_VERSION})
  35 list(GET VPP_LIB_VERSION 0 VPP_LIB_VERSION)
  36
  37 ##############################################################################
  38 # cross compiling
  39 ##############################################################################
  40 if(CMAKE_CROSSCOMPILING)
  41   set(CMAKE_IGNORE_PATH
  42     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/
  43     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/lib/
  44   )
  45 endif()
  46 set(CMAKE_C_COMPILER_TARGET ${CMAKE_SYSTEM_PROCESSOR}-linux-gnu)
  47
  48 ##############################################################################
  49 # build config
  50 ##############################################################################
  51 check_c_compiler_flag("-Wno-address-of-packed-member"
  52                       compiler_flag_no_address_of_packed_member)
  53 set(VPP_RUNTIME_DIR "bin" CACHE STRING "Relative runtime directory path")
  54 set(VPP_LIBRARY_DIR "lib" CACHE STRING "Relative library directory path")
  55
  56 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_RUNTIME_DIR})
  57 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_LIBRARY_DIR})
  58
  59 if (CMAKE_BUILD_TYPE)
  60   set(CMAKE_C_FLAGS "-g -fPIC -Werror -Wall ${CMAKE_C_FLAGS}")
  61 endif()
  62
  63 if (compiler_flag_no_address_of_packed_member)
  64   set(CMAKE_C_FLAGS "-Wno-address-of-packed-member ${CMAKE_C_FLAGS}")
  65 endif()
  66
  67 # release
  68 list(APPEND BUILD_TYPES "release")
  69 string(CONCAT CMAKE_C_FLAGS_RELEASE
  70   "-O2 "
  71   "-fstack-protector "
  72   "-DFORTIFY_SOURCE=2 "
  73   "-fno-common "
  74 )
  75
  76 string(CONCAT CMAKE_EXE_LINKER_FLAGS_RELEASE "-pie")
  77
  78 # debug
  79 list(APPEND BUILD_TYPES "debug")
  80 string(CONCAT CMAKE_C_FLAGS_DEBUG
  81   "-O0 "
  82   "-DCLIB_DEBUG "
  83   "-fstack-protector "
  84   "-DFORTIFY_SOURCE=2 "
  85   "-fno-common "
  86 )
  87
  88 # coverity
  89 list(APPEND BUILD_TYPES "coverity")
  90 string(CONCAT CMAKE_C_FLAGS_COVERITY "-O2 -D__COVERITY__")
  91
  92 # gcov
  93 list(APPEND BUILD_TYPES "gcov")
  94 string(CONCAT CMAKE_C_FLAGS_GCOV
  95   "-O0 "
  96   "-DCLIB_DEBUG "
  97   "-DCLIB_GCOV "
  98   "-fprofile-arcs "
  99   "-ftest-coverage ")
 100
 101 string(TOUPPER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_UC)
 102
 103
 104 string(REPLACE ";" " " BUILD_TYPES "${BUILD_TYPES}")
 105 set_property(CACHE CMAKE_BUILD_TYPE PROPERTY
 106              HELPSTRING "Build type - valid options are: ${BUILD_TYPES}")
 107
 108 ##############################################################################
 109 # sanitizers
 110 ##############################################################################
 111
 112 option(VPP_ENABLE_SANITIZE_ADDR "Enable Address Sanitizer" OFF)
 113 set(VPP_SANITIZE_ADDR_OPTIONS
 114   "unmap_shadow_on_exit=1:disable_coredump=0:abort_on_error=1:detect_leaks=0"
 115   CACHE
 116   STRING "Address sanitizer arguments"
 117 )
 118
 119 if (VPP_ENABLE_SANITIZE_ADDR)
 120   set(CMAKE_C_FLAGS "-fsanitize=address -DCLIB_SANITIZE_ADDR ${CMAKE_C_FLAGS}")
 121   set(CMAKE_EXE_LINKER_FLAGS "-fsanitize=address ${CMAKE_EXE_LINKER_FLAGS}")
 122   set(CMAKE_SHARED_LINKER_FLAGS "-fsanitize=address ${CMAKE_SHARED_LINKER_FLAGS}")
 123 endif (VPP_ENABLE_SANITIZE_ADDR)
 124
 125 ##############################################################################
 126 # install config
 127 ##############################################################################
 128 set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib")
 129 set(CMAKE_INSTALL_MESSAGE NEVER)
 130
 131 include_directories (
 132         ${CMAKE_SOURCE_DIR}
 133         ${CMAKE_BINARY_DIR}
 134         ${CMAKE_BINARY_DIR}/include
 135 )
 136 set(CMAKE_INSTALL_DEFAULT_COMPONENT_NAME "vpp")
 137
 138 set(THREADS_PREFER_PTHREAD_FLAG ON)
 139 find_package(Threads REQUIRED)
 140
 141 include(cmake/syscall.cmake)
 142 include(cmake/api.cmake)
 143 include(cmake/library.cmake)
 144 include(cmake/exec.cmake)
 145 include(cmake/plugin.cmake)
 146
 147 ##############################################################################
 148 # subdirs - order matters
 149 ##############################################################################
 150 option(VPP_HOST_TOOLS_ONLY "Build only host tools" OFF)
 151 if(VPP_HOST_TOOLS_ONLY)
 152   set(SUBDIRS tools/vppapigen cmake)
 153 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
 154   find_package(OpenSSL REQUIRED)
 155   set(SUBDIRS
 156     vppinfra svm vlib vlibmemory vlibapi vnet vpp vat vcl plugins
 157     vpp-api tools/vppapigen tools/g2 tools/perftool cmake pkg
 158     tools/appimage
 159   )
 160 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
 161   set(SUBDIRS vppinfra)
 162 else()
 163   message(FATAL_ERROR "Unsupported system: ${CMAKE_SYSTEM_NAME}")
 164 endif()
 165
 166 foreach(DIR ${SUBDIRS})
 167   add_subdirectory(${DIR})
 168 endforeach()
 169
 170 ##############################################################################
 171 # detect if we are inside git repo and add configure dependency
 172 ##############################################################################
 173 execute_process(
 174   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 175   COMMAND git rev-parse --show-toplevel
 176   OUTPUT_VARIABLE VPP_GIT_TOPLEVEL_DIR
 177   OUTPUT_STRIP_TRAILING_WHITESPACE
 178   ERROR_QUIET
 179 )
 180
 181 if (VPP_GIT_TOPLEVEL_DIR)
 182   set_property(
 183     DIRECTORY APPEND PROPERTY
 184     CMAKE_CONFIGURE_DEPENDS ${VPP_GIT_TOPLEVEL_DIR}/.git/index
 185   )
 186 endif()
 187
 188 ##############################################################################
 189 # print configuration
 190 ##############################################################################
 191 message(STATUS "Configuration:")
 192 pr("VPP version" "${VPP_VERSION}")
 193 pr("VPP library version" "${VPP_LIB_VERSION}")
 194 pr("GIT toplevel dir" "${VPP_GIT_TOPLEVEL_DIR}")
 195 pr("Build type" "${CMAKE_BUILD_TYPE}")
 196 pr("C flags" "${CMAKE_C_FLAGS}${CMAKE_C_FLAGS_${CMAKE_BUILD_TYPE_UC}}")
 197 pr("Linker flags (apps)" "${CMAKE_EXE_LINKER_FLAGS}${CMAKE_EXE_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}}")
 198 pr("Linker flags (libs)" "${CMAKE_SHARED_LINKER_FLAGS}${CMAKE_SHARED_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}}")
 199 pr("Host processor" "${CMAKE_HOST_SYSTEM_PROCESSOR}")
 200 pr("Target processor" "${CMAKE_SYSTEM_PROCESSOR}")
 201 pr("Prefix path" "${CMAKE_PREFIX_PATH}")
 202 pr("Install prefix" "${CMAKE_INSTALL_PREFIX}")