src/cmake/cpu.cmake

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 ##############################################################################
  15 # Cache line size detection
  16 ##############################################################################
  17 if(CMAKE_CROSSCOMPILING)
  18   message(STATUS "Cross-compiling - cache line size detection disabled")
  19   set(VPP_LOG2_CACHE_LINE_SIZE 6)
  20 elseif(DEFINED VPP_LOG2_CACHE_LINE_SIZE)
  21   # Cache line size assigned via cmake args
  22 elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "^(aarch64.*|AARCH64.*)")
  23   file(READ "/proc/cpuinfo" cpuinfo)
  24   string(REPLACE "\n" ";" cpuinfo ${cpuinfo})
  25   foreach(l ${cpuinfo})
  26     string(REPLACE ":" ";" l ${l})
  27     list(GET l 0 name)
  28     list(GET l 1 value)
  29     string(STRIP ${name} name)
  30     string(STRIP ${value} value)
  31     if(${name} STREQUAL "CPU implementer")
  32       set(CPU_IMPLEMENTER ${value})
  33     endif()
  34     if(${name} STREQUAL "CPU part")
  35       set(CPU_PART ${value})
  36     endif()
  37   endforeach()
  38   # Implementer 0x43 - Cavium
  39   #  Part 0x0af - ThunderX2 is 64B, rest all are 128B
  40   if (${CPU_IMPLEMENTER} STREQUAL "0x43")
  41     if (${CPU_PART} STREQUAL "0x0af")
  42       set(VPP_LOG2_CACHE_LINE_SIZE 6)
  43     else()
  44       set(VPP_LOG2_CACHE_LINE_SIZE 7)
  45     endif()
  46   else()
  47       set(VPP_LOG2_CACHE_LINE_SIZE 6)
  48   endif()
  49   math(EXPR VPP_CACHE_LINE_SIZE "1 << ${VPP_LOG2_CACHE_LINE_SIZE}")
  50   message(STATUS "ARM AArch64 CPU implementer ${CPU_IMPLEMENTER} part ${CPU_PART} cacheline size ${VPP_CACHE_LINE_SIZE}")
  51 else()
  52   set(VPP_LOG2_CACHE_LINE_SIZE 6)
  53 endif()
  54
  55 set(VPP_LOG2_CACHE_LINE_SIZE ${VPP_LOG2_CACHE_LINE_SIZE}
  56     CACHE STRING "Target CPU cache line size (power of 2)")
  57
  58 ##############################################################################
  59 # Gnu Assembler AVX-512 bug detection
  60 # - see: https://sourceware.org/bugzilla/show_bug.cgi?id=23465
  61 ##############################################################################
  62 if(CMAKE_SYSTEM_PROCESSOR MATCHES "amd64.*|x86_64.*|AMD64.*")
  63   if (CMAKE_C_COMPILER_ID STREQUAL "GNU")
  64     set(pfx ${CMAKE_CURRENT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/gas_avx512_bug_test)
  65     file(WRITE ${pfx}.s "vmovaps 0x40(,%rax), %zmm0\n")
  66     execute_process(COMMAND ${CMAKE_C_COMPILER} -c ${pfx}.s -o ${pfx}.o)
  67     execute_process(COMMAND objdump -s ${pfx}.o OUTPUT_VARIABLE _output)
  68     if (NOT _output MATCHES "62f17c48 28040540 000000")
  69       set(GNU_ASSEMBLER_AVX512_BUG 1)
  70     endif()
  71   endif()
  72 endif()
  73
  74 ##############################################################################
  75 # CPU optimizations and multiarch support
  76 ##############################################################################
  77 if(CMAKE_SYSTEM_PROCESSOR MATCHES "amd64.*|x86_64.*|AMD64.*")
  78   set(CMAKE_C_FLAGS "-march=corei7 -mtune=corei7-avx ${CMAKE_C_FLAGS}")
  79   check_c_compiler_flag("-march=core-avx2" compiler_flag_march_core_avx2)
  80   if(compiler_flag_march_core_avx2)
  81     list(APPEND MARCH_VARIANTS "avx2\;-march=core-avx2 -mtune=core-avx2")
  82   endif()
  83   if (GNU_ASSEMBLER_AVX512_BUG)
  84      message(WARNING "AVX-512 multiarch variant(s) disabled due to GNU Assembler bug")
  85   else()
  86     check_c_compiler_flag("-march=skylake-avx512" compiler_flag_march_skylake_avx512)
  87     check_c_compiler_flag("-march=icelake-client" compiler_flag_march_icelake_client)
  88     if(compiler_flag_march_skylake_avx512)
  89       list(APPEND MARCH_VARIANTS "avx512\;-march=skylake-avx512 -mtune=skylake-avx512")
  90     endif()
  91   endif()
  92 elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "^(aarch64.*|AARCH64.*)")
  93   set(CMAKE_C_FLAGS "-march=armv8-a+crc ${CMAKE_C_FLAGS}")
  94   check_c_compiler_flag("-march=armv8-a+crc+crypto -mtune=qdf24xx" compiler_flag_march_core_qdf24xx)
  95   if(compiler_flag_march_core_qdf24xx)
  96     list(APPEND MARCH_VARIANTS "qdf24xx\;-march=armv8-a+crc+crypto -DCLIB_N_PREFETCHES=8")
  97   endif()
  98   check_c_compiler_flag("-march=armv8.1-a+crc+crypto -mtune=thunderx2t99" compiler_flag_march_thunderx2t99)
  99   if(compiler_flag_march_thunderx2t99)
 100     if (CMAKE_C_COMPILER_ID STREQUAL "GNU" AND (NOT CMAKE_C_COMPILER_VERSION VERSION_LESS 8.3))
 101       list(APPEND MARCH_VARIANTS "thunderx2t99\;-march=armv8.1-a+crc+crypto -mtune=thunderx2t99 -DCLIB_N_PREFETCHES=8")
 102     else()
 103       list(APPEND MARCH_VARIANTS "thunderx2t99\;-march=armv8.1-a+crc+crypto -DCLIB_N_PREFETCHES=8")
 104     endif()
 105   endif()
 106   check_c_compiler_flag("-march=armv8-a+crc+crypto -mtune=cortex-a72" compiler_flag_march_cortexa72)
 107   if(compiler_flag_march_cortexa72)
 108     list(APPEND MARCH_VARIANTS "cortexa72\;-march=armv8-a+crc+crypto -mtune=cortex-a72 -DCLIB_N_PREFETCHES=6")
 109   endif()
 110   check_c_compiler_flag("-march=armv8.2-a+crc+crypto -mtune=neoverse-n1" compiler_flag_march_neoversen1)
 111   if(compiler_flag_march_neoversen1)
 112     list(APPEND MARCH_VARIANTS "neoversen1\;-march=armv8.2-a+crc+crypto -mtune=neoverse-n1 -DCLIB_N_PREFETCHES=6")
 113   endif()
 114 endif()
 115
 116 macro(vpp_library_set_multiarch_sources lib)
 117   foreach(V ${MARCH_VARIANTS})
 118     list(GET V 0 VARIANT)
 119     list(GET V 1 VARIANT_FLAGS)
 120     set(l ${lib}_${VARIANT})
 121     add_library(${l} OBJECT ${ARGN})
 122     set_target_properties(${l} PROPERTIES POSITION_INDEPENDENT_CODE ON)
 123     target_compile_options(${l} PUBLIC "-DCLIB_MARCH_VARIANT=${VARIANT}")
 124     separate_arguments(VARIANT_FLAGS)
 125     target_compile_options(${l} PUBLIC ${VARIANT_FLAGS})
 126     target_sources(${lib} PRIVATE $<TARGET_OBJECTS:${l}>)
 127   endforeach()
 128 endmacro()
 129